ESP32开发实例（七），WebServer使用_esp32 web

目录

 

一、什么是WebServer

二、基本语法

三、路径参数的简单认识

四、用户认证

五、总结

 

 

---

一、什么是WebServer

Web Server中文名称叫网页服务器或web服务器。WEB服务器也称为WWW(WORLD WIDE WEB)服务器，主要功能是提供网上信息浏览服务。

太过官方的解释，大家可能看不懂。通俗点讲，这个功能其实可以简单的理解为是网页服务器。它的主要作用就是用户访问链接的时候执行相应的动作。就比如你访问了特定的网页，他可以给你一个特定的回执或者是提示或指令。对于开发来说，处理的主要就是注册链接，并编写用户访问该链接时需要执行的操作或者是提示。

二、基本语法

首先我们看一下它的基本使用语法和功能关键词。​

• 引入相应库#include <WebServer.h>；
• 声明WebServer对象并设置端口号，一般WebServer端口号使用80；
• 使用on()方法注册链接与回调函数；
• 使用begin()方法启动服务器进行请求监听；
• 使用handleClient()处理来自客户端的请求；

 

相关的代码如下

#include <WiFi.h>
#include <WebServer.h> //引入相应库
 
const char *ssid = "********";
const char *password = "********";
 
WebServer server(80); //声明WebServer对象
 
void handleRoot() //回调函数
{
  server.send(200, "text/plain", "这是根页面");
}
 
void handleP1() //回调函数
{
  server.send(200, "text/plain", "这是P1页面");
}
 
void setup()
{
  Serial.begin(115200);
  Serial.println();
 
  WiFi.mode(WIFI_STA);
  WiFi.setSleep(false);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println("Connected");
  Serial.print("IP Address:");
  Serial.println(WiFi.localIP());
 
  server.on("/", handleRoot); //注册链接"/"与对应回调函数
 
  server.on("/p1", handleP1); //注册链接"/p1"与对应回调函数
 
  server.on("/p2", []() { //注册链接"/p2"，对应回调函数通过内联函数声明
    server.send(200, "text/plain", "这是P2页面，由内联函数声明");
  });
 
  server.begin(); //启动服务器
  Serial.println("Web server started");
}
 
void loop()
{
  server.handleClient(); //处理来自客户端的请求
}

 代码解释

首先我们要引入两个库，一个是WiFi库，一个是web server库，并设置我们家里的WiFi密码和WiFi名称，然后设置回调函数以及提示相应的文字，在主函数中，我们设置串口通信梳理为115200。以及设置我们的WIFI工作模式为sta模式，设计通信WiFi的连接程序以及相应的回调函数。然后我们启动服务器，并让loop程序一直执行来处理来自客户端的请求。

三、路径参数的简单认识

第2个我们介绍一个简便方法。当我们处理的链接比较多时，并且链接具有相似的规律性。我们就没有必要对每个链接都进行注册，我们可以使用路径参数来处理这些相似或者是动态的链接，这样就让我们的编程变得更加简单和易于操作。相关的代码如下。

#include <WiFi.h>
#include <WebServer.h> //引入相应库
 
const char *ssid = "********";
const char *password = "********";
 
WebServer server(80); //声明WebServer对象
 
void handleArg1() //回调函数
{
  String arg = server.pathArg(0);
  server.send(200, "text/plain", "这是链接/{}，参数是： " + arg);
}
 
void handleArg2() //回调函数
{
  String arg0 = server.pathArg(0);
  String arg1 = server.pathArg(1);
  server.send(200, "text/plain", "这是链接/p/{}/d/{}，参数是： " + arg0 + " 、 " + arg1);
}
 
void setup()
{
  Serial.begin(115200);
  Serial.println();
 
  WiFi.mode(WIFI_STA);
  WiFi.setSleep(false);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println("Connected");
  Serial.print("IP Address:");
  Serial.println(WiFi.localIP());
 
  server.on("/{}", handleArg1);        //注册链接与回调函数
  server.on("/p/{}/d/{}", handleArg2); //注册链接与回调函数
 
  server.begin(); //启动服务器
  Serial.println("Web server started");
}
 
void loop()
{
  server.handleClient(); //处理来自客户端的请求
}

 代码在前面部分和上个例子一样，这里不多解释。我们主要看这两个回调函数。这两个回调函数是进行动态变化的重要元素，在主函数中，我们首先设置串口以及设置蓝牙的工作模式。和WiFi的连接判断程序。并启动服务器。再让循环函数一起执行，来自客户端的请求。

四、用户认证

上述的设置和网站链接都是让任何用户都可以访问的。现在我们可以将我们的链接设置增加一些安全性，让特定的用户进行访问和登录。换句话说，我们需要设置用户的登录名称和密码。让拥有正确登录名称和密码用户登录。

#include <WiFi.h>
#include <WebServer.h> //引入相应库
 
const char *ssid = "********";
const char *password = "********";
 
WebServer server(80); //声明WebServer对象
 
const char *username = "user";     //用户名
const char *userpassword = "1234"; //用户密码
 
void handleRoot() //回调函数
{
  if (!server.authenticate(username, userpassword)) //校验用户是否登录
  {
    return server.requestAuthentication(); //请求进行用户登录认证
  }
  server.send(200, "text/plain", "登录成功!"); //登录成功则显示真正的内容
}
 
void setup()
{
  Serial.begin(115200);
  Serial.println();
 
  WiFi.mode(WIFI_STA);
  WiFi.setSleep(false);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED)
  {
    delay(500);
    Serial.print(".");
  }
  Serial.println("Connected");
  Serial.print("IP Address:");
  Serial.println(WiFi.localIP());
 
  server.on("/", handleRoot); //注册链接和回调函数
 
  server.begin(); //启动服务器
  Serial.println("Web server started");
}
 
void loop()
{
  server.handleClient(); //处理来自客户端的请求
}

首先我们引入两个库，设置WiFi名称和密码。并创建外把Siri的对象输入用户名和设置用户密码。这样只有正确的用户名和用户密码才可以访问这个链接。我们使用回调函数来验证用户是否登录以及请求进行登录认证的界面。在主函数中我们输入 WiFi的链接程序和判断程序，最后我们启动服务器以及让循环函数一直执行，来自客户端的请求。

五、总结

 

这期的学习较为简单，也比较通俗易懂。我们主要学习了web server的简单用法。其中包括基本语法以及他用来处理相似链接的方式，并且我们了解到了用户认证和提高链接安全性的一种保护手段。在代码方面，我们主要认识了回调函数以及 WiFi的连接和判断程序。