如何快速开发一个上位机？aardio了解一下_上位机软件开发

作者：Monodyee | 2024-05-21 06:56:26

踩

上位机软件开发

https://gitee.com/zhengnianli/EmbedSummary

我们的资料仓库下面之前有一位小伙伴留言：

杂烩君之前偶然间知道aardio这么一个工具，但没有实际去了解过。本期花点时间来了解、学习一下aardio，看看aardio是不是如这位朋友所说的这是一个不错的工具。

本期主角：aardio

aardio属于易用性极强的动态语言，但也是一种混合语言，可以罕见地、非常方便地操作静态类型，因此可以直接调用 C语言、C++ 等等静态语言的 API 接口函数。

aardio应用于桌面软件开发。aardio已经发展了 17年 ，一直保持非常活跃地更新。

aardio的特点：

良好的架构与语法
小、轻、快，轻便利索，体积仅 6.5MB，学习和使用成本极低
胶水能力极强
可以嵌入非常多的浏览器控件
不仅仅可以开发桌面软件，也可以用于开发网站
可以方便地通过拖拉传统控件创建程序

aardio官网：

https://www.aardio.com/

aardio的使用

aardio说白了就是一门编程语言，它很灵活且强大。下面一起通过实例来简单了解aardio。

首先，从aardio官网下载得到aardio开发包：

aardio的开发包非常小！里面的内容有：

其中，开发工具 aardio.exe 只有6MB！相对于其它如Qt Creator、VS等开发工具动不动就几个G，aardio.exe的小就是一大优势。

aardio.exe的界面如：

aardio专注于桌面软件开发。我们就来看一下如何使用aardio来写一个简单的 串口点灯上位机 。没错，这个我们之前有基于QT的手把手开发教程：易懂 | 手把手教你编写你的第一个上位机

本篇文章我们基于aardio来写一个，体验桌面软件快速开发！

首先，使用界面控件设计界面：

这些控件不是拖动过去的。而是 先点击鼠标左键选中某个控件 ，再在设计区域 点击鼠标左键放置控件 。

然后，切换到代码视图编写代码：

import win.dlg.message;
import win.ui;
/*DSG{{*/
mainForm = win.form(text="serial_led";right=457;bottom=329)
mainForm.add(
baudrateEdit={cls="edit";text="115200";left=212;top=97;right=320;bottom=122;edge=1;multiline=1;z=9};
closeBtn={cls="button";text="关闭串口";left=245;top=170;right=320;bottom=208;z=6};
combobox={cls="combobox";left=212;top=54;right=318;bottom=80;edge=1;items={};mode="dropdown";z=2};
edit={cls="edit";left=12;top=12;right=446;bottom=318;db=1;disabled=1;dl=1;dr=1;dt=1;edge=1;multiline=1;z=1};
ledoffBtn={cls="button";text="灭灯";left=247;top=239;right=322;bottom=277;z=8};
ledonBtn={cls="button";text="点灯";left=130;top=240;right=205;bottom=278;z=7};
openBtn={cls="button";text="打开串口";left=130;top=170;right=205;bottom=208;z=5};
static={cls="static";text="串口";left=148;top=58;right=186;bottom=83;notify=1;transparent=1;z=3};
static2={cls="static";text="波特率";left=148;top=102;right=186;bottom=127;notify=1;transparent=1;z=4}
)
/*}}*/

// 串口列表
import sys.comPort;
var comPorts = sys.comPort.list();
mainForm.combobox.items = comPorts;
mainForm.combobox.selIndex = 1; 

import sio;
var sioPort;

// 打开串口
mainForm.openBtn.oncommand = function(id,event){
	if(sioPort){
		sioPort.close();
	}
	
	var err;
	sioPort,err = sio.port(mainForm.combobox.selText);
	if(!sioPort){
		return mainForm.msgErr(err);
	}
	
	sioPort.ioctl(eval(mainForm.baudrateEdit.text),8,1);
	
	mainForm.msgOk("已打开端口",1000)
}

// 关闭串口
mainForm.closeBtn.oncommand = function(id,event){
	if(sioPort){
		sioPort.close();
		mainForm.msgOk("已关闭端口",1000);
	}  
}

// 点灯
mainForm.ledonBtn.oncommand = function(id,event){
	if(!sioPort){
		mainForm.openBtn.oncommand();
	}
	
	if( !sioPort.writeHex("01") ){
		return mainForm.msgErr("发送失败");
	}
	else {
		return mainForm.msgOk("发送ON成功",1000);
	}	
}

// 灭灯
mainForm.ledoffBtn.oncommand = function(id,event){
	if(!sioPort){
		mainForm.openBtn.oncommand();
	}
	
	if( !sioPort.writeHex("00") ){
		return mainForm.msgErr("发送失败");
	}
	else {
		return mainForm.msgOk("发送OFF成功",1000);
	}	
}

if(_ARGV.opt){
	mainForm.edit.print(_ARGV.opt,_ARGV[#_ARGV]);
}

mainForm.edit.oncommand = function(id,event){
	
}

mainForm.static.oncommand = function(id,event){
	
}

mainForm.static2.oncommand = function(id,event){
	
}

mainForm.show();
return win.loopMessage();
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97