【Unity Shader】透明效果（透明度测试与透明度混合）_unity shader 透明度

作者：Gausst松鼠会 | 2024-02-19 18:44:38

踩

unity shader 透明度

在Unity中，一般有两种方式来实现“透明”效果。
第一种，是比较霸道的透明度测试。对于不满足透明度测试的片元会直接舍弃。与其叫它透明，我觉得用“镂空”来形容它更合适。因为它的实现效果是下面这样：
在这里插入图片描述
第二种，才可以得到真正的半透明效果，我们管它叫透明度混合

在学习OpenGL的时候，就明白了当开启透明混合时，渲染顺序是非常重要的。因为需要关闭深度写入，不然就会直接舍弃掉后面的那些本能通过透明面看到的片元。

那么正确的渲染顺序应该是怎么样呢：
（1）先渲染场景中所有的不透明物体，并且开启他们的深度测试和深度写入。
（2）把半透明物体按照他们距离摄像机的远近进行排序，然后按照从后往前的顺序渲染这些半透明物体，并且开启他们的深度测试，关闭深度写入
当模型物体之间有循环遮挡之类的情况时，引擎这时一般会将复杂的模型拆分成可以独立排序的多个子模型。

而在Unity中，提供了渲染队列这一解决方案。

名称	队列索引号	描述
Backgroud	1000	这个渲染队列会在任何其他队列之前被渲染，我们通常使用该队列来渲染那些需要绘制在背景上的物体
Geometry	2000	默认的渲染队列，大部分物体都使用这个队列，不透明物体使用这个队列
AlphaTest	2450	需要透明度测试的物体使用这个队列。在Untiy5中它从Geometry队列中被单独分出来，这是因为在所有不透明物体渲染之后再渲染他们会更高效
Transparent	3000	这个队列中的物体会在所有Geometry和AlphaTest物体渲染后，再按照从后往前的顺序渲染。任何使用了透明度混合的物体都应该使用该队列
Overlay	4000	该队列用于实现一些叠加效果。任何需要再最后渲染的物体都应该使用该队列

接下来就是透明度测试和透明度混合的Shader。使用了一张包含透明度通道的纹理图片。其余的细节在Shader里查看

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'

Shader "Unlit/AlphaTest"
{
    Properties
    {
        _Color ("Main Tint",Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _Cutoff("Alpha Cutoff",Range(0,1)) = 0.5//透明度测试阈值
    }
    SubShader
    {
        Tags{"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
        //使用AlphaTest渲染队列
        //InoreProjector表示这个Shader不会受到投影器的影响
        //RenderType表示将此Shader归入TransparentCutout组中
        //使用了透明度测试的Shader都应该使用这三个标签
        Pass
        {
            Tags {"LightModel"="ForwardBase"}
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;//用于得到纹理的缩放和平移值
            fixed _Cutoff;//透明度测试阈值

            struct a2v{
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f{
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : TEXCOORD2;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target{
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed4 texColor = tex2D(_MainTex,i.uv);

                //Alpha(透明度)测试
                clip(texColor.a - _Cutoff);
                //等同于
                // if((texColor.a-_Cutoff)<0.0){
                //     discard;
                // }

                fixed3 albedo = texColor.rgb * _Color.rgb;
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
                fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,worldLightDir));

                return fixed4(ambient + diffuse,1.0);
            }
            ENDCG
        }
    }
    Fallback "Transparent/Cutout/VertexLit"
}

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80

Shader "Unlit/AlphaBlend"
{
    Properties
    {
        _Color ("Main Tint",Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _AlphaScale("Alpha Scale",Range(0,1)) = 1
    }
    SubShader
    {
        Tags{"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
        //使用Transparent渲染队列
        //InoreProjector表示这个Shader不会受到投影器的影响
        //RenderType表示将此Shader归入Transparent组中
        //使用了透明度测试的Shader都应该使用这三个标签
        Pass
        {
            Tags {"LightModel"="ForwardBase"}
            
            ZWrite off//关闭深度写入
            Blend SrcAlpha oneMinusSrcAlpha
            //源颜色的混合因子设为SrcAlpha，把目标颜色的混合因子设为oneMinusSrcAlpha
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;//用于得到纹理的缩放和平移值
            fixed _AlphaScale;//透明度混合

            struct a2v{
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f{
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : TEXCOORD2;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target{
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed4 texColor = tex2D(_MainTex,i.uv);

                fixed3 albedo = texColor.rgb * _Color.rgb;
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
                fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,worldLightDir));

                return fixed4(ambient + diffuse,texColor.a*_AlphaScale);
            }
            ENDCG
        }
    }
    Fallback "Transparent/VertexLit"
}

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74

由于Unity默认是开启背面剔除的，所以透明时，会看不到本身属于这个物体的背面。
我们想得到正确的效果，还需要关闭背面剔除。同时，对于使用透明度混合的物体，仅仅关闭背面剔除是无法得到正确的渲染关系的。因此需要多用一个Pass去渲染两面。第一个Pass用于渲染背面，第二个Pass只用于渲染正面。由于Unity会按照顺序执行Pass，所以总是会得到背面先被渲染的结果，也就保证了正确的渲染关系。

Shader "Unlit/AlphaTestBothSided"
{
    Properties
    {
        _Color ("Main Tint",Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _Cutoff("Alpha Cutoff",Range(0,1)) = 0.5//透明度测试阈值
    }
    SubShader
    {
        Tags{"Queue"="AlphaTest" "IgnoreProjector"="True" "RenderType"="TransparentCutout"}
        //使用AlphaTest渲染队列
        //InoreProjector表示这个Shader不会受到投影器的影响
        //RenderType表示将此Shader归入TransparentCutout组中
        //使用了透明度测试的Shader都应该使用这三个标签
        Pass
        {
            Tags {"LightModel"="ForwardBase"}
            Cull off//关闭面剔除
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;//用于得到纹理的缩放和平移值
            fixed _Cutoff;//透明度测试阈值

            struct a2v{
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f{
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : TEXCOORD2;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target{
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed4 texColor = tex2D(_MainTex,i.uv);

                //Alpha(透明度)测试
                clip(texColor.a - _Cutoff);
                //等同于
                // if((texColor.a-_Cutoff)<0.0){
                //     discard;
                // }

                fixed3 albedo = texColor.rgb * _Color.rgb;
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
                fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,worldLightDir));

                return fixed4(ambient + diffuse,1.0);
            }
            ENDCG
        }
    }
    Fallback "Transparent/Cutout/VertexLit"
}

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78

效果图：（双面透明度测试）
在这里插入图片描述

Shader "Unlit/AlphaBlendBothSided1"
{
    Properties
    {
        _Color ("Main Tint",Color) = (1,1,1,1)
        _MainTex ("Main Tex", 2D) = "white" {}
        _AlphaScale("Alpha Scale",Range(0,1)) = 1
    }
    SubShader
    {
        Tags{"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
        //使用Transparent渲染队列
        //InoreProjector表示这个Shader不会受到投影器的影响
        //RenderType表示将此Shader归入Transparent组中
        //使用了透明度测试的Shader都应该使用这三个标签
        Pass //第一个Pass只渲染背面
        {
            Tags {"LightModel"="ForwardBase"}

            Cull Front        
            ZWrite off//关闭深度写入
            Blend SrcAlpha oneMinusSrcAlpha
            //源颜色的混合因子设为SrcAlpha，把目标颜色的混合因子设为oneMinusSrcAlpha
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;//用于得到纹理的缩放和平移值
            fixed _AlphaScale;//透明度混合

            struct a2v{
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f{
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : TEXCOORD2;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target{
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed4 texColor = tex2D(_MainTex,i.uv);

                fixed3 albedo = texColor.rgb * _Color.rgb;
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
                fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,worldLightDir));

                return fixed4(ambient + diffuse,texColor.a*_AlphaScale);
            }
            ENDCG
        }

        Pass //第二个Pass只渲染正面
        {
            Tags {"LightModel"="ForwardBase"}
            
            Cull Back
            ZWrite off//关闭深度写入
            Blend SrcAlpha oneMinusSrcAlpha
            //源颜色的混合因子设为SrcAlpha，把目标颜色的混合因子设为oneMinusSrcAlpha
            CGPROGRAM

            #pragma vertex vert
            #pragma fragment frag
            
            #include "Lighting.cginc"

            fixed4 _Color;
            sampler2D _MainTex;
            float4 _MainTex_ST;//用于得到纹理的缩放和平移值
            fixed _AlphaScale;//透明度混合

            struct a2v{
                float4 vertex:POSITION;
                float3 normal:NORMAL;
                float4 texcoord:TEXCOORD0;
            };

            struct v2f{
                float4 pos : SV_POSITION;
                float3 worldNormal : TEXCOORD0;
                float3 worldPos : TEXCOORD1;
                float2 uv : TEXCOORD2;
            };

            v2f vert(a2v v){
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.worldNormal = UnityObjectToWorldNormal(v.normal);
                o.worldPos = mul(unity_ObjectToWorld,v.vertex).xyz;
                o.uv = TRANSFORM_TEX(v.texcoord,_MainTex);

                return o;
            }

            fixed4 frag(v2f i) : SV_Target{
                fixed3 worldNormal = normalize(i.worldNormal);
                fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
                fixed4 texColor = tex2D(_MainTex,i.uv);

                fixed3 albedo = texColor.rgb * _Color.rgb;
                fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
                fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(worldNormal,worldLightDir));

                return fixed4(ambient + diffuse,texColor.a*_AlphaScale);
            }
            ENDCG
        }
    }
    Fallback "Transparent/VertexLit"
}

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132

效果图：（双面透明度混合）
在这里插入图片描述

声明：本文内容由网友自发贡献，不代表【wpsshop博客】立场，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：https://www.wpsshop.cn/w/Gausst松鼠会/article/detail/116298