devbox
喵喵爱编程
这个屌丝很懒，什么也没留下！
关注作者
热门标签
热门文章
当前位置:   article > 正文

搞定秋招！3W字LLM高频面试题汇总：大模型手撕CUDA

作者：喵喵爱编程 | 2024-07-20 10:58:33

赞

踩

cuda 手写kernel 面试

作者 | DefTruth  编辑 | 自动驾驶之心

原文链接：https://zhuanlan.zhihu.com/p/678903537

点击下方卡片，关注“自动驾驶之心”公众号

戳我-> 领取自动驾驶近15个方向学习路线

>>点击进入→自动驾驶之心『大模型』技术交流群

本文只做学术分享，如有侵权，联系删文

0x00 前言

dd8f04d9048b2c02bb69499ce19278fb.png

前段时间参加了一些大模型的面试，大部分都要手撕CUDA，因此也整体复习了一遍CUDA优化相关的内容，整理了一些高频题的基本写法，保存在这里也便于日后自己复习。当然，有些代码不一定是最优化解，比如GEMM，想要在面试短短的30分钟内写一个好的GEMM Kernel，是有些难度的。印象比较深刻的是，其中有一场面试2个多小时，一个小时问项目，剩下一个小时在写GEMM，说实话，如果不是事先有准备过一些，直接上手写优化版还是会有点慌。就自己的经验而言，命中率还挺高（目前还没有遇到这些题目之外的），考虑深度优化的，一般也不会让你在面试短短几十分钟手撸出来。要是遇到有面试官让你手撸一个FlashAttention，那说明，你们实在是没有缘分，还是尽早好聚好散的好，或者提前结束面试，把时间省下来，出去吃顿烧烤也不错...，附GitHub链接：

https://github.com/DefTruth/cuda-learn-note
github.com/DefTruth/cuda-learn-note

TIPS: 文章整理为方便自己复习，不喜欢的请自动跳过哈。

0x01 高频面试题汇总简介

相关kernel如下。也就是不到1000行代码，建议背下来，我个人是喜欢背记，背的过程中基本就慢慢理解所有细节。当然，每个人的学习方法都不一样哈，自己觉得舒服就行。

  • sgemm naive, sgemm + block-tile + k-tile + vec4

  • sgemv k32/k128/k16 kernel

  • warp/block reduce sum/max, block all reduce + vec4

  • dot product, dot product + vec4

  • elementwise, elementwise + vec4

  • histogram, histogram + vec4

  • softmax, softmax + vec4 (grid level memory fence)

  • sigmoid, sigmoid + vec4

  • relu, relu + vec4

  • layer_norm, layer_norm + vec4

  • rms_norm, rms_norm + vec4

  • ....

题内话，大模型相关的岗位，手撕CUDA的概率非常大，leetcode反而写的少，就前段时间个人的经验，基本是4:1的比例，还是建议好好复习下CUDA。当然，这些只是最简单的kernel实现，比如flash_attn，FMHA这些优化手段，就不在这篇文章里写了，面试中基本都会问到。FlashAttention系列原理详解，可以看我写的另一篇文章：

0x02 sgemm naive, sgemm + block-tile + k-tile + vec4

  1. #include <stdio.h>
  2. #include <stdlib.h>
  3. #include <float.h>
  4. #include <vector>
  5. #include <algorithm>
  6. #include <cuda_runtime.h>
  7.  
  8. #define WARP_SIZE 32
  9. #define INT4(value) (reinterpret_cast<int4*>(&(value))[0])
  10. #define FLOAT4(value) (reinterpret_cast<float4*>(&(value))[0])
  11.  
  12. // SGEMM: Block Tile + K Tile, with smem
  13. // Block Tile (BM, BN) + K Tile (BK=32)
  14. // grid((N + BN - 1) / BN, (M + BM - 1) / BM), block(BN, BM)
  15. // a: MxK, b: KxN, c: MxN, compute: c = a * b, all row major  
  16. __global__ void sgemm(float* a, float* b, float* c, int M, int N, int K) {
  17.   // [1] Block Tile: 32x32的block处理c上一块32x32的元素计算
  18.   // [2]     K Tile: 使用共享内存，并将K分块为BK大小的块
  19.   constexpr int BM = 32;
  20.   constexpr int BN = 32;
  21.   constexpr int BK = 32;
  22.   __shared__ float s_a[BM][BK], s_b[BK][BN]; 
  23.  
  24.   int bx = blockIdx.x;
  25.   int by = blockIdx.y;
  26.   int tx = threadIdx.x;
  27.   int ty = threadIdx.y;
  28.   int tid = threadIdx.y * blockDim.x + tx; // tid within the block
  29.   // load values to shared memory, 32x32 threads working together 
  30.   // to fetch data along the row direction of a and b both for s_a 
  31.   // and s_b 32x32x4x2=8KB, we use 32x32 threads within block to 
  32.   // load 32x32 elements from global memory to shared memory, namely, 
  33.   // each thread will load 1 element.
  34.   int load_smem_a_m = tid / 32; // 0~31, tid / 32, tid / BM, threadIdx.y
  35.   int load_smem_a_k = tid % 32; // 0~31, tid % 32, tid % BK, threadIdx.x
  36.   int load_smem_b_k = tid / 32; // 0~31, tid / 32, tid / BK, threadIdx.y
  37.   int load_smem_b_n = tid % 32; // 0~31, tid % 32, tid % BN, threadIdx.x
  38.   int load_gmem_a_m = by * BM + load_smem_a_m; // global row of a and c
  39.   int load_gmem_b_n = bx * BN + load_smem_b_n; // global col of b and c
  40.   // if (load_gmem_a_m >= M || load_gmem_b_n >= N) return;
  41.   
  42.   float sum = 0.f;
  43.   for (int bk = 0; bk < (K + BK - 1) / BK; ++bk) {
  44.     int load_gmem_a_k = bk * BK + load_smem_a_k;
  45.     int load_gmem_a_addr = load_gmem_a_m * K + load_gmem_a_k;
  46.     s_a[load_smem_a_m][load_smem_a_k] = a[load_gmem_a_addr];
  47.     int load_gmem_b_k = bk * BK + load_smem_b_k;
  48.     int load_gmem_b_addr = load_gmem_b_k * N + load_gmem_b_n;
  49.     s_b[load_smem_b_k][load_smem_b_n] = b[load_gmem_b_addr];
  50.     __syncthreads();
  51.     #pragma unroll
  52.     for (int k = 0; k < BK; ++k) {
  53.       int comp_smem_a_m = load_smem_a_m;
  54.       int comp_smem_b_n = load_smem_b_n;
  55.       sum += s_a[comp_smem_a_m][k] * s_b[k][comp_smem_b_n];
  56.     }
  57.     __syncthreads();
  58.   }
  59.   int store_gmem_c_m = load_gmem_a_m;
  60.   int store_gmem_c_n = load_gmem_b_n;
  61.   int store_gmem_c_addr = store_gmem_c_m * N + store_gmem_c_n;
  62.   c[store_gmem_c_addr] = sum;
  63. }
  64.  
  65. // SGEMM: Block Tile + Thread Tile + K Tile + Vec4, with smem
  66. // BK:TILE_K=8 BM=BN=128
  67. // TM=TN=8 增加计算密度 BM/TM=16 BN/TN=16
  68. // dim3 blockDim(BN/TN, BM/TM);
  69. // dim3 gridDim((N + BN - 1) / BN, (M + BM - 1) / BM)
  70. __global__ void sgemm_thread_tile_vec4(
  71.   float* a, float* b, float* c, int M, int N, int K) {
  72.   // [1]  Block Tile: 一个16x16的block处理C上大小为128X128的一个目标块
  73.   // [2] Thread Tile: 每个thread负责计算TM*TN(8*8)个元素，增加计算密度
  74.   // [3]      K Tile: 将K分块，每块BK大小，迭代(K+BK-1/BK)次，
  75.   //                  每次计算TM*TN个元素各自的部分乘累加
  76.   // [4]   Vectorize: 减少load和store指令，使用float4
  77.   constexpr int BM = 128;
  78.   constexpr int BN = 128;
  79.   constexpr int BK = 8; 
  80.   constexpr int TM = 8;
  81.   constexpr int TN = 8;
  82.  
  83.   int bx = blockIdx.x;
  84.   int by = blockIdx.y;
  85.   int tx = threadIdx.x;
  86.   int ty = threadIdx.y;
  87.   int tid = threadIdx.y * blockDim.x + tx; // tid within the block
  88.   __shared__ float s_a[BM][BK], s_b[BK][BN]; // 2*128*8*4=8KB
  89.   
  90.   // 0. 先计算shared memory中的索引
  91.   // tid和需要加载的smem s_a[BM][BK] 之间的索引关系 BM=128 BK=8 按行读取 A行主序
  92.   // 对于s_a每行8个数据，每个线程读取4个，需要2个线程；总共128行，需要128x2刚好256线程
  93.   int load_smem_a_m = tid / 2; // tid/2 (128/8)*(128/8)=256 threads per block, tid/2->[0,128), BM=128 0~127
  94.   int load_smem_a_k = (tid % 2 == 0) ? 0 : 4;  // (tid%2 == 0) ? 0 : 4, col of s_a 0,4
  95.   // tid和需要加载的smem s_b[BK][BN] 之间的索引关系 BK=8 BN=128 按行读取 B行主序
  96.   // 对于s_b每行128个数据，每个线程读4个数据，需要32个线程；总共8行，需要32x8=256个线程
  97.   int load_smem_b_k = tid / 32; // tid/32, row of s_b 256/32=8 行 0~7
  98.   int load_smem_b_n = (tid % 32) * 4;  // (tid % 32) * 4, col of s_b 0,4,...,124
  99.   // 1. 再计算全局内存中的索引
  100.   // 要加载到s_a中的元素对应到A全局内存中的行数 每个block负责出C中大小为BM*BN的块
  101.   int load_gmem_a_m = by * BM + load_smem_a_m; // global row of a and c
  102.   int load_gmem_b_n = bx * BN + load_smem_b_n; // global col of b and c
  103.   
  104.   float r_c[TM][TN] = {0.0}; // 8x8
  105.   // 2. 先对K进行分块，每块BK大小
  106.   for (int bk = 0; bk < (K + BK - 1) / BK; ++bk) {
  107.     // 加载数据到共享内存smem s_a BM*BK 128*8 vectorize float4
  108.     int load_gmem_a_k = bk * BK + load_smem_a_k; // global col of a
  109.     int load_gmem_a_addr = load_gmem_a_m * K + load_gmem_a_k;
  110.     FLOAT4(s_a[load_smem_a_m][load_smem_a_k]) = FLOAT4(a[load_gmem_a_addr]);
  111.     // 加载数据到共享内存smem s_b BK*BN 8*128 vectorize float4
  112.     int load_gmem_b_k = bk * BK + load_smem_b_k; // global row of b
  113.     int load_gmem_b_addr = load_gmem_b_k * N + load_gmem_b_n; 
  114.     FLOAT4(s_b[load_smem_b_k][load_smem_b_n]) = FLOAT4(b[load_gmem_b_addr]); 
  115.     __syncthreads();
  116.     #pragma unroll
  117.     for (int k = 0; k < BK; k++) {
  118.       // 3. 每个线程负责计算BM*BN(12x128)中的TM*TN(8x8)个元素
  119.       #pragma unroll
  120.       for (int m = 0; m < TM; m++) {
  121.         #pragma unroll
  122.         for (int n = 0; n < TN; n++) {
  123.           // k from 0~7，0 ~ BK, ty and tx range from 0 to 15, 16x8=128
  124.           int comp_smem_a_m = ty * TM + m;  // 128*8 128/TM(8)=16 M方向 16线程
  125.           int comp_smem_b_n = tx * TN + n;  // 8*128 128/TN(8)=16 N方向 16线程
  126.           r_c[m][n] += s_a[comp_smem_a_m][k] * s_b[k][comp_smem_b_n];
  127.         }
  128.       }
  129.     }
  130.     __syncthreads();
  131.   }
  132.  
  133.   #pragma unroll
  134.   for (int m = 0; m < TM; ++m) {
  135.     int store_gmem_c_m = by * BM + ty * TM + m;
  136.     #pragma unroll
  137.     for (int n = 0; n < TN; n += 4) {
  138.       int store_gmem_c_n = bx * BN + tx * TN + n;
  139.       int store_gmem_c_addr = store_gmem_c_m * N + store_gmem_c_n;
  140.       FLOAT4(c[store_gmem_c_addr]) = FLOAT4(r_c[m][n]);
  141.     }
  142.   }
  143. }

这里gemm的实现比较简单，只使用了CUDA Cores，并且只实现Block Tile + K Tile以及Block Tile + K Tile+Thread Tile+向量化的版本。主要在于如何加载gmem中的数据到smem，也就是把全局内存中的数据索引mapping到共享内存中的。核心思维：把一个block中的线程id按照线性来理解，然后把这个线性的id和全局内存索引以及共享内存索引进行匹配。比如Block Tile + K Tile的实现，block内一共32x32个Threads，需要加载到smem的数据也是32x32，那么，最简单的做法，只需要每个线程加载一个互不重复数据即可。NOTE，本文的gemm kernel修改自：紫气东来：CUDA（三）：通用矩阵乘法：从入门到熟练

0x03 warp/block reduce sum/max

  1. // Warp Reduce Sum
  2. template<const int kWarpSize = WARP_SIZE>
  3. __device__ __forceinline__ float warp_reduce_sum(float val) {
  4.   #pragma unroll
  5.   for (int mask = kWarpSize >> 1; mask >= 1; mask >>= 1) {
  6.     val += __shfl_xor_sync(0xffffffff, val, mask);
  7.   }
  8.   return val;
  9. }
  10.  
  11. // Warp Reduce Max
  12. template<const int kWarpSize = WARP_SIZE>
  13. __device__ __forceinline__ float warp_reduce_max(float val) {
  14.   #pragma unroll
  15.   for (int mask = kWarpSize >> 1; mask >= 1; mask >>= 1) {
  16.     val = fmaxf(val, __shfl_xor_sync(0xffffffff, val, mask));
  17.   }
  18.   return val;
  19. }
  20.  
  21. // Block reduce sum/max/min device helper for Layer/RMS Norm/Softmax etc.
  22. // grid 1D block 1D, grid(N/128), block(128)
  23. template<const int NUM_THREADS=128>
  24. __device__ __forceinline__ float block_reduce_sum(float val) {
  25.   // always <= 32 warps per block (limited by 1024 threads per block)
  26.   constexpr int NUM_WARPS = (NUM_THREADS + WARP_SIZE - 1) / WARP_SIZE;
  27.   int warp = threadIdx.x / WARP_SIZE;
  28.   int lane = threadIdx.x % WARP_SIZE;
  29.   static __shared__ float shared[NUM_WARPS];
  30.   
  31.   val = warp_reduce_sum<WARP_SIZE>(val);
  32.   if (lane == 0) shared[warp] = val;
  33.   __syncthreads();
  34.   val = (lane < NUM_WARPS) ? shared[lane] : 0.0f;
  35.   val = warp_reduce_sum<NUM_WARPS>(val);
  36.   return val;
  37. }
  38.  
  39. template<const int NUM_THREADS=128>
  40. __device__ __forceinline__ float block_reduce_max(float val) {
  41.   // always <= 32 warps per block (limited by 1024 threads per block)
  42.   constexpr int NUM_WARPS = (NUM_THREADS + WARP_SIZE - 1) / WARP_SIZE;
  43.   int warp = threadIdx.x / WARP_SIZE;
  44.   int lane = threadIdx.x % WARP_SIZE;
  45.   static __shared__ float shared[NUM_WARPS];
  46.   
  47.   val = warp_reduce_max<WARP_SIZE>(val);
  48.   if (lane == 0) shared[warp] = val;
  49.   __syncthreads();
  50.   val = (lane < NUM_WARPS) ? shared[lane] : -FLT_MAX;
  51.   val = warp_reduce_max<NUM_WARPS>(val);
  52.   return val;
  53. }

warp reduce几乎已经成为大部分reduce kernel的标准写法了，比如vLLM中，就是这种经典的写法。所以，先搞懂warp reduce（也就是搞懂各种warp functions的用法），再去写其他kernel，思路就会容易很多。需要注意的是，warp函数处理的是寄存器上的数据，也就是说，此时，没必要先加载数据到smem，再进行reduce，直接加载到寄存器即可（以前犯过这个小错误...）。Warp Functions建议参考：jhang：CUDA编程入门之Warp-Level Primitives

0x04 block all reduce + vec4

  1. // Block All Reduce Sum
  2. // grid(N/128), block(128)
  3. // a: Nx1, y=sum(a)
  4. template<const int NUM_THREADS = 128>
  5. __global__ void block_all_reduce_sum(float* a, float* y, int N) {
  6.   int tid = threadIdx.x;
  7.   int idx = blockIdx.x * NUM_THREADS + tid;
  8.   constexpr int NUM_WARPS = (NUM_THREADS + WARP_SIZE - 1) / WARP_SIZE;
  9.   __shared__ float reduce_smem[NUM_WARPS];
  10.   // keep the data in register is enougth for warp operaion.
  11.   float sum = (idx < N) ? a[idx] : 0.0f;
  12.   int warp = tid / WARP_SIZE;
  13.   int lane = tid % WARP_SIZE;
  14.   // perform warp sync reduce.
  15.   sum = warp_reduce_sum<WARP_SIZE>(sum);
  16.   // warp leaders store the data to shared memory.
  17.   if (lane == 0) reduce_smem[warp] = sum;
  18.   __syncthreads(); // make sure the data is in shared memory.
  19.   // the first warp compute the final sum.
  20.   sum = (lane < NUM_WARPS) ? reduce_smem[lane] : 0.0f;
  21.   if (warp == 0) sum = warp_reduce_sum<NUM_WARPS>(sum);
  22.   if (tid == 0) atomicAdd(y, sum);
  23. }
  24.  
  25. // Block All Reduce Sum + float4
  26. // grid(N/128), block(128/4)
  27. // a: Nx1, y=sum(a)
  28. template<const int NUM_THREADS = 128/4>
  29. __global__ void block_all_reduce_sum_vec4(float* a, float* y, int N) {
  30.   int tid = threadIdx.x;
  31.   int idx = (blockIdx.x * NUM_THREADS + tid) * 4;
  32.   constexpr int NUM_WARPS = (NUM_THREADS + WARP_SIZE - 1) / WARP_SIZE;
  33.   __shared__ float reduce_smem[NUM_WARPS];
  34.  
  35.   float4 reg_a = FLOAT4(a[idx]);
  36.   // keep the data in register is enougth for warp operaion.
  37.   float sum = (idx < N) ? (reg_a.x + reg_a.y + reg_a.z + reg_a.w) : 0.0f;
  38.   int warp = tid / WARP_SIZE;
  39.   int lane = tid % WARP_SIZE;
  40.   // perform warp sync reduce.
  41.   sum = warp_reduce_sum<WARP_SIZE>(sum);
  42.   // warp leaders store the data to shared memory.
  43.   if (lane == 0) reduce_smem[warp] = sum;
  44.   __syncthreads(); // make sure the data is in shared memory.
  45.   // the first warp compute the final sum.
  46.   sum = (lane < NUM_WARPS) ? reduce_smem[lane] : 0.0f;
  47.   if (warp == 0) sum = warp_reduce_sum<NUM_WARPS>(sum);
  48.   if (tid == 0) atomicAdd(y, sum);
  49. }

block all reduce是在warp reduce的基础上进行的，reduce_smem这部分的共享内存申请无法避免，这是用来同步每个warp之间得到局部结果。注意，最后，还需要atomicAdd做一个block级别的原子操作，以得到全局的和。float4向量化优化访存，可以减缓WarpScheduler发送指令的压力。

0x05 sgemv k32/k128/k16 kernel

  1. // SGEMV: Warp SGEMV K32
  2. // 假设K为32的倍数，每个warp负责一行
  3. // grid(M/4), block(32,4) blockDim.x=32=K, blockDim.y=4
  4. // a: MxK, x: Kx1, y: Mx1, compute: y = a * x
  5. __global__ void sgemv_k32(float* a, float* x, float* y, int M, int K) {
  6.   int tx = threadIdx.x;         // 0~31
  7.   int ty = threadIdx.y;         // 0~4
  8.   int bx = blockIdx.x;          // 0~M/4
  9.   int lane = tx % WARP_SIZE;    // 0~31
  10.   int m = bx * blockDim.y + ty; // (0~M/4) * 4 + (0~3)
  11.   if (m < M) {
  12.     float sum = 0.0f;
  13.     int NUM_WARPS = (K + WARP_SIZE - 1) / WARP_SIZE;
  14.     #pragma unroll
  15.     for (int w = 0; w < NUM_WARPS; ++w) {
  16.       // 若NUM_WARPS>=2，先将当前行的数据累加到第一个warp中
  17.       int k = w * WARP_SIZE + lane;
  18.       sum += a[m * K + k] * x[k];
  19.     }
  20.     sum = warp_reduce_sum<WARP_SIZE>(sum);
  21.     if (lane == 0) y[m] = sum;
  22.   }
  23. }
  24.  
  25. // SGEMV: Warp SGEMV K128 + Vec4
  26. // 假设K为128的倍数 float4
  27. // grid(M/4), block(32,4) blockDim.x=32=K, blockDim.y=4
  28. // a: MxK, x: Kx1, y: Mx1, compute: y = a * x
  29. __global__ void sgemv_k128(float* a, float* x, float* y, int M, int K) {
  30.   // 每个线程负责4个元素，一个warp覆盖128个元素
  31.   int tx = threadIdx.x;         // 0~31
  32.   int ty = threadIdx.y;         // 0~3
  33.   int bx = blockIdx.x;          // 0~M/4
  34.   int lane = tx % WARP_SIZE;    // 0~31
  35.   int m = blockDim.y * bx + ty; // (0~M/4) * 4 + (0~3)
  36.   
  37.   if (m < M) {
  38.     float sum = 0.0f;
  39.     // process 4*WARP_SIZE elements per warp.
  40.     int NUM_WARPS = (((K + WARP_SIZE - 1) / WARP_SIZE) + 4 - 1) / 4;
  41.     #pragma unroll
  42.     for (int w = 0; w < NUM_WARPS; ++w) {
  43.       int k = (w * WARP_SIZE + lane) * 4;
  44.       float4 reg_x = FLOAT4(x[k]);
  45.       float4 reg_a = FLOAT4(a[m * K + k]);
  46.       sum += (reg_a.x * reg_x.x + reg_a.y * reg_x.y 
  47.             + reg_a.z * reg_x.z + reg_a.w * reg_x.w);
  48.     }
  49.     sum = warp_reduce_sum<WARP_SIZE>(sum);
  50.     if(lane == 0) y[m] = sum;
  51.   }
  52. }
  53.  
  54. // SGEMV: Warp SGEMV K16
  55. // 假设K为16 < 32,每个warp负责2行，每行有16个元素
  56. // NUM_THREADS=128, NUM_WARPS=NUM_THREADS/WARP_SIZE;
  57. // NUM_ROWS=NUM_WARPS * ROW_PER_WARP, grid(M/NUM_ROWS), block(32,NUM_WARPS)
  58. // a: MxK, x: Kx1, y: Mx1, compute: y = a * x
  59. template<const int ROW_PER_WARP = 2> 
  60. __global__ void sgemv_k16(float* A, float* x, float* y, int M, int K) {
  61.   constexpr int K_WARP_SIZE = (WARP_SIZE + ROW_PER_WARP - 1) / ROW_PER_WARP;
  62.   int tx = threadIdx.x;       // 0~31
  63.   int ty = threadIdx.y;       // 0~NUM_WARPS
  64.   int bx = blockIdx.x;        // 0~M/NUM_ROWS (NUM_ROWS=NUM_WARPS * ROW_PER_WARP)
  65.   int lane = tx % WARP_SIZE;  // 0~31
  66.   int k = lane % K_WARP_SIZE; // 0~15
  67.   // gloabl row of a: MxK and y:Mx1, blockDim.y=NUM_WARPS
  68.   int m = (blockDim.y * bx + ty) * ROW_PER_WARP + lane / K_WARP_SIZE;
  69.   if (m < M) {
  70.     float sum = A[m * K + k] * x[k];
  71.     sum = warp_reduce_sum<K_WARP_SIZE>(sum);
  72.     // 注意是k == 0，而不是lane == 0
  73.     if(k == 0) y[m] = sum; 
  74.   }
  75. }

估计有些大佬倒立都能写sgemv的各种优化版了，核心思路其实也是基于warp reduce，考虑K的不同情况进行优化。本文的sgemv kernel修改自：有了琦琦的棍子：深入浅出GPU优化系列：gemv优化

0x06 dot product, dot product + vec4

  1. // Dot Product
  2. // grid(N/128), block(128)
  3. // a: Nx1, b: Nx1, y=sum(elementwise_mul(a,b))
  4. template<const int NUM_THREADS = 128>
  5. __global__ void dot(float* a, float* b, float* y, int N) {
  6.   int tid = threadIdx.x;
  7.   int idx = blockIdx.x * NUM_THREADS + tid;
  8.   constexpr int NUM_WARPS = (NUM_THREADS + WARP_SIZE - 1) / WARP_SIZE;
  9.   __shared__ float reduce_smem[NUM_WARPS];
  10.  
  11.   // keep the data in register is enougth for warp operaion.
  12.   float prod = (idx < N) ? a[idx] * b[idx] : 0.0f;
  13.   int warp = tid / WARP_SIZE;
  14.   int lane = tid % WARP_SIZE;
  15.   // perform warp sync reduce.
  16.   prod = warp_reduce_sum<WARP_SIZE>(prod);
  17.   // warp leaders store the data to shared memory.
  18.   if (lane == 0) reduce_smem[warp] = prod;
  19.   __syncthreads(); // make sure the data is in shared memory.
  20.   // the first warp compute the final sum.
  21.   prod = (lane < NUM_WARPS) ? reduce_smem[lane] : 0.0f;
  22.   if (warp == 0) prod = warp_reduce_sum<NUM_WARPS>(prod);
  23.   if (tid == 0) atomicAdd(y, prod);
  24. }
  25.  
  26. // Dot Product + Vec4
  27. // grid(N/128), block(128/4)
  28. // a: Nx1, b: Nx1, y=sum(elementwise_mul(a,b))
  29. template<const int NUM_THREADS = 128/4>
  30. __global__ void dot_vec4(float* a, float* b, float* y, int N) {
  31.   int tid = threadIdx.x;
  32.   int idx = (blockIdx.x * NUM_THREADS + tid) * 4;
  33.   constexpr int NUM_WARPS = (NUM_THREADS + WARP_SIZE - 1) / WARP_SIZE;
  34.   __shared__ float reduce_smem[NUM_WARPS];
  35.  
  36.   float4 reg_a = FLOAT4(a[idx]);
  37.   float4 reg_b = FLOAT4(b[idx]);
  38.   float prod = (idx < N) ? (reg_a.x * reg_b.x + reg_a.y * reg_b.y 
  39.                           + reg_a.z * reg_b.z + reg_a.w * reg_b.w) : 0.0f;
  40.   int warp = tid / WARP_SIZE;
  41.   int lane = tid % WARP_SIZE;
  42.   // perform warp sync reduce.
  43.   prod = warp_reduce_sum<WARP_SIZE>(prod);
  44.   // warp leaders store the data to shared memory.
  45.   if (lane == 0) reduce_smem[warp] = prod;
  46.   __syncthreads(); // make sure the data is in shared memory.
  47.   // the first warp compute the final sum.
  48.   prod = (lane < NUM_WARPS) ? reduce_smem[lane] : 0.0f;
  49.   if (warp == 0) prod = warp_reduce_sum<NUM_WARPS>(prod);
  50.   if (tid == 0) atomicAdd(y, prod);
  51. }

dot product kernel的核心就是block reduce，不多说了。

0x07 elementwise, elementwise + vec4

  1. // ElementWise Add  
  2. // grid(N/128), block(128)
  3. // a: Nx1, b: Nx1, c: Nx1, c = elementwise_add(a, b)
  4. __global__ void elementwise_add(float* a, float* b, float* c, int N) {
  5.   int idx = blockIdx.x * blockDim.x + threadIdx.x;
  6.   if (idx < N) c[idx] = a[idx] + b[idx];
  7. }
  8.  
  9. // ElementWise Add + Vec4
  10. // grid(N/128), block(128/4)
  11. // a: Nx1, b: Nx1, c: Nx1, c = elementwise_add(a, b)
  12. __global__ void elementwise_add_vec4(float* a, float* b, float* c, int N) {
  13.   int idx = 4 * (blockIdx.x * blockDim.x + threadIdx.x);
  14.   if (idx < N) {
  15.     float4 reg_a = FLOAT4(a[idx]);
  16.     float4 reg_b = FLOAT4(b[idx]);
  17.     float4 reg_c;
  18.     reg_c.x = reg_a.x + reg_b.x;
  19.     reg_c.y = reg_a.y + reg_b.y;
  20.     reg_c.z = reg_a.z + reg_b.z;
  21.     reg_c.w = reg_a.w + reg_b.w;
  22.     FLOAT4(c[idx]) = reg_c;
  23.   }
  24. }

elementwise可以考虑加点向量化进行访存优化。

0x08 histogram, histogram + vec4

  1. // Histogram
  2. // grid(N/128), block(128)
  3. // a: Nx1, y: count histogram
  4. __global__ void histogram(int* a, int* y, int N) {
  5.   int idx = blockIdx.x * blockDim.x + threadIdx.x;
  6.   if (idx < N) atomicAdd(&(y[a[idx]]), 1);
  7. }
  8.  
  9. // Histogram + Vec4
  10. // grid(N/128), block(128/4)
  11. // a: Nx1, y: count histogram
  12. __global__ void histogram_vec4(int* a, int* y, int N) {
  13.   int idx = 4 * (blockIdx.x * blockDim.x + threadIdx.x);
  14.   if (idx < N) {
  15.     int4 reg_a = INT4(a[idx]);
  16.     atomicAdd(&(y[reg_a.x]), 1);
  17.     atomicAdd(&(y[reg_a.y]), 1);
  18.     atomicAdd(&(y[reg_a.z]), 1);
  19.     atomicAdd(&(y[reg_a.w]), 1);
  20.   }
  21. }

统计频数直方图，很简单，两行代码搞定。

0x09 softmax, softmax + vec4 (grid level memory fence)

  1. // Softmax x: N, y: N
  2. // grid(N/128), block(K=128)
  3. template<const int NUM_THREADS = 128>
  4. __global__ void softmax(float* x, float* y, float* total, int N) {
  5.   const int tid = threadIdx.x;
  6.   const int idx = blockIdx.x * blockDim.x + tid; 
  7.   constexpr int NUM_WARPS = (NUM_THREADS + WARP_SIZE - 1) / WARP_SIZE;
  8.   __shared__ float reduce_smem[NUM_WARPS];
  9.   
  10.   float sum = (idx < N) ? expf(x[idx]) : 0.0f;
  11.   int warp = tid / WARP_SIZE;
  12.   int lane = tid % WARP_SIZE;
  13.   sum = warp_reduce_sum<WARP_SIZE>(sum);
  14.   if (lane == 0) reduce_smem[warp] = sum;
  15.   __syncthreads();
  16.   // compute the final sum in each warp
  17.   sum = (lane < NUM_WARPS) ? reduce_smem[lane] : 0.0f;
  18.   sum = warp_reduce_sum<NUM_WARPS>(sum); // sum(e^x_0,...,e^x_n-1)
  19.   // get the total sum of all blocks.
  20.   if (tid == 0) atomicAdd(total, sum);
  21.   __threadfence(); // grid level memory fence 注意这里需要网格级别的内存同步
  22.   // e^x_i/sum(e^x_0,...,e^x_n-1) 
  23.   if (idx < N) y[idx] = block_smem[tid] / (*total); 
  24. }
  25.  
  26. // Softmax x: N, y: N
  27. // grid(N/128), block(K=128)
  28. template<const int NUM_THREADS = 128>
  29. __global__ void softmax_v2(float* x, float* y, float* total, int N) {
  30.   const int tid = threadIdx.x;
  31.   const int idx = blockIdx.x * blockDim.x + tid; 
  32.   
  33.   float exp_val = (idx < N) ? expf(x[idx]) : 0.0f;
  34.   float sum = block_reduce_sum<NUM_THREADS>(exp_val);
  35.   // get the total sum of all blocks.
  36.   if (tid == 0) atomicAdd(total, sum);
  37.   __threadfence(); // grid level memory fence  注意这里需要网格级别的内存同步
  38.   // e^x_i/sum(e^x_0,...,e^x_n-1) 
  39.   if (idx < N) y[idx] = exp_val / (*total); 
  40. }
  41.  
  42. // Softmax Vec4 x: N, y: N
  43. // grid(N/128), block(128/4)
  44. template<const int NUM_THREADS = 128/4>
  45. __global__ void softmax_v2_vec4(float* x, float* y, float* total, int N) {
  46.   const int tid = threadIdx.x;
  47.   const int idx = (blockIdx.x * blockDim.x + tid) * 4; 
  48.   
  49.   float4 reg_x = FLOAT4(x[idx]);
  50.   float4 reg_exp;
  51.   reg_exp.x = (idx < N) ? expf(reg_x.x) : 0.0f;
  52.   reg_exp.y = (idx < N) ? expf(reg_x.y) : 0.0f;
  53.   reg_exp.z = (idx < N) ? expf(reg_x.z) : 0.0f;
  54.   reg_exp.w = (idx < N) ? expf(reg_x.w) : 0.0f;
  55.   float exp_val = (reg_exp.x + reg_exp.y + reg_exp.z + reg_exp.w);
  56.   float sum = block_reduce_sum<NUM_THREADS>(exp_val);
  57.   // get the total sum of all blocks.
  58.   if (tid == 0) atomicAdd(total, sum);
  59.   __threadfence(); // grid level memory fence  注意这里需要网格级别的内存同步
  60.   // e^x_i/sum(e^x_0,...,e^x_n-1) 
  61.   if (idx < N) {
  62.     float4 reg_y;
  63.     reg_y.x = reg_exp.x / (*total);
  64.     reg_y.y = reg_exp.y / (*total);
  65.     reg_y.z = reg_exp.z / (*total);
  66.     reg_y.w = reg_exp.w / (*total);
  67.     FLOAT4(y[idx]) = reg_y; 
  68.   }
  69. }

softmax稍微要注意的就是内存同步的问题，这里，你需要做一个网格级别的同步，而不能仅仅是block级别，否则拿不到全局的exp sum作为分母项。因此使用 __threadfence 这个网格及内存同步操作。不过效率我还没测过，实在要高效的话，可能得整成FA2那样的 1-pass + online softmax的实现。不过，如果是面试的话，就不要太为难自己了... ，但是FA1/FA2的论文很经典，强烈建议多读几遍。

0x0a sigmoid, sigmoid + vec4

  1. // Sigmoid x: N, y: N y=1/(1+exp(-x))
  2. // grid(N/128), block(K=128) 
  3. __global__ void sigmoid(float* x, float* y, int N) {
  4.   int idx = blockIdx.x * blockDim.x + threadIdx.x;
  5.   if (idx < N) y[idx] = 1.0f / (1.0f + expf(-x[idx]));
  6. }
  7.  
  8. // Sigmoid x: N, y: N y=1/(1+exp(-x)) Vec4
  9. // grid(N/128), block(128/4)
  10. __global__ void sigmoid_vec4(float* x, float* y, int N) {
  11.   int idx = (blockIdx.x * blockDim.x + threadIdx.x) * 4;
  12.   if (idx < N) {
  13.     float4 reg_x = FLOAT4(x[idx]);
  14.     float4 reg_y;
  15.     reg_y.x = 1.0f / (1.0f + expf(-reg_x.x));
  16.     reg_y.y = 1.0f / (1.0f + expf(-reg_x.y));
  17.     reg_y.z = 1.0f / (1.0f + expf(-reg_x.z));
  18.     reg_y.w = 1.0f / (1.0f + expf(-reg_x.w));
  19.     FLOAT4(y[idx]) = reg_y;
  20.   }
  21. }

0x0b relu, relu + vec4

  1. // Relu x: N, y: N y=max(0,x)
  2. // grid(N/128), block(K=128) 
  3. __global__ void relu(float* x, float* y, int N) {
  4.   int idx = blockIdx.x * blockDim.x + threadIdx.x;
  5.   if (idx < N) y[idx] = fmaxf(0.0f, x[idx]);
  6. }
  7.  
  8. // Relu x: N, y: N y=max(0,x) Vec4
  9. // grid(N/128/4), block(128/4) 
  10. __global__ void relu_vec4(float* x, float* y, int N) {
  11.   int idx = (blockIdx.x * blockDim.x + threadIdx.x) * 4;
  12.   if (idx < N) {
  13.     float4 reg_x = FLOAT4(x[idx]);
  14.     float4 reg_y;
  15.     reg_y.x = fmaxf(0.0f, reg_x.x);
  16.     reg_y.y = fmaxf(0.0f, reg_x.y);
  17.     reg_y.z = fmaxf(0.0f, reg_x.z);
  18.     reg_y.w = fmaxf(0.0f, reg_x.w);
  19.     FLOAT4(y[idx]) = reg_y;
  20.   }
  21. }

0x0c layer_norm, layer_norm + vec4

  1. // Layer Norm: x: NxK(K=128<1024), y': NxK, y'=x-mean(x)/std(x) each row
  2. // mean(x) = sum(x)/K, 1/std(x) = rsqrtf( sum( (x-mean(x))^2 )/K ) each row
  3. // grid(N*K/K), block(K<1024) N=batch_size*seq_len, K=hidden_size
  4. // y=y'*g + b (g: scale, b: bias)
  5. template<const int NUM_THREADS=128>
  6. __global__ void layer_norm(float* x, float* y, float g, float b, int N, int K) {
  7.   int tid = threadIdx.x; // 0..K-1
  8.   int bid = blockIdx.x; // 0..N-1
  9.   int idx = bid * blockDim.x + threadIdx.x;
  10.   const float epsilon = 1e-5f;
  11.  
  12.   __shared__ float s_mean; // shared within block
  13.   __shared__ float s_variance; // shared within block
  14.   float value = (idx < N * K) ? x[idx] : 0.0f; // load once only
  15.   float sum = block_reduce_sum<NUM_THREADS>(value);
  16.   if (tid == 0) s_mean = sum / (float) K;
  17.   // wait for s_mean in shared memory to be ready for all threads
  18.   __syncthreads();
  19.   float variance = (value - s_mean) * (value - s_mean);
  20.   variance = block_reduce_sum<NUM_THREADS>(variance);
  21.   if (tid == 0) s_variance = rsqrtf(variance / (float) K + epsilon);
  22.   // wait for s_variance in shared memory to be ready for all threads
  23.   __syncthreads();
  24.   if (idx < N * K) y[idx] = ((value - s_mean) * s_variance) * g + b;
  25. }
  26.  
  27. // Layer Norm Vec4: x: NxK(K=128<1024), y': NxK, y'=x-mean(x)/std(x) each row
  28. // mean(x) = sum(x)/K, 1/std(x) = rsqrtf( sum( (x-mean(x))^2 )/K ) each row
  29. // grid(N*K/K), block(K/4<1024) N=batch_size*seq_len, K=hidden_size
  30. // y=y'*g + b (g: scale, b: bias)
  31. template<const int NUM_THREADS=128/4>
  32. __global__ void layer_norm_vec4(float* x, float* y, float g, float b, int N, int K) {
  33.   int tid = threadIdx.x; // 0..K-1
  34.   int bid = blockIdx.x; // 0..N-1
  35.   int idx = (bid * blockDim.x + threadIdx.x) * 4;
  36.   const float epsilon = 1e-5f;
  37.  
  38.   __shared__ float s_mean; // shared within block
  39.   __shared__ float s_variance; // shared within block
  40.   float4 reg_x = FLOAT4(x[idx])
  41.   float value = (idx < N * K) ? (reg_x.x + reg_x.y 
  42.                                + reg_x.z + reg_x.w) : 0.0f;
  43.   float sum = block_reduce_sum<NUM_THREADS>(value);
  44.   if (tid == 0) s_mean = sum / (float) K;
  45.   // wait for s_mean in shared memory to be ready for all threads
  46.   __syncthreads();
  47.   float4 reg_x_hat;
  48.   reg_x_hat.x = reg_x.x - s_mean;
  49.   reg_x_hat.y = reg_x.y - s_mean;
  50.   reg_x_hat.z = reg_x.z - s_mean;
  51.   reg_x_hat.w = reg_x.w - s_mean;
  52.   float variance = reg_x_hat.x * reg_x_hat.x + reg_x_hat.y * reg_x_hat.y 
  53.                  + reg_x_hat.z * reg_x_hat.z + reg_x_hat.w * reg_x_hat.w;
  54.   variance = block_reduce_sum<NUM_THREADS>(variance);
  55.   if (tid == 0) s_variance = rsqrtf(variance / (float) K + epsilon);
  56.   // wait for s_variance in shared memory to be ready for all threads
  57.   __syncthreads();
  58.   float4 reg_y;
  59.   reg_y.x = reg_x_hat.x * s_variance * g + b;
  60.   reg_y.y = reg_x_hat.y * s_variance * g + b;
  61.   reg_y.z = reg_x_hat.z * s_variance * g + b;
  62.   reg_y.w = reg_x_hat.w * s_variance * g + b;
  63.   if (idx < N * K) FLOAT4(y[idx]) = reg_y;
  64. }

layer norm实现的核心同样也是block reduce和warp reduce，然后再整点向量化...

0x0d rms_norm, rms_norm + vec4

  1. // RMS Norm: x: NxK(K=128<1024), y': NxK, y'=x/rms(x) each row
  2. // 1/rms(x) = rsqrtf( sum(x^2)/K ) each row
  3. // grid(N*K/K), block(K<1024) N=batch_size*seq_len, K=hidden_size
  4. // y=y'*g (g: scale)
  5. template<const int NUM_THREADS=128>
  6. __global__ void rms_norm(float* x, float* y, float g, int N, int K) {
  7.   int tid = threadIdx.x; // 0..K-1
  8.   int bid = blockIdx.x; // 0..N-1
  9.   int idx = bid * blockDim.x + threadIdx.x;
  10.   const float epsilon = 1e-5f;
  11.  
  12.   __shared__ float s_variance; // shared within block
  13.   float value = (idx < N * K) ? x[idx] : 0.0f; // load once only
  14.   float variance = value * value;
  15.   variance = block_reduce_sum<NUM_THREADS>(variance);
  16.   if (tid == 0) s_variance = rsqrtf(variance / (float) K + epsilon);
  17.   // wait for s_variance in shared memory to be ready for all threads
  18.   __syncthreads(); 
  19.   if (idx < N * K) y[idx] = (value * s_variance) * g;
  20. }
  21.  
  22. // RMS Norm Vec4: x: NxK(K=128<1024), y': NxK, y'=x/rms(x) each row
  23. // 1/rms(x) = rsqrtf( sum(x^2)/K ) each row
  24. // grid(N*K/K), block(K/4<1024) N=batch_size*seq_len, K=hidden_size
  25. // y=y'*g (g: scale)
  26. template<const int NUM_THREADS=128/4>
  27. __global__ void rms_norm_vec4(float* x, float* y, float g, int N, int K) {
  28.   int tid = threadIdx.x; // 0..K-1
  29.   int bid = blockIdx.x; // 0..N-1
  30.   int idx = (bid * blockDim.x + threadIdx.x) * 4;
  31.   const float epsilon = 1e-5f;
  32.  
  33.   __shared__ float s_variance; // shared within block
  34.   float4 reg_x = FLOAT4(x[idx]);
  35.   float variance = (idx < N * K) ? (reg_x.x * reg_x.x + reg_x.y * reg_x.y 
  36.                                   + reg_x.z * reg_x.z + reg_x.w * reg_x.w) : 0.0f;
  37.   variance = block_reduce_sum<NUM_THREADS>(variance);
  38.   if (tid == 0) s_variance = rsqrtf(variance / (float) K + epsilon);
  39.   // wait for s_variance in shared memory to be ready for all threads
  40.   __syncthreads(); 
  41.   float4 reg_y;
  42.   reg_y.x = reg_x.x * s_variance * g;
  43.   reg_y.y = reg_x.y * s_variance * g;
  44.   reg_y.z = reg_x.z * s_variance * g;
  45.   reg_y.w = reg_x.w * s_variance * g;
  46.   if (idx < N * K) FLOAT4(y[idx]) = reg_y;
  47. }

rms norm实现的核心同样也是block reduce和warp reduce...，然后再加点float4向量化什么的。

0x0e NMS

  1. struct Box {
  2.   float x1, y1, x2, y2, score;
  3.   float area() const {return (std::abs(x2 - x1 + 1)) * std::abs(y2 - y1 + 1); }
  4.   float iou_of(const Box& other) const{
  5.     float inner_x1 = x1 > other.x1 ? x1 : other.x1;
  6.     float inner_y1 = y1 > other.y1 ? y1 : other.y1;
  7.     float inner_x2 = x2 < other.x2 ? x2 : other.x2;
  8.     float inner_y2 = y2 < other.y2 ? y2 : other.y2;
  9.     float inner_h = inner_y2 - inner_y1 + 1.0f;
  10.     float inner_w = inner_x2 - inner_x1 + 1.0f;
  11.     float inner_area = inner_h * inner_w;
  12.     return (inner_area / (area() + tbox.area() - inner_area));
  13.   }
  14. }
  15. void hard_nms(std::vector<Box> &input, std::vector<Box> &output, float iou_threshold){
  16.   if (input.empty()) return;
  17.   std::sort(input.begin(), input.end(),[](Box& a, Box& b) { return a.score > b.score; });
  18.   int box_num = input.size();
  19.   std::vector<int> merged(box_num, 0);
  20.   for (int i = 0; i < box_num; ++i) {
  21.     if (merged[i]) continue;
  22.     merged[i] = 1;
  23.     for (int j = i + 1; j < box_num; ++j) {
  24.       if (merged[j]) continue;
  25.       float iou = input[i].iou_of(input[j]);
  26.       if (iou > iou_threshold) merged[j] = 1;
  27.     }
  28.     output.push_back(input[i]);
  29.   }
  30. }

CV相关的经常会要手撕NMS，也记录下。

0x0f 总结

可以发现，大部分kernel的基本写法都是依赖warp reduce和block reduce的，基本上只要熟练应用warp functions各种场景的写法，应该问题不大；softmax需要考虑网格级同步的问题，或者online softmax以及FlashAttention；sgemm的优化是个很大的课题，不是案例中写的这么简单，但是入门的话，基本就是tiling的思想以及如何做索引之间的mapping；sgemv的优化则主要考虑K不同的值（因为M为1了），比如K=16,64,128等情况下，如何按照warp来处理；relu、sigmoid等都是elementwise的操作，很好实现，可以再考虑加点向量化优化访存；layer norm和rms norm在数学上其实也是挺清晰简单的，落实到cuda kernel时，只要按照逐个token来处理，headdim没有超过1024的情况下（一个block最多可以放1024个threads），可以放到一个block处理，这样并行化就很好写。当然，核心还是warp reduce和block reduce；NMS是乱入的，没有CUDA版本，别问了...

最后，附GitHub repo:

https://github.com/DefTruth/cuda-learn-note/
github.com/DefTruth/cuda-learn-note/

投稿作者为『自动驾驶之心知识星球』特邀嘉宾，欢迎加入交流！

① 全网独家视频课程

BEV感知、BEV模型部署、BEV目标跟踪、毫米波雷达视觉融合、多传感器标定、多传感器融合、多模态3D目标检测、车道线检测、轨迹预测、在线高精地图、世界模型、点云3D目标检测、目标跟踪、Occupancy、cuda与TensorRT模型部署、大模型与自动驾驶、Nerf、语义分割、自动驾驶仿真、传感器部署、决策规划、轨迹预测等多个方向学习视频（扫码即可学习）

cfd0f1aa6bacd69d95600ec39a1596b5.png

网页端官网：www.zdjszx.com

② 国内首个自动驾驶学习社区

国内最大最专业，近3000人的交流社区，已得到大多数自动驾驶公司的认可！涉及30+自动驾驶技术栈学习路线，从0到一带你入门自动驾驶感知（2D/3D检测、语义分割、车道线、BEV感知、Occupancy、多传感器融合、多传感器标定、目标跟踪）、自动驾驶定位建图（SLAM、高精地图、局部在线地图）、自动驾驶规划控制/轨迹预测等领域技术方案、大模型、端到端等，更有行业动态和岗位发布！欢迎扫描下方二维码，加入自动驾驶之心知识星球，这是一个真正有干货的地方，与领域大佬交流入门、学习、工作、跳槽上的各类难题，日常分享论文+代码+视频

d1fa20ccba4747611cf84fc42a09d851.png

③【自动驾驶之心】技术交流群

自动驾驶之心是首个自动驾驶开发者社区，聚焦感知、定位、融合、规控、标定、端到端、仿真、产品经理、自动驾驶开发、自动标注与数据闭环多个方向，目前近60+技术交流群，欢迎加入！扫码添加汽车人助理微信邀请入群，备注：学校/公司+方向+昵称（快速入群方式）

872e2814eaff4826eab7670bda2d098b.jpeg

④【自动驾驶之心】全平台矩阵

fd0b6f60b7c2485dd2ee77c2b2869ad1.png

声明：本文内容由网友自发贡献，不代表【wpsshop博客】立场，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：https://www.wpsshop.cn/w/喵喵爱编程/article/detail/856527
推荐阅读
相关标签

Copyright © 2003-2013 www.wpsshop.cn 版权所有，并保留所有权利。

  

闽ICP备14008679号