devbox
凡人多烦事01
这个屌丝很懒，什么也没留下！
关注作者
热门标签
热门文章
当前位置:   article > 正文

NSIS 自定义界面，下载并安装Net.Framework4.8_通过nsis和duilib实现自定义安装界面

作者：凡人多烦事01 | 2024-02-19 04:31:22

赞

踩

通过nsis和duilib实现自定义安装界面

如果我们的软件开发的语言使用的是C#，使用的平台框架是Net.Framework,哪么在部署软件安装时，就需要考虑在安装过程检测是否需要安装net环境，并进行安装。

本文以 ScreenToGif 这款软件为例，详细讲解如何在安装的过程中检测并下载net包进行安装。

 

前言

1、ScreenToGif 是一款开源的截屏软件，依赖于Net.Framework环境

2、本文讲解的NSIS安装过程为自定义界面，而非传统界面（需要传统界面的留言区留言）。

3、Win10系统好像是自动集成了Net.Framework4.8的环境

4、安装Net.Framework4.0以上的版本，需要先安装微软证书，再安装Net.Framework安装，否则可能安装不成功，如下图：

 

相关资源

微软证书2011下载链接：https://download.microsoft.com/download/2/4/8/248D8A62-FCCD-475C-85E7-6ED59520FC0F/MicrosoftRootCertificateAuthority2011.cer

Net.Framework4.8离线包下载链接：https://download.visualstudio.microsoft.com/download/pr/014120d7-d689-4305-befd-3cb711108212/0fd66638cde16859462a6243a4629a50/ndp48-x86-x64-allos-enu.exe

本文中的安装示例包：

链接: 链接: https://pan.baidu.com/s/1aMUEs_F74whkGEzubInkfw

提取码: 2g6y

 

NSIS使用到的插件

1、nsNiuniuSkin：基于Duilib的界面库（自定义界面的界面库）

2、nsis7zU：压缩及解压

3、inetc：下载文件（增加下载回调，当前进度，下载包大小，已下载大小，下载速度 ，剩余时间等信息）

4、KillProcDLL：结束进程（增加向结束进程发送主线程消息，进而实现被结束的进程安全退出，默认的结束方式为强制结束进程）

 

系统相关的问题

1、Win10系统使用NSIS创建任务栏图标会失败，Win10以下的系统无问题。

2、如果你的应用程序启动需要管理员身份启动，哪么添加开机启动将会失败。

 

制作好的安装包安装过程：

安装过程的逻辑

1、验证系统当前的net版本是否低于 4.8.03761，如果低于 4.8.03761 则做如下逻辑：

  •      下载微软证书
  •      安装微软证书
  •      下载net安装包
  •      安装net安装包

 

NSIS功能代码分享

 

代码段相关的宏定义

  1. # ====================== 自定义宏 产品信息==============================
  2. !define PRODUCT_NAME           		"ScreenToGif"
  3. #安装卸载项用到的KEY
  4. !define PRODUCT_PATHNAME 			"ScreenToGif"
  5. #安装路径追加的名称 
  6. !define INSTALL_APPEND_PATH         "ScreenToGif"
  7. #默认生成的安装路径 
  8. !define INSTALL_DEFALT_SETUPPATH    ""
  9. #执行文件名称 
  10. !define EXE_NAME               		"ScreenToGif.exe"
  11. #版本号
  12. !define PRODUCT_VERSION        		"1.0.0.0"
  13. #主页地址
  14. !define HOME_URL    		        "https://www.screentogif.com/"
  15. #用户条款
  16. !define TERMS_URL    		        ""
  17. #产品发布商
  18. !define PRODUCT_PUBLISHER      		"Nicke Manarin"
  19. #产品法律
  20. !define PRODUCT_LEGAL          		"Nicke Manarin Copyright（c）2020"
  21. #打包出来的文件名称
  22. !define INSTALL_OUTPUT_NAME    		"ScreenToGif_${PRODUCT_VERSION}.exe"
  23. #应用程序的数据目录
  24. !define LOCAL_APPDATA_DIR    		"$LOCALAPPDATA\ScreenToGif"
  25. #打包文件目录
  26. !define APP_FILE_DIR    		    "D:\myCode\app\app-qt-client\PackageDirectory\ScreenToGif"
  27. #文件数量
  28. !define APP_FILE_COUNT    		    9
  29. #完整安装包下载地址
  30. !define ALL_SETUP_DL_URL            ""
  31. #Net包名称
  32. !define NET_PACK_NAME               "ndp48-x86-x64-allos-enu.exe"
  33. #Net包下载地址
  34. !define NET_PACK_DL_URL             "https://download.visualstudio.microsoft.com/download/pr/014120d7-d689-4305-befd-3cb711108212/0fd66638cde16859462a6243a4629a50/ndp48-x86-x64-allos-enu.exe"
  35. #微软证书名称(win7安装net4.6以上版本需下载微软证书并安装,否则net安装会失败)
  36. #net4.0不需要安装微软证书
  37. !define MS_ROOT_CERT_NAME           "MicrosoftRootCertificateAuthority2011.cer"
  38. #微软证书下载地址
  39. !define MS_ROOT_CERT_DL_URL         "https://download.microsoft.com/download/2/4/8/248D8A62-FCCD-475C-85E7-6ED59520FC0F/MicrosoftRootCertificateAuthority2011.cer"

 

获取net版本

  1. ;获取.Net Framework版本支持
  2. Function GetNetFrameworkVersion
  3.     Push $1
  4.     Push $0
  5.     ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full" "Install"
  6.     ReadRegDWORD $1 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v4\Full" "Version"
  7.     StrCmp $0 1 KnowNetFrameworkVersion +1
  8.     ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v3.5" "Install"
  9.     ReadRegDWORD $1 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v3.5" "Version"
  10.     StrCmp $0 1 KnowNetFrameworkVersion +1
  11.     ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v3.0\Setup" "InstallSuccess"
  12.     ReadRegDWORD $1 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v3.0\Setup" "Version"
  13.     StrCmp $0 1 KnowNetFrameworkVersion +1
  14.     ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v2.0.50727" "Install"
  15.     ReadRegDWORD $1 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v2.0.50727" "Version"
  16.     StrCmp $1 "" +1 +2
  17.     StrCpy $1 "2.0.50727.832"
  18.     StrCmp $0 1 KnowNetFrameworkVersion +1
  19.     ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v1.1.4322" "Install"
  20.     ReadRegDWORD $1 HKLM "SOFTWARE\Microsoft\NET Framework Setup\NDP\v1.1.4322" "Version"
  21.     StrCmp $1 "" +1 +2
  22.     StrCpy $1 "1.1.4322.573"
  23.     StrCmp $0 1 KnowNetFrameworkVersion +1
  24.     ReadRegDWORD $0 HKLM "SOFTWARE\Microsoft\.NETFramework\policy\v1.0" "Install"
  25.     ReadRegDWORD $1 HKLM "SOFTWARE\Microsoft\.NETFramework\policy\v1.0" "Version"
  26.     StrCmp $1 "" +1 +2
  27.     StrCpy $1 "1.0.3705.0"
  28.     StrCmp $0 1 KnowNetFrameworkVersion +1
  29.     StrCpy $1 "not .NetFramework"
  30.     KnowNetFrameworkVersion:
  31.     Pop $0
  32.     Exch $1
  33. FunctionEnd

 

下载微软证书

  1. ; 微软证书下载回调
  2. Function MicrosoftCertificatePackDownLoadCallBack
  3. 	; 0-当前进度（百分比）
  4. 	Pop $0
  5. 	; 1-累计大小
  6. 	Pop $1
  7. 	; 2-已下载大小
  8. 	Pop $2
  9. 	; 3-下载速度
  10. 	Pop $3
  11. 	; 4-剩余时间
  12. 	Pop $4
  13.  
  14. 	;更新包下载进度
  15. 	; 当前进度
  16. 	push $0
  17. 	; 当前剩余时间
  18. 	push $4
  19. FunctionEnd
  20.  
  21. ;下载微软证书
  22. Function DownloadMicrosoftCertificate
  23. 	GetFunctionAddress $R9 MicrosoftCertificatePackDownLoadCallBack
  24. 	inetc::get "${MS_ROOT_CERT_DL_URL}" "$TEMP\${MS_ROOT_CERT_NAME}" $R9
  25. 	; 读取值
  26. 	Pop $1
  27. 	; 写入值($1="ok"表示下载成功)
  28. 	Push $1
  29. FunctionEnd

 

安装微软证书

  1. AddCertificateToStore
  2.   Exch $0
  3.   Push $1
  4.   Push $R0
  5.   System::Call "crypt32::CryptQueryObject(i ${CERT_QUERY_OBJECT_FILE}, w r0, \
  6.     i ${CERT_QUERY_CONTENT_FLAG_ALL}, i ${CERT_QUERY_FORMAT_FLAG_ALL}, \
  7.     i 0, i 0, i 0, i 0, i 0, i 0, *i .r0) i .R0"
  8.   ${If} $R0 <> 0
  9.     System::Call "crypt32::CertOpenStore(i ${CERT_STORE_PROV_SYSTEM}, i 0, i 0, \
  10.       i ${CERT_STORE_OPEN_EXISTING_FLAG}|${CERT_SYSTEM_STORE_LOCAL_MACHINE}, \
  11.       w 'ROOT') i .r1"
  12.     ${If} $1 <> 0
  13.       System::Call "crypt32::CertAddCertificateContextToStore(i r1, i r0, \
  14.         i ${CERT_STORE_ADD_ALWAYS}, i 0) i .R0"
  15.       System::Call "crypt32::CertFreeCertificateContext(i r0)"
  16.       ${If} $R0 = 0
  17.         StrCpy $0 "Unable to add certificate to certificate store"
  18.       ${Else}
  19.         StrCpy $0 "success"
  20.       ${EndIf}
  21.       System::Call "crypt32::CertCloseStore(i r1, i 0)"
  22.     ${Else}
  23.       System::Call "crypt32::CertFreeCertificateContext(i r0)"
  24.       StrCpy $0 "Unable to open certificate store"
  25.     ${EndIf}
  26.   ${Else}
  27.     StrCpy $0 "Unable to open certificate file"
  28.   ${EndIf}
  29.  
  30.   Pop $R0
  31.   Pop $1
  32.   Exch $0
  33. FunctionEnd
  34.  
  35. ; 安装微软证书
  36. Function InstallMicrosoftCertificate
  37. 	Push $TEMP\${MS_ROOT_CERT_NAME}
  38. 	Call AddCertificateToStore
  39. 	Pop $0
  40. 	${If} $0 == success
  41. 		; 安装完成,删除文件
  42. 		Delete "$TEMP\${MS_ROOT_CERT_NAME}"
  43. 	${EndIf}
  44.     ; $0=success表示安装成功
  45.     Push $0
  46. FunctionEnd

 

下载net安装包

  1. ; Net安装包下载回调
  2. Function NetPackDownLoadCallBack
  3. 	; 0-当前进度（百分比）
  4. 	Pop $0
  5. 	; 1-累计大小
  6. 	Pop $1
  7. 	; 2-已下载大小
  8. 	Pop $2
  9. 	; 3-下载速度
  10. 	Pop $3
  11. 	; 4-剩余时间
  12. 	Pop $4
  13. FunctionEnd
  14.  
  15. ;下载 .NET Framework 4.0
  16. Function DownloadNetFramework4
  17. 	GetFunctionAddress $R9 NetPackDownLoadCallBack
  18. 	inetc::get "${NET_PACK_DL_URL}" "$TEMP\${NET_PACK_NAME}" $R9
  19. 	; 读取值
  20. 	Pop $1
  21. 	; 写入值($1="ok"表示下载成功)
  22. 	Push $1
  23. FunctionEnd

 

安装net安装包

  1. ; 安装net包
  2. Function InstallDotNetPack
  3. 	; 安装net包
  4. 	ExecWait '$TEMP\${NET_PACK_NAME} /q /norestart /ChainingPackage FullX64Bootstrapper' $R1
  5. 	; 安装成功(安装成功返回0 16386 文件损坏 返回当前版本号 文件不存在)
  6. 	${If} $R1 == 0
  7. 		; 安装完成,删除安装包
  8. 		Delete "$TEMP\${NET_PACK_NAME}"
  9. 	${EndIf}
  10. 	; 返回值($R1=0表示安装成功)
  11. 	Push $R1
  12. FunctionEnd

 

Net环境检测

  1. ; 检查net环境
  2. Function CheckNetCondition
  3. 	; net版本验证及安装
  4. 	;检测是否是需要的.NET Framework版本
  5. 	Call GetNetFrameworkVersion
  6. 	Pop $R1
  7. 	; ${If} $R1 < '4.7.03062'
  8. 	${If} $R1 < '4.8.03761'
  9.         ; 下载微软证书
  10. 		GetFunctionAddress $0 DownloadMicrosoftCertificate
  11. 		; 等待结果
  12. 		BgWorker::CallAndWait
  13.         
  14.         ; 弹出下载结果
  15. 		Pop $R1
  16. 		; 下载成功验证
  17. 		${If} $R1 == "ok"
  18.             ; 微软证书
  19. 			GetFunctionAddress $0 InstallMicrosoftCertificate
  20. 			BgWorker::CallAndWait
  21.             ; 弹出安装结果
  22. 			Pop $R2
  23. 			; 安装结果验证
  24. 			${If} $R2 != success
  25.                 #微软证书安装完成
  26.             ${Endif}
  27.         ${EndIf}
  28.  
  29.         ; 下载net安装包
  30. 		GetFunctionAddress $0 DownloadNetFramework4
  31. 		; 等待结果
  32. 		BgWorker::CallAndWait
  33.  
  34.         ; 弹出下载结果
  35. 		Pop $R3
  36. 		; 下载成功验证
  37. 		${If} $R3 == "ok"
  38.             ; 安装net包
  39. 			GetFunctionAddress $0 InstallDotNetPack
  40. 			BgWorker::CallAndWait
  41.  
  42.             ; 弹出安装结果
  43. 			Pop $R4
  44. 			; 安装结果验证
  45. 			${If} $R4 == 0
  46.                 #net包安装成功
  47.             ${EndIf}
  48.         ${EndIf} 
  49.     ${EndIf}
  50. FunctionEnd

 

结束指定进程

  1. #注：ShowMsgBox 可更换为MessageBox使用系统提示框提示
  2.  
  3. ; 结束进程
  4. ; 返回0 表示结束成功 返回1 表示退出安装
  5. Function KillProc
  6. 	#此处检测当前是否有程序正在运行，如果正在运行，提示先卸载再安装 
  7. 	nsProcess::_FindProcess "${EXE_NAME}"
  8. 	Pop $R0
  9.  
  10. 	#验证查询结果
  11. 	${If} $R0 == 0
  12. 		; 弹框提示
  13.         StrCpy $R8 "检测到 ${EXE_NAME} 正在运行。点击 “确定” 结束进程${EXE_NAME}，继续安装。点击 “取消” 退出安装程序。"
  14. 		StrCpy $R7 "1"
  15. 		Call ShowMsgBox
  16.  
  17. 		Pop $0
  18. 		; 结束进程
  19. 		${If} $0 == 1
  20. 			; 设置安装提示
  21. 			nsNiuniuSkin::SetControlAttribute $hInstallDlg "progress_tip" "text" "正在安全的结束进程,请稍后..."
  22. 			#结束进程
  23.    			KillProcDLL::KillProc"${EXE_NAME}"
  24. 		${Else}
  25. 			#设置返回值
  26. 			push 1
  27. 			; 退出
  28. 			goto KillProcEnd
  29. 		${EndIf}
  30.  
  31. 		#循环验证
  32.    		${For} $R1 0 100
  33. 		   	#等待100毫秒再查询结果
  34.       		Sleep 100
  35. 			#接收结果
  36. 			nsProcess::_FindProcess "${EXE_NAME}"
  37. 			#检测进程
  38. 			Pop $R0
  39. 			; 判断进程是否存在
  40. 			${If} $R0 != 0
  41. 				#设置返回值
  42. 				push 0
  43. 				; 查找进程结束
  44. 				goto KillProcEnd
  45. 			${EndIf}
  46. 		${Next}
  47.  
  48. 		; 弹框提示
  49.         StrCpy $R8 "我们无法安全的结束正在运行的 ${EXE_NAME} 应用程序,请手动退出应用程序,再尝试安装!"
  50. 		StrCpy $R7 "0"
  51. 		Call ShowMsgBox
  52. 		#设置返回值
  53. 		push 1
  54. 	; 结束
  55. 	KillProcEnd:
  56.     ${EndIf}
  57. FunctionEnd

 

创建桌面快捷方式

  1. ;创建桌面快捷方式
  2. Function CreateDeskTopIco   
  3.     #添加到桌面快捷方式的动作在此添加  
  4. 	SetShellVarContext all
  5. 	CreateShortCut "$DESKTOP\${PRODUCT_NAME}.lnk" "$INSTDIR\${EXE_NAME}"	
  6. 	SetShellVarContext current	
  7. FunctionEnd

 

创建任务栏快捷方式

注：Win10下可能存在问题，系统机制原因

  1. ;创建任务栏快捷方式
  2. Function CreateBarlnk    
  3.   ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"    
  4.   ${if} $R0 >= 6.0  
  5.      SetOutPath $INSTDIR  
  6. 	 ;注意这句与下一句是有先后顺序的(与ExecShell taskbarpin关联)
  7.      CreateShortCut "$DESKTOP\${PRODUCT_NAME}.lnk" "$INSTDIR\${EXE_NAME}"
  8.      ;创建任务栏快捷方式(win10系统会失败,并且导致程序运行)
  9.      ;ExecShell taskbarpin "$DESKTOP\${PRODUCT_NAME}.lnk"
  10. 	 ${StdUtils.InvokeShellVerb} $0 "$INSTDIR" "${EXE_NAME}" ${StdUtils.Const.ShellVerb.PinToTaskbar}
  11.   ${else}   
  12.      CreateShortCut "$QUICKLAUNCH\${PRODUCT_NAME}.lnk" "$INSTDIR\${EXE_NAME}"  
  13.   ${Endif}  
  14. FunctionEnd

 

添加开机启动

注：应用软件如果需要管理员身份启动，开机可能无法正常启动

  1. ; 创建开机启动
  2. ; 备注:开机启动的项目不能为管理员身份启动，否则会启动不起来
  3. Function CreateBootStart
  4. 	WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Run" "${PRODUCT_NAME}" "$INSTDIR\${EXE_NAME}"
  5. FunctionEnd

 

创建开始菜单

  1. Function CreateAppShortcut
  2.   SetShellVarContext all
  3.   CreateDirectory "$SMPROGRAMS\${PRODUCT_NAME}"
  4.   CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\${PRODUCT_NAME}.lnk" "$INSTDIR\${EXE_NAME}"
  5.   CreateShortCut "$SMPROGRAMS\${PRODUCT_NAME}\卸载${PRODUCT_NAME}.lnk" "$INSTDIR\uninst.exe"
  6.   SetShellVarContext current
  7. FunctionEnd

 

创建卸载信息

  1. # 生成卸载入口 
  2. Function CreateUninstall
  3. 	#写入注册信息 
  4. 	SetRegView 32
  5. 	WriteRegStr HKLM "Software\${PRODUCT_PATHNAME}" "InstPath" "$INSTDIR"
  6. 	
  7. 	; WriteUninstaller "$INSTDIR\uninst.exe"
  8. 	
  9. 	# 添加卸载信息到控制面板
  10. 	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_PATHNAME}" "DisplayName" "${PRODUCT_NAME}"
  11. 	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_PATHNAME}" "UninstallString" "$INSTDIR\uninst.exe"
  12. 	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_PATHNAME}" "DisplayIcon" "$INSTDIR\${EXE_NAME}"
  13. 	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_PATHNAME}" "Publisher" "${PRODUCT_PUBLISHER}"
  14. 	WriteRegStr HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_PATHNAME}" "DisplayVersion" "${PRODUCT_VERSION}"
  15. FunctionEnd

 

卸载-删除快捷方式

  1. ;卸载时删除任务栏快捷方式
  2. Function un.DelBarlnk
  3.   ReadRegStr $R0 HKLM "SOFTWARE\Microsoft\Windows NT\CurrentVersion" "CurrentVersion"  
  4.   ${if} $R0 >= 6.0  
  5.   ;win10系统会有问题
  6.   ExecShell taskbarunpin "$DESKTOP\${PRODUCT_NAME}.lnk"
  7.   ${StdUtils.InvokeShellVerb} $0 "$INSTDIR" "${EXE_NAME}" ${StdUtils.Const.ShellVerb.UnpinFromTaskbar}
  8.  
  9.   Delete "$DESKTOP\${PRODUCT_NAME}.lnk"  
  10.   ${else}  
  11.   delete "$QUICKLAUNCH\${PRODUCT_NAME}.lnk"  
  12.   ${Endif}  
  13. FunctionEnd
  14.  
  15. ;删除开始菜单，桌面图标
  16. Function un.DeleteShotcutAndInstallInfo
  17. 	SetRegView 32
  18. 	DeleteRegKey HKLM "Software\${PRODUCT_PATHNAME}"	
  19. 	DeleteRegKey HKLM "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT_PATHNAME}"
  20. 	
  21. 	; 删除快捷方式
  22. 	SetShellVarContext all
  23. 	Delete "$SMPROGRAMS\${PRODUCT_NAME}\${PRODUCT_NAME}.lnk"
  24. 	Delete "$SMPROGRAMS\${PRODUCT_NAME}\卸载${PRODUCT_NAME}.lnk"
  25. 	RMDir "$SMPROGRAMS\${PRODUCT_NAME}\"	
  26. 	Delete "$DESKTOP\${PRODUCT_NAME}.lnk"
  27. 	
  28. 	#删除开机启动  
  29.   Delete "$SMSTARTUP\${PRODUCT_NAME}.lnk"
  30. 	SetShellVarContext current
  31. FunctionEnd

 

卸载删除开机启动

  1. ;卸载时删除开机启动 
  2. Function un.DelBootStart
  3.   DeleteRegValue HKCU "Software\Microsoft\Windows\CurrentVersion\Run" "${PRODUCT_NAME}"
  4. FunctionEnd

 

打开链接

  1. ; 打开链接
  2. !define OpenURL '!insertmacro "_OpenURL"'
  3.  
  4. ; 打开链接
  5. !macro _OpenURL URL
  6. 	Push "${URL}"
  7. 	Call openLinkNewWindow
  8. !macroend
  9.  
  10. ; 新窗口打开链接
  11. Function openLinkNewWindow
  12.   Push $3
  13.   Exch
  14.   Push $2
  15.   Exch
  16.   Push $1
  17.   Exch
  18.   Push $0
  19.   Exch
  20.  
  21.   ReadRegStr $0 HKCR "http\shell\open\command" ""
  22. # Get browser path
  23.     DetailPrint $0
  24.   StrCpy $2 '"'
  25.   StrCpy $1 $0 1
  26.   StrCmp $1 $2 +2 # if path is not enclosed in " look for space as final char
  27.     StrCpy $2 ' '
  28.   StrCpy $3 1
  29.   loop:
  30.     StrCpy $1 $0 1 $3
  31.     DetailPrint $1
  32.     StrCmp $1 $2 found
  33.     StrCmp $1 "" found
  34.     IntOp $3 $3 + 1
  35.     Goto loop
  36.  
  37.   found:
  38.     StrCpy $1 $0 $3
  39.     StrCmp $2 " " +2
  40.       StrCpy $1 '$1"'
  41.  
  42.   Pop $0
  43.   Exec '$1 $0'
  44.   Pop $0
  45.   Pop $1
  46.   Pop $2
  47.   Pop $3
  48. FunctionEnd
  49.  
  50. ;使用示例
  51. ${OpenURL} "www.baidu.com"

 

完整源码下载

https://github.com/zhaobangyu/NSIS/tree/NsisPackage

声明：本文内容由网友自发贡献，不代表【wpsshop博客】立场，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：https://www.wpsshop.cn/w/凡人多烦事01/article/detail/112615
推荐阅读
相关标签

Copyright © 2003-2013 www.wpsshop.cn 版权所有，并保留所有权利。

  

闽ICP备14008679号