devbox
小小林熬夜学编程
这个屌丝很懒，什么也没留下！
关注作者
热门标签
热门文章
当前位置:   article > 正文

Unity Shader入门学习（1）：基础shader

作者：小小林熬夜学编程 | 2024-02-18 11:36:36

赞

踩

unity shader

 1.基础光照shader+贴图

  1. //理解shader代码的最重要一步，就是将渲染流水线的步骤与 代码对应
  2.  
  3. Shader "01"{//这里指定的路径与名字与文件名名不要求一致
  4.  
  5. 	Properties{//属性
  6. 	//格式：属性名（显示出来的属性名，类型）=默认值
  7. 		_Color("Color",Color) = (1,1,1,1)//颜色
  8. 		_Specular("Specular",Color) = (1,1,1,1)//高光颜色
  9. 		_Gloss("Gloss",Range(8.0,256)) = 20//光泽度。（cos角的指数）。一般大于10
  10.  
  11. 		_MainTex("Main Tex",2D)="write"{}//贴图
  12. 	}
  13.  
  14. 	SubShader{
  15. 	//子属性，可以有多个。用来控制效果。而不同的子属性用来适配不同的显卡 。
  16. 	//显卡运行效果时，从第一个subshader开始，若效果都可以实现（由显卡性能决定），则使用第一个subshader，否则自动运行下一个
  17. 	//subshader内至少有一个pass块。（pass相当于方法）shader代码就是在pass块里编写的
  18.  
  19. 	Tags {"RenderType" = "Opaque" }
  20. 		
  21. 		pass {
  22. 			Tags{"LightMode" = "ForwardBase"}
  23.  
  24. 			CGPROGRAM                  //Begin
  25.  
  26. 			#pragma vertex vert  
  27. 			//顶点函数。这里声明了顶点函数的函数名
  28. 			#pragma fragment frag 
  29. 			//片元函数。这里声明了片元函数的函数名
  30. 			//顶点函数处理顶点，将顶点坐标，从模型空间转换到剪裁空间（处理位置）
  31. 			//片元函数处理像素，决定具体像素显示声明（颜色值）
  32.  
  33. 			#include "Lighting.cginc"
  34. 		    //取得第一个直射光的颜色_LightColor0 第一个直射光的位置_WorldSpaceLightPos0（即方向）
  35.  
  36. 			fixed4 _Color;
  37. 			fixed4 _Specular;
  38. 			float _Gloss;
  39. 			sampler2D _MainTex;
  40. 			float4 _MainTex_ST;//纹理属性。ST意指缩放与平移。此值可以让我们获得纹理的缩放平移值
  41. 			//_MainTex_ST.xy存缩放，_MainTex_ST.zw存平移
  42. 			//这里声明的变量名不是随意起的。是用  _纹理名_ST 的格式固定声明的。
  43.  
  44. 			struct a2v {
  45. 				float4 vertex : POSITION;//语义POSITION指模型空间下的顶点位置
  46. 				float3 normal :NORMAL;//语义指模型空间下法线
  47. 				float4 texcoord:TEXCOORD0;
  48. 			};
  49. 			
  50. 			struct v2f {
  51. 				float4 pos : SV_POSITION;// SV_POSITION指裁剪空间下定点位置。与f.pos = UnityObjectToClipPos(v.vertex);联系
  52. 				float3 WorldNormal:TEXCOORD0;
  53. 				float3 WorldPos : TEXCOORD1;
  54. 				float2 uv:TEXCOORD2;//用于存储纹理坐标
  55. 			};
  56.  
  57. 			//顶点函数。如	#pragma vertex vert 所声明
  58. 			//顶点shder最重要的工作就是f.pos = UnityObjectToClipPos(v.vertex);即把顶点坐标从模型空间转化到齐次裁剪空间
  59. 			v2f vert(a2v v) {
  60. 				v2f f;
  61.  
  62. 				f.WorldNormal= UnityObjectToWorldNormal(v.normal);//法线世界化
  63. 				//f.WorldNormal = normalize(mul(unity_ObjectToWorld, v.normal));
  64.  
  65. 				f.WorldPos = mul(unity_ObjectToWorld, v.vertex);//点坐标世界化
  66. 				//点坐标世界化，是方便通过世界坐标下的点作为一些内置函数的参数，获取光照方向，视线方向等
  67.  
  68. 				f.pos = UnityObjectToClipPos(v.vertex);//点坐标片元化。从模型空间转换到裁剪空间
  69.  
  70. 				f.uv=TRANSFORM_TEX(v.texcoord,_MainTex);
  71. 				//f.uv=v.texcoord.xy*_MainTex_ST.xy+_MainTex_ST.zw;
  72. 				//_MainTex_ST.xy对纹理进行缩放，_MainTex_ST.zw对纹理偏移
  73.  
  74. 				return f;
  75. 			}
  76.  
  77. 			//片元shader主要的功能就是决定片元的颜色。
  78. 			//而片元颜色（姑且理解为像素颜色，实际片元是包含像素，深度等信息的集合）又由光照颜色和贴图决定
  79. 			//片元包含了比RGBA更多的信息，比如可能有深度值，法线，纹理坐标等等信息。
  80. 			fixed4 frag(v2f f) :SV_TARGET0{
  81. 			//在frag方法里实现光照就是逐像素光照。相应的，在vert方法里写就是逐顶点光照。
  82.  
  83. 				fixed3 lightDir = normalize(UnityWorldSpaceLightDir(f.WorldPos));
  84. 				//单位化光的方向.求光的方向需要知道点的世界坐标，再利用方法UnityWorldSpaceLightDir求得
  85.  
  86. 				fixed3 worldNormal=normalize(f.WorldNormal);
  87. 				//单位化法线的方向
  88.  
  89. 				fixed3 albedo =tex2D(_MainTex,f.uv).rgb* _Color.rgb;//albedo是反照率（非镜面），这里指物体本身颜色？
  90. 				//tex2D函数负责对纹理进行采样
  91.  
  92. 				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT * albedo;	//ambient是环境光.
  93. 				//环境光乘以albedo后才能使背光处（但受环境光）的物体也显示出颜色
  94.  
  95. 				fixed3 diffuse = _LightColor0.rgb * albedo *( dot(worldNormal,lightDir)*0.5+0.5);//半兰伯特光照模型
  96. 				//fixed3 diffuse = _LightColor0.rgb * albedo * max(0,dot(f.WorldNormal,lightDir));//兰伯特光照模型
  97. 				//取得漫反射颜色：光色*albedo*max（光与法线夹角的cos，0）
  98.  
  99. 				fixed3 viewDir = normalize(UnityWorldSpaceViewDir(f.WorldPos));//单位化视线方向。需要知道点的世界坐标
  100. 				fixed3 halfDir = normalize(lightDir + viewDir);//求视线与光线的中间向量（原理想想计算机图形学）
  101. 				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot(worldNormal,halfDir)),_Gloss);//pow方法指取指数。
  102. 				//利用Blinn-Phong光照模型取得高光。此模型的核心是取得了视野方向与入射光中向量与法线向量的夹角。如果运用phong模型，则取出射光与视野方向的夹角
  103.  
  104. 				return fixed4(ambient + diffuse + specular , 1);
  105. 			}
  106. 			ENDCG              //end
  107. 		}
  108. 	}
  109.  
  110.  
  111. 	FallBack "Diffuse"//用来指定一个后备方案。
  112. }

 

2.引入法线贴图

  1.  
  2. Shader "02" { 
  3.  
  4.     Properties{
  5.         _MainTex("Main Tex", 2D) = "white"{} // 纹理贴图
  6.         _Color("Color", Color) = (1,1,1,1)   // 控制纹理贴图的颜色
  7. 		_Specular("Specular",Color) = (1,1,1,1)//高光颜色
  8. 		_Gloss("Gloss",Range(8.0,256)) = 20//光泽度。（cos角的指数）。一般大于10
  9.         _NormalMap("Normal Map", 2D) = "bump"{} // 表示当该位置没有指定任何法线贴图时，就使用模型顶点自带的法线
  10.         _BumpScale("Bump Scale", Float) = 1  // 法线贴图的凹凸参数。为0表示使用模型原来的发现，为1表示使用法线贴图中的值。大于1则凹凸程度更大。
  11.     }
  12.  
  13.     SubShader{
  14.         Pass {
  15.             Tags{"LightMode" = "ForwardBase"}
  16.  
  17.             CGPROGRAM
  18.  
  19. 			#pragma vertex vert
  20. 			#pragma fragment frag
  21. 			#include "Lighting.cginc"
  22. 			//取得第一个直射光的颜色_LightColor0 第一个直射光的位置_WorldSpaceLightPos0（即方向）
  23.  
  24.             fixed4 _Color;
  25. 			fixed4 _Specular;
  26. 			float _Gloss;
  27.             sampler2D _MainTex;
  28.             float4 _MainTex_ST; //命名是固定的贴图名+后缀"_ST"，4个值前两个xy表示缩放，后两个zw表示偏移
  29.             sampler2D _NormalMap;
  30.             float4 _NormalMap_ST; //命名是固定的贴图名+后缀"_ST"，4个值前两个xy表示缩放，后两个zw表示偏移
  31.             float _BumpScale;    
  32.  
  33.             struct a2v
  34.             {
  35.                 float4 vertex : POSITION;   
  36.                 float3 normal : NORMAL;       //不再使用模型自带的法线。保留该变量是因为切线空间是通过（模型里的）法线和（模型里的）切线确定的。
  37.                 float4 tangent : TANGENT;    //tangent.w用来确定切线空间中坐标轴的方向的。
  38.                 float4 texcoord : TEXCOORD0; 
  39.             };
  40.  
  41.             struct v2f
  42.             {
  43.                 float4 pos : SV_POSITION; // 声明用来存储顶点在裁剪空间下的坐标
  44.                 //float3 WorldNormal : TEXCOORD0;  // 不再使用世界空间下的法线方向
  45.                 //float3 WorldPos: TEXCOORD1;
  46.  
  47.                 float4 uv : TEXCOORD0; // xy存储MainTex的纹理坐标，zw存储NormalMap的纹理坐标
  48. 				float3 lightDir : TEXCOORD1;   // 切线空间下，平行光的方向
  49. 				float3 viewDir : TEXCOORD2;   // 切线空间下，平行光的方向
  50.             };
  51.  
  52.             // 计算顶点坐标从模型坐标系转换到裁剪面坐标系
  53.             v2f vert(a2v v)
  54.             {
  55.                 v2f f;
  56.                 f.pos= UnityObjectToClipPos(v.vertex); // UNITY_MATRIX_MVP是内置矩阵。该步骤用来把一个坐标从模型空间转换到剪裁空间             
  57. 			    
  58.                 f.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; // 贴图的纹理坐标，等同于f.uv=TRANSFORM_TEX(v.texcoord,_MainTex);
  59.                 f.uv.zw = v.texcoord.xy * _NormalMap_ST.xy + _NormalMap_ST.zw; // 法线贴图的纹理坐标
  60.  
  61.                 TANGENT_SPACE_ROTATION; // 调用这个宏会得到一个矩阵rotation，该矩阵用来把模型空间下的方向转换为切线空间下。注意不是世界空间
  62.                 f.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)); //切线空间下，平行光的方向。ObjSpaceLightDir(v.vertex); 得到模型空间下的平行光方向
  63. 				f.viewDir=mul(rotation,ObjSpaceViewDir(v.vertex));//切线空间下，视线的方向
  64.  
  65.                 return f;
  66.             }
  67.  
  68.             // 要把所有跟法线方向有关的运算，都放到切线空间下。因为从法线贴图中取得的法线方向是在切线空间下的。
  69.             fixed4 frag(v2f f) : SV_Target 
  70.             {
  71. 				fixed3 albedo = tex2D(_MainTex,f.uv.xy).rgb* _Color.rgb;//f.uv.xy存储了普通贴图的信息
  72. 				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT * albedo;	
  73.                 
  74.                 //下面求切线空间的法线。先获取法线贴图的颜色信息，再通过内置函数获取法线
  75.                 fixed4 normalColor = tex2D(_NormalMap, f.uv.zw); //f.uv.zw存储了法线贴图的信息
  76.                 fixed3 tangentNormal = UnpackNormal(normalColor); // 使用Unity内置的方法，从颜色值得到法线在切线空间的方向
  77.                 tangentNormal.xy= tangentNormal.xy* _BumpScale; // 控制凹凸程度。只和法线贴图的xy值有关。
  78.                 tangentNormal = normalize(tangentNormal);
  79.  
  80.  
  81.                 // 光照方向与视线方向的单位化。切线空间的转换完成
  82.                 fixed3 tangentLightDir = normalize(f.lightDir); // 切线空间下的光照方向
  83. 				fixed3 tangentViewDir = normalize(f.viewDir); // 切线空间下的光照方向
  84.                 
  85. 				fixed3 diffuse = _LightColor0.rgb * albedo *( dot( tangentNormal,tangentLightDir)*0.5+0.5);//半兰伯特光照模型
  86.  
  87. 				fixed3 halfDir = normalize(tangentViewDir  + tangentLightDir);
  88. 				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot (tangentNormal,tangentLightDir)),_Gloss);
  89.  
  90. 				return fixed4(ambient + diffuse + specular , 1.0);
  91.             }
  92.  
  93.             ENDCG
  94.         }
  95.         
  96.     }
  97.     FallBack "Diffuse"
  98. }

3.引入渐变纹理+高光遮罩+边缘光

  1. Shader "03" { 
  2.  
  3.     Properties{
  4.         _MainTex("Main Tex", 2D) = "white"{} // 纹理贴图
  5.         _Color("Color", Color) = (1,1,1,1)   // 控制纹理贴图的颜色
  6. 		_Specular("Specular",Color) = (1,1,1,1)//高光颜色
  7. 		_Gloss("Gloss",Range(8.0,256)) = 20//光泽度。（cos角的指数）。一般大于10
  8.         _NormalMap("Normal Map", 2D) = "bump"{} // 表示当该位置没有指定任何法线贴图时，就使用模型顶点自带的法线
  9.         _BumpScale("Bump Scale", Float) = 1  // 法线贴图的凹凸参数。为0表示使用模型原来的发现，为1表示使用法线贴图中的值。大于1则凹凸程度更大。
  10.  
  11. 		_RampTex("Ramp Tex",2D)="white"{}//渐变纹理贴图
  12.  
  13. 		_SpecularMask("Specular Mask",2D)="white"{}//高光遮罩贴图
  14. 		_SpecularScale("Specular Scale",Range(0,1))=1//控制高光遮罩影响度系数
  15.  
  16. 		_RimColor("RimColor",Color)=(1,1,1,1)//边缘光颜色
  17. 		_RimLength("RimLength",Range(0,0.8))=0.3
  18. 		_RimPower("RimPower",Range(0.5,3))=1
  19.  
  20.     }
  21.  
  22.     SubShader{
  23.         Pass {
  24.             Tags{"LightMode" = "ForwardBase"}
  25.  
  26.             CGPROGRAM
  27.  
  28. 			#pragma vertex vert
  29. 			#pragma fragment frag
  30. 			#include "Lighting.cginc"
  31. 			// 取得第一个直射光的颜色_LightColor0 第一个直射光的位置_WorldSpaceLightPos0（即方向）
  32.  
  33.             fixed4 _Color;
  34. 			fixed4 _Specular;
  35. 			fixed4 _RimColor;
  36. 			float _Gloss;
  37. 		    float _BumpScale;    
  38. 			float _SpecularScale;
  39. 			float _RimLength; 
  40. 			float _RimPower; 
  41.             sampler2D _MainTex;
  42. 			sampler2D _NormalMap;
  43. 			sampler2D _SpecularMask;
  44. 			sampler2D _RampTex;
  45.             float4 _MainTex_ST; //让主纹理，高光遮罩纹理共同使用这个纹理属性变量
  46. 			float4 _NormalMap_ST;
  47.  
  48.  
  49.             struct a2v
  50.             {
  51.                 float4 vertex : POSITION;   
  52.                 float3 normal : NORMAL;        // 不再使用模型自带的法线。保留该变量是因为切线空间是通过（模型里的）法线和（模型里的）切线确定的。
  53.                 float4 texcoord : TEXCOORD0; //第一组纹理坐标。片元着色器会使用uv纹理坐标对其采样。
  54.  
  55. 			    float4 tangent : TANGENT;    // tangent.w用来确定切线空间中坐标轴的方向的。
  56.             };
  57.  
  58.             struct v2f
  59.             {
  60.                 float4 pos : SV_POSITION; // 声明用来存储顶点在裁剪空间下的坐标
  61.                 //float3 WorldNormal : TEXCOORD0;  // 不再使用世界空间下的法线方向
  62.                 //float3 WorldPos: TEXCOORD1;
  63.                 float4 uv : TEXCOORD0; // xy存储MainTex的纹理坐标，zw存储NormalMap的纹理坐标
  64. 				float3 lightDir : TEXCOORD1;   // 切线空间下，平行光的方向
  65. 				float3 viewDir : TEXCOORD2;   // 切线空间下，平行光的方向
  66.  
  67.             };
  68.  
  69.             // 计算顶点坐标从模型坐标系转换到裁剪面坐标系
  70.             v2f vert(a2v v)
  71.             {
  72.                 v2f f;
  73.                 f.pos= UnityObjectToClipPos(v.vertex); // UNITY_MATRIX_MVP是内置矩阵。该步骤用来把一个坐标从模型空间转换到剪裁空间	
  74.                 f.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; // 贴图的纹理坐标，等同于f.uv=TRANSFORM_TEX(v.texcoord,_MainTex);
  75.                 f.uv.zw = v.texcoord.xy * _NormalMap_ST.xy + _NormalMap_ST.zw; // 法线贴图的纹理坐标
  76.  
  77.                 TANGENT_SPACE_ROTATION; // 调用这个宏会得到一个矩阵rotation，该矩阵用来把模型空间下的方向转换为切线空间下。注意不是世界空间
  78.                 f.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)); //切线空间下，平行光的方向。ObjSpaceLightDir(v.vertex); 得到模型空间下的平行光方向
  79. 				f.viewDir=mul(rotation,ObjSpaceViewDir(v.vertex));//切线空间下，视线的方向
  80.  
  81.                 return f;
  82.             }
  83.  
  84.             // 要把所有跟法线方向有关的运算，都放到切线空间下。因为从法线贴图中取得的法线方向是在切线空间下的。
  85.             fixed4 frag(v2f f) : SV_Target 
  86.             {
  87. 				fixed3 albedo =tex2D(_MainTex,f.uv.xy).rgb* _Color.rgb;//f.uv.xy存储了普通贴图的信息
  88. 				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT * albedo;	
  89.                 
  90.                 //下面求切线空间的法线。先获取法线贴图的颜色信息，再通过内置函数获取法线
  91.                 fixed4 normalColor = tex2D(_NormalMap, f.uv.zw); //f.uv.zw存储了法线贴图的信息
  92.                 fixed3 tangentNormal = UnpackNormal(normalColor); // 使用Unity内置的方法，从颜色值得到法线在切线空间的方向
  93.                 tangentNormal.xy = tangentNormal.xy * _BumpScale; // 控制凹凸程度。只和法线贴图的xy值有关。
  94.                 tangentNormal = normalize(tangentNormal);
  95.  
  96.                 // 光照方向与视线方向的单位化。切线空间的转换完成
  97.                 fixed3 tangentLightDir = normalize(f.lightDir); // 切线空间下的光照方向
  98. 				fixed3 tangentViewDir = normalize(f.viewDir); // 切线空间下的光照方向
  99.  
  100. 				//fixed3 diffuse = _LightColor0.rgb * albedo *( dot( tangentNormal,tangentLightDir)*0.5+0.5);//半兰伯特光照模型
  101.                 
  102. 				//以下是尝试使用渐变纹理的效果。但实际使用后，并不能体现高光（因为渐变贴图绘制时已经考虑高光了），也无法很好体现法线贴图
  103. 				fixed halfLambert =dot( tangentNormal,tangentLightDir)*0.5+0.5;//半兰伯特
  104. 				fixed3 diffuseColor=tex2D(_RampTex,fixed2(halfLambert,halfLambert)).rgb*_Color.rgb;
  105. 				//让半兰伯特的取值范围映射在（0,1），用其数值构建一套纹理坐标，并用这套坐标对渐变纹理采样。
  106. 				fixed3 diffuse=diffuseColor*_LightColor0.rgb;
  107.  
  108. 				//下面是边缘光的初步尝试
  109. 				if(dot(tangentViewDir,tangentNormal)<_RimLength){
  110. 					 diffuse+=_RimPower*(_RimColor.rgb*lerp(1,0,dot(tangentViewDir,tangentNormal)/_RimLength));
  111. 				}
  112.  
  113. 				fixed3 halfDir = normalize(tangentViewDir  + tangentLightDir);//求视线与光线的中间向量
  114. 				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot (tangentNormal,tangentLightDir)),_Gloss);
  115. 				fixed specularMask=tex2D(_SpecularMask,f.uv).r*_SpecularScale;//对遮罩纹理采样后，用r分量计算掩码值并与高光参数相乘。黑色的r值为0，白1
  116. 				specular=specular*specularMask;
  117.  
  118. 				return fixed4(ambient + diffuse + specular , 1.0);
  119.             }
  120.  
  121.             ENDCG
  122.         }
  123.         
  124.     }
  125.     FallBack "Diffuse"
  126. }

4.透明效果

  1. //想要实现透明效果，有两种方式。一种是透明度测试，一种是透明度混合。
  2. //透明度测试简单粗暴，将低于某个值的像素直接剔除。无法实现半透明
  3.  
  4. //透明度测试的代码需要添加如下内容：
  5. //1.Propertiers{...  _CutOff("Alpha CutOff",Range(0,1))=0.5}  (_CutOff参数范围【0,1】。是进行透明度测试时的判断条件)
  6. //2.SubShader{... Tags{"Queue"="AlphaTest","IgnoreProjector"="True","RenderType"="TransparentCutOut"} ...  } 
  7. //(SubShader的Queue标签决定模型归于哪个序列，见课本提及的五个渲染序列)
  8. //3.fixed _CutOff
  9. //4.fixed4 frag(v2f f):SV_Target{...  fixed4 texColor=tex2D(_MainTex,i.uv);    Clip(texColor.a-_CutOff);}
  10. //(Clip方法会判断其参数即texColor.a-_CutOff是否为负数，是则舍弃该片元的输出)
  11.  
  12. //下面是透明度混合的代码（下面代码无法双面渲染。双面渲染要开启两个pass。第一个pass渲染背面（Cull Front），第二个渲染前面。其他地方一致）
  13. Shader "07" { 
  14.  
  15.     Properties{
  16.         _MainTex("Main Tex", 2D) = "white"{} // 纹理贴图
  17.         _Color("Color", Color) = (1,1,1,1)   // 控制纹理贴图的颜色
  18. 		_Specular("Specular",Color) = (1,1,1,1)//高光颜色
  19. 		_Gloss("Gloss",Range(8.0,256)) = 20//光泽度。（cos角的指数）。一般大于10
  20.         _NormalMap("Normal Map", 2D) = "bump"{} // 表示当该位置没有指定任何法线贴图时，就使用模型顶点自带的法线
  21.         _BumpScale("Bump Scale", Float) = 1  // 法线贴图的凹凸参数。为0表示使用模型原来的发现，为1表示使用法线贴图中的值。大于1则凹凸程度更大。
  22.  
  23. 		_RampTex("Ramp Tex",2D)="white"{}//渐变纹理贴图
  24.  
  25. 		_SpecularMask("Specular Mask",2D)="white"{}//高光遮罩贴图
  26. 		_SpecularScale("Specular Scale",Float)=1//控制高光遮罩影响度系数
  27.  
  28. 		_AlphaScale("Alpha Scale",Range(0,1))=1
  29.     }
  30.  
  31.     SubShader{
  32. 		Tags{"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}  
  33.  
  34. 		pass{
  35. 			//这个pass块开启深度写入，但不输出颜色，目的仅为把该模型的深度值写入深度缓冲
  36. 			//这样可以得到逐像素级别的正确深度信息（否则，模型有交叉结构时无法得到正确效果）
  37. 			Zwrite On
  38. 			ColorMask 0
  39. 		}
  40.  
  41.         Pass {
  42.  
  43.             Tags{"LightMode" = "ForwardBase"}
  44. 			
  45. 			ZWrite Off//关闭深度写入。详见课本
  46. 			Blend SrcAlpha OneMinusSrcAlpha//开启并设置pass的混合模式。（有多种模式可以选择）
  47.  
  48.             CGPROGRAM
  49.  
  50. 			#pragma vertex vert
  51. 			#pragma fragment frag
  52. 			#include "Lighting.cginc"
  53. 			// 取得第一个直射光的颜色_LightColor0 第一个直射光的位置_WorldSpaceLightPos0（即方向）
  54.  
  55.             fixed4 _Color;
  56. 			fixed4 _Specular;
  57. 			float _Gloss;
  58. 		    float _BumpScale;    
  59. 			float _SpecularScale;
  60.             sampler2D _MainTex;
  61. 			sampler2D _NormalMap;
  62. 			sampler2D _SpecularMask;
  63. 			sampler2D _RampTex;
  64.             float4 _MainTex_ST; //让主纹理，法线纹理，高光遮罩纹理共同使用这个纹理属性变量
  65. 			fixed _AlphaScale;
  66.  
  67.  
  68.             struct a2v
  69.             {
  70.                 float4 vertex : POSITION;   
  71.                 float3 normal : NORMAL;        // 不再使用模型自带的法线。保留该变量是因为切线空间是通过（模型里的）法线和（模型里的）切线确定的。
  72.                 float4 texcoord : TEXCOORD0; //第一组纹理坐标。片元着色器会使用uv纹理坐标对其采样。
  73.  
  74. 			    float4 tangent : TANGENT;    // tangent.w用来确定切线空间中坐标轴的方向的。
  75.             };
  76.  
  77.             struct v2f
  78.             {
  79.                 float4 pos : SV_POSITION; // 声明用来存储顶点在裁剪空间下的坐标
  80.                 //float3 WorldNormal : TEXCOORD0;  // 不再使用世界空间下的法线方向
  81.                 //float3 WorldPos: TEXCOORD1;
  82.                 float2 uv : TEXCOORD0; // xy存储MainTex的纹理坐标，zw存储NormalMap的纹理坐标
  83. 				float3 lightDir : TEXCOORD1;   // 切线空间下，平行光的方向
  84. 				float3 viewDir : TEXCOORD2;   // 切线空间下，平行光的方向
  85.             };
  86.  
  87.             // 计算顶点坐标从模型坐标系转换到裁剪面坐标系
  88.             v2f vert(a2v v)
  89.             {
  90.                 v2f f;
  91.                 f.pos= UnityObjectToClipPos(v.vertex); // UNITY_MATRIX_MVP是内置矩阵。该步骤用来把一个坐标从模型空间转换到剪裁空间	
  92.                 f.uv.xy = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw; // 贴图的纹理坐标，等同于f.uv=TRANSFORM_TEX(v.texcoord,_MainTex);
  93.  
  94.  
  95.                 TANGENT_SPACE_ROTATION; // 调用这个宏会得到一个矩阵rotation，该矩阵用来把模型空间下的方向转换为切线空间下。注意不是世界空间
  96.                 f.lightDir = mul(rotation, ObjSpaceLightDir(v.vertex)); //切线空间下，平行光的方向。ObjSpaceLightDir(v.vertex); 得到模型空间下的平行光方向
  97. 				f.viewDir=mul(rotation,ObjSpaceViewDir(v.vertex));//切线空间下，视线的方向
  98.  
  99.                 return f;
  100.             }
  101.  
  102.             // 要把所有跟法线方向有关的运算，都放到切线空间下。因为从法线贴图中取得的法线方向是在切线空间下的。
  103.             fixed4 frag(v2f f) : SV_Target 
  104.             {
  105. 			    fixed4 texColor=tex2D(_MainTex,f.uv);
  106. 				fixed3 albedo =texColor.rgb* _Color.rgb;//f.uv.xy存储了普通贴图的信息
  107. 				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT * albedo;	
  108.                 
  109.                 //下面求切线空间的法线。先获取法线贴图的颜色信息，再通过内置函数获取法线
  110.                 fixed4 normalColor = tex2D(_NormalMap, f.uv); //f.uv.zw存储了法线贴图的信息
  111.                 fixed3 tangentNormal = UnpackNormal(normalColor); // 使用Unity内置的方法，从颜色值得到法线在切线空间的方向
  112.                 tangentNormal.xy = tangentNormal.xy * _BumpScale; // 控制凹凸程度。只和法线贴图的xy值有关。
  113.                 tangentNormal = normalize(tangentNormal);
  114.  
  115.  
  116.                 // 光照方向与视线方向的单位化。切线空间的转换完成
  117.                 fixed3 tangentLightDir = normalize(f.lightDir); // 切线空间下的光照方向
  118. 				fixed3 tangentViewDir = normalize(f.viewDir); // 切线空间下的光照方向
  119.  
  120.  
  121. 				fixed3 diffuse = _LightColor0.rgb * albedo *( dot( tangentNormal,tangentLightDir)*0.5+0.5);//半兰伯特光照模型
  122.                 
  123.  
  124.  
  125. 				fixed3 halfDir = normalize(tangentViewDir  + tangentLightDir);
  126. 				fixed3 specular = _LightColor0.rgb * _Specular.rgb * pow(max(0,dot (tangentNormal,tangentLightDir)),_Gloss);
  127. 				fixed specularMask=tex2D(_SpecularMask,f.uv).r*_SpecularScale;//对遮罩纹理采样后，用r分量计算掩码值并与高光参数相乘。黑色的r值为0，白1
  128. 				specular=specular*specularMask;
  129.  
  130. 				return fixed4(ambient + diffuse + specular , texColor.a*_AlphaScale);//设置着色器返回值的透明通道
  131.             }
  132.  
  133.             ENDCG
  134.         }
  135.         
  136.     }
  137.     FallBack "Diffuse"
  138. }

声明：本文内容由网友自发贡献，不代表【wpsshop博客】立场，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：https://www.wpsshop.cn/w/小小林熬夜学编程/article/detail/107632
推荐阅读
相关标签

Copyright © 2003-2013 www.wpsshop.cn 版权所有，并保留所有权利。

  

闽ICP备14008679号