Shader学习的基础知识（二十八）卡通风格渲染_shader viewpode

什么是卡通风格

卡通风格是什么呢？有点抽象。在这里我们做的即是其高光部分是一个个色块的效果，即减少过度区域，且添加描边效果。

制作轮廓方式有很多种，这里用的是过程式几何轮廓渲染。
这种方法的核心是使用两个Pass,一个渲染背面并使用某些技术让轮廓可见。另一个Pass再正常渲染正面。这方法快速有效，只是不适用于立方体这样平整的模型。

描边

第一个Pass中会用轮廓颜色 渲染整个背面并在视角空间下把模型顶点沿着法线方向扩张一段距离，参考代码如下：

viewPos = viewPos + viewNormal * _Outline;
1

如何避免后挡前的问题
如果直接使用顶点法线扩展，对于一些内凹的模型就可能背面挡住正面，为了防止这种问题我们要对顶点法线的z分量进行处理，使它等于一个值，然后把法线归一化，再对顶点进行扩张。扩张后的背景更扁平化，从而降低了挡到正面的可能，参考代码如下：

viewNormal.z=-0.5;
viewNormal=normalize(viewNormal);
viewPos=viewPos+viewNormal*_Outline;
1
2
3

卡通高光

卡通风格的高光上是一块块纯色色块，以前我们使用法线点乘光照方向以及视角方向的一半：

float spec = pow(max(0,dot(normal,halfDir)),_Gloss);
1

我们现在用的这以前的类似，但要做一定修改，我们把该值与阈值做一个对比，小于则阈值高光为0，大于则高光阈值为1。

float spec=dot(worldNormal,worldHalfDir);
spec=step(threshold,spec);
1
2

我们使用了step函数，第一个参数是参考值，第二个参数是待对比值。如果对比值大于第一个参数则返回1，反之为0。
但这种可能会有据齿，我们可以使用下面方法优化：
float spec=dot(worldNormal,worldHalfDir);
spec=lerp(0,1,smoothstep(-w,w,spec-threshold));
smoothstep函数中w是一个很小的值，当spec-threshold，小于-w时返回0，大于w时返回1，否则在0~1之间插值。
我们也可以使用相临像素之间的近似导数值，使用fwidth函数来得到。

实例

解释在代码中，很有意思的例子，可以好好看看：

Shader "Unity Shaders Book/Chapter 14/Toon Shading" {
	Properties {
		_Color ("Color Tint", Color) = (1, 1, 1, 1)
		_MainTex ("Main Tex", 2D) = "white" {}
		//漫反射，色调的渐变纹理
		_Ramp ("Ramp Texture", 2D) = "white" {}
		//轮廓宽度
		_Outline ("Outline", Range(0, 1)) = 0.1
		//轮廓颜色
		_OutlineColor ("Outline Color", Color) = (0, 0, 0, 1)
		//高光色
		_Specular ("Specular", Color) = (1, 1, 1, 1)
		//高光宽度比例
		_SpecularScale ("Specular Scale", Range(0, 0.1)) = 0.01
	}
    SubShader {
		Tags { "RenderType"="Opaque" "Queue"="Geometry"}
		
		//这个Pass用来写轮廓效果的
		Pass {
			//定义Pass名字以后可以直接调用
			NAME "OUTLINE"
			
			//剔除正面
			Cull Front
			
			CGPROGRAM
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "UnityCG.cginc"
			
			float _Outline;
			fixed4 _OutlineColor;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
			}; 
			
			struct v2f {
			    float4 pos : SV_POSITION;
			};
			
			v2f vert (a2v v) {
				v2f o;
				
				float4 pos = mul(UNITY_MATRIX_MV, v.vertex); 

				//法线转到视角空间下
				float3 normal = mul((float3x3)UNITY_MATRIX_IT_MV, v.normal);  
				//避免扩张时超过前面的面片
				normal.z = -0.5;
				//当前位置加上法线上的位置达扩张效果
				pos = pos + float4(normalize(normal), 0) * _Outline;
				//从摄像机空间转到裁剪空间
				o.pos = mul(UNITY_MATRIX_P, pos);
				
				return o;
			}
			
			float4 frag(v2f i) : SV_Target { 
				//直接输出
				return float4(_OutlineColor.rgb, 1);               
			}
			
			ENDCG
		}
		
		Pass {
			Tags { "LightMode"="ForwardBase" }
			
			//剔除背面
			Cull Back
		
			CGPROGRAM
		
			#pragma vertex vert
			#pragma fragment frag
			
			#pragma multi_compile_fwdbase
		
			#include "UnityCG.cginc"
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			#include "UnityShaderVariables.cginc"
			
			fixed4 _Color;
			sampler2D _MainTex;
			float4 _MainTex_ST;
			sampler2D _Ramp;
			fixed4 _Specular;
			fixed _SpecularScale;
		
			struct a2v {
				float4 vertex : POSITION;
				float3 normal : NORMAL;
				float4 texcoord : TEXCOORD0;
				float4 tangent : TANGENT;
			}; 
		
			struct v2f {
				float4 pos : POSITION;
				float2 uv : TEXCOORD0;
				float3 worldNormal : TEXCOORD1;
				float3 worldPos : TEXCOORD2;
				//阴影纹理存在第4组纹理中
				SHADOW_COORDS(3)
			};
			
			v2f vert (a2v v) {
				v2f o;
				
				o.pos = UnityObjectToClipPos( v.vertex);
				o.uv = TRANSFORM_TEX (v.texcoord, _MainTex);
				o.worldNormal  = UnityObjectToWorldNormal(v.normal);
				o.worldPos = mul(unity_ObjectToWorld, v.vertex).xyz;
				
				//计算阴影
				TRANSFER_SHADOW(o);
				
				return o;
			}
			
			float4 frag(v2f i) : SV_Target { 
				fixed3 worldNormal = normalize(i.worldNormal);
				fixed3 worldLightDir = normalize(UnityWorldSpaceLightDir(i.worldPos));
				fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(i.worldPos));
				fixed3 worldHalfDir = normalize(worldLightDir + worldViewDir);
				
				fixed4 c = tex2D (_MainTex, i.uv);
				fixed3 albedo = c.rgb * _Color.rgb;
				
				fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz * albedo;
				
				//计算光照衰减
				UNITY_LIGHT_ATTENUATION(atten, i, i.worldPos);
				
				//半兰伯特当归模型并乘以衰减
				fixed diff =  dot(worldNormal, worldLightDir);
				diff = (diff * 0.5 + 0.5) * atten;
				
				//漫反射
				fixed3 diffuse = _LightColor0.rgb * albedo * tex2D(_Ramp, float2(diff, diff)).rgb;
				
				//高光使用一定的阈值来控制高光范围
				fixed spec = dot(worldNormal, worldHalfDir);
				fixed w = fwidth(spec) * 2.0;
				fixed3 specular = _Specular.rgb * lerp(0, 1, smoothstep(-w, w, spec + _SpecularScale - 1)) * step(0.0001, _SpecularScale);
				
				return fixed4(ambient + diffuse + specular, 1.0);
			}
		
			ENDCG
		}
	}
	FallBack "Diffuse"
}

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160