devbox
我家自动化
这个屌丝很懒，什么也没留下！
关注作者
热门标签
热门文章
当前位置:   article > 正文

以太坊开发入门-ERC20合约_erc20.totalsupply() + amount

作者：我家自动化 | 2024-04-06 02:27:24

赞

踩

erc20.totalsupply() + amount

在上一章节中完成了一个非常简单的合约，本节中将按照ERC20协议完成一个合约, 本章部分源代码参考于网络开源代码，详细了解：openzeppelin-contracts/contracts/token/ERC20 at master · OpenZeppelin/openzeppelin-contracts · GitHub。

开始之前先介绍一下什么是ERC20：

ERC-20指的是以太坊网络的一种代币合约标准。ERC-20是现在最出名的标准，ERC-20标准里无价值的差别，Token之间是能够进行互换的。意思就是在ERC-20标准下，你的100块“钱”和我的100块“钱”相同，没什么区别。ERC-20标准里规定了Token要有它的名字、符号、总供应量以及包含转账、汇款等其他功能。这个标准的优势就是：只要Token符合ERC-20标准，这样的话它就会兼容以太坊钱包。也就是说，就可以太坊钱包里加入这个Token，还能通过钱包把它发给别人。由于ERC-20标准的存在，发行Token就会更加简单。现在以太坊上ERC-20 Token的数量超过了180000种。

ERC2.0是一套接口定义，定义了合约的基本功能，其定义如下：

  1. // SPDX-License-Identifier: MIT
  2. //file IERC20.sol
  3. pragma solidity ^0.8.0;
  4.  
  5. interface IERC20 {
  6.     // 总发行量
  7.     function totalSupply() external view returns (uint256);
  8.     // 查看地址余额
  9.     function balanceOf(address account) external view returns (uint256);
  10.     /// 从自己帐户给指定地址转账
  11.     function transfer(address account, uint256 amount) external returns (bool);
  12.     // 查看被授权人还可以使用的代币余额
  13.     function allowance(address owner, address spender) external view returns (uint256);
  14.     // 授权指定帐户使用你拥有的代币
  15.     function approve(address spender, uint256 amount) external returns (bool);
  16.     // 从一个地址转账至另一个地址，该函数只能是通过approver授权的用户可以调用
  17.     function transferFrom(
  18.         address from,
  19.         address to,
  20.         uint256 amount
  21.     ) external returns (bool);
  22.  
  23.     /// 定义事件，发生代币转移时触发
  24.     event Transfer(address indexed from, address indexed to, uint256 value);
  25.     /// 定义事件 授权时触发
  26.     event Approval(address indexed owner, address indexed spender, uint256 value);
  27. }

详细说明参考代码注释。

  1. // SPDX-License-Identifier: MIT
  2. //file IERC20Metadata.sol
  3. pragma solidity ^0.8.0;
  4. import "./IERC20.sol";
  5. interface IERC20Metadata is IERC20 {
  6.     // 代币名称, 如:BitCoin
  7.     function name() external view returns (string memory);
  8.     // 代币符号或简称, 如:BTC
  9.     function symbol() external view returns (string memory);
  10.     // 代币支持的小数点后位数，若无特别需求，我们一般默认采用18位。
  11.     function decimals() external view returns (uint8);
  12. }

MetaData数据定义，该部分比较简单，定义三个函数，分别对应代币名称，代币简称和代币小数点位数。

具体代码实现：

  1. // SPDX-License-Identifier: MIT
  2. pragma solidity ^0.8.0;
  3.  
  4. import "./IERC20.sol";
  5. import "./IERC20Metadata.sol";
  6. contract ERC20 is IERC20, IERC20Metadata {
  7.     // 地址余额
  8.     mapping(address => uint256) private _balances;
  9.     // 授权地址余额
  10.     mapping(address => mapping(address => uint256)) private _allowances;
  11.  
  12.     uint256 private _totalSupply;
  13.  
  14.     string private _name;
  15.     string private _symbol;
  16.  
  17.     // 设定代币名称符号，并初始化铸造了10000000000代币在发布者帐号下。
  18.     constructor() {
  19.         _name = "HarryToken";
  20.         _symbol = "HYT";
  21.         _mint(msg.sender, 10000000000);
  22.     }
  23.  
  24.     function name() public view virtual override returns (string memory) {
  25.         return _name;
  26.     }
  27.  
  28.     function symbol() public view virtual override returns (string memory) {
  29.         return _symbol;
  30.     }
  31.  
  32.     /// 小数点位数一般为 18
  33.     function decimals() public view virtual override returns (uint8) {
  34.         return 18;
  35.     }
  36.  
  37.     // 返回当前流通代币的总量
  38.     function totalSupply() public view virtual  override returns (uint256) {
  39.         return _totalSupply;
  40.     }
  41.  
  42.     // 查询指定帐号地址余额
  43.     function balanceOf(address account) public view virtual override returns (uint256) {
  44.         return _balances[account];
  45.     }
  46.  
  47.     // 转帐功能
  48.     function transfer(address to, uint256 amount) public virtual override returns (bool) {
  49.         address owner = msg.sender;
  50.         _transfer(owner, to, amount);
  51.         return true;
  52.     }
  53.  
  54.     // 获取被授权者可使用授权帐号的可使用余额
  55.     function allowance(address owner, address spender) public view virtual override returns (uint256) {
  56.         return _allowances[owner][spender];
  57.     }
  58.  
  59.     // 授权指定帐事情可使用自己一定额度的帐户余额。
  60.     // 授权spender, 可将自己余额。使用可使用的余额的总量为amount
  61.     function approve(address spender, uint256 amount) public virtual override returns (bool) {
  62.         address owner = msg.sender;
  63.         _approve(owner, spender, amount);
  64.         return true;
  65.     }
  66.  
  67.     //approve函数中的spender调用，将授权人 from 帐户中的代币转入to 帐户中
  68.     function transferFrom(
  69.         address from,
  70.         address to,
  71.         uint256 amount
  72.     ) public virtual override returns (bool) {
  73.         address spender = msg.sender;
  74.         _spendAllowance(from, spender, amount);
  75.         _transfer(from, to, amount);
  76.         return true;
  77.     }
  78.  
  79.     function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
  80.         address owner = msg.sender;
  81.         _approve(owner, spender, _allowances[owner][spender] + addedValue);
  82.         return true;
  83.     }
  84.  
  85.     function decreaseAllowance(address spender, uint256 substractedValue) public virtual returns (bool) {
  86.         address owner = msg.sender;
  87.         uint256 currentAllowance = _allowances[owner][spender];
  88.         require(currentAllowance >= substractedValue, "ERC20: decreased allowance below zero");
  89.         unchecked {
  90.             _approve(owner, spender, currentAllowance - substractedValue);
  91.         }
  92.         return true;
  93.     }
  94.  
  95.     function _transfer(
  96.         address from,
  97.         address to,
  98.         uint256 amount
  99.     ) internal virtual {
  100.         require(from != address(0), "ERC20: transfer from the zero address");
  101.         require(to != address(0), "ERC20: transfer to the zero address");
  102.  
  103.         _beforeTokenTransfer(from, to, amount);
  104.  
  105.         uint256 fromBalance = _balances[from];
  106.         require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
  107.         unchecked {
  108.             _balances[from] = fromBalance - amount;
  109.         }
  110.         _balances[to] += amount;
  111.  
  112.         emit Transfer(from, to, amount);
  113.  
  114.         _afterTokenTransfer(from, to, amount);
  115.     }
  116.  
  117.     function _mint(address account, uint256 amount) internal virtual {
  118.         require(account != address(0), "ERC20: mint to the zero address");
  119.  
  120.         _beforeTokenTransfer(address(0), account, amount);
  121.  
  122.         _totalSupply += amount;
  123.         _balances[account] += amount;
  124.         emit Transfer(address(0), account, amount);
  125.  
  126.         _afterTokenTransfer(address(0), account, amount);
  127.     }
  128.  
  129.     function _burn(address account, uint256 amount) internal virtual {
  130.         require(account != address(0), "ERC20: burn from the zero address");
  131.  
  132.         _beforeTokenTransfer(account, address(0), amount);
  133.  
  134.         uint256 accountBalance = _balances[account];
  135.         require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
  136.         unchecked {
  137.             _balances[account] = accountBalance - amount;
  138.         }
  139.         _totalSupply -= amount;
  140.         emit Transfer(account, address(0), amount);
  141.         _afterTokenTransfer(account, address(0), amount);
  142.     }
  143.  
  144.     function _approve(
  145.         address owner,
  146.         address spender,
  147.         uint256 amount
  148.     ) internal virtual {
  149.         require(owner != address(0), "ERC20: approve from the zero address");
  150.         require(spender != address(0), "ERC20: approve  to the zero address");
  151.  
  152.         _allowances[owner][spender] = amount;
  153.         emit Approval(owner, spender, amount);
  154.     }
  155.  
  156.     function _spendAllowance(
  157.         address owner,
  158.         address spender,
  159.         uint256 amount
  160.     ) internal virtual {
  161.         uint256 currentAllowance = allowance(owner, spender);
  162.         if (currentAllowance != type(uint256).max) {
  163.             require(currentAllowance >= amount, "ERC20: insufficient allowance");
  164.             unchecked {
  165.                 _approve(owner, spender, currentAllowance - amount);
  166.             }
  167.         }
  168.     }
  169.  
  170.     function _beforeTokenTransfer(
  171.         address from,
  172.         address to,
  173.         uint256 amount
  174.     ) internal virtual {}
  175.  
  176.     function _afterTokenTransfer(
  177.         address from,
  178.         address to,
  179.         uint256 amount
  180.     ) internal virtual {}
  181. }
  1.     // 地址余额
  2.     mapping(address => uint256) private _balances;
  3.     // 授权地址余额
  4.     mapping(address => mapping(address => uint256)) private _allowances;
  5.  
  6.     uint256 private _totalSupply;
  7.  
  8.     string private _name;
  9.     string private _symbol;

ERC20合约中定义了5个变量：

_balances变量以keyv=>value方式存储帐号和其对应的余额。

_allowances变量是一个两层mapping，数据值以下结构存储：0x123456=>[0x123457=>1000, 0x123458=>2000]，代表的意思是0x123456帐号授权0x123457和0x123458两个帐号，分别可以使用0x123456帐号1000和2000余额额度。使用余额的函数为transferFrom。

_totalSupply变量是存储当成代币合约发行的代币总量，一般我们每铸造一个新代币，就在其值上+1。

_name变量是代币的名称，如比特币名称：BitCoin

_symbol变量是代币的简称, 如比特币简称：BTC

  1.     // 设定代币名称符号，并初始化铸造了10000000000代币在发布者帐号下。
  2.     constructor() {
  3.         _name = "HarryToken";
  4.         _symbol = "HYT";
  5.         _mint(msg.sender, 10000000000);
  6.     }

构造函数，指令name和symbol。这里我们调用了一个private的函数_mint，给合约创建者新铸造了10000000000个代币。因为本合约实现的时候并没有public的mint函数可以铸造代币，所以直接初始化入创建者帐户，该合约所有的代币都只能用创建都帐户转出。当前也可以将实现一个public的mint函数，关加上权限控制，让有权限的帐户可以随时调mint铸造新代币。

  1.   function name() public view virtual override returns (string memory) {
  2.         return _name;
  3.     }
  4.  
  5.     function symbol() public view virtual override returns (string memory) {
  6.         return _symbol;
  7.     }
  8.  
  9.     /// 小数点位数一般为 18
  10.     function decimals() public view virtual override returns (uint8) {
  11.         return 18;
  12.     }

IERC20Metadata 接口的实现方法，主要用于获取代币名称，简称及支持的小数点位数。

  1. function totalSupply() public view virtual  override returns (uint256) {
  2.     return _totalSupply;
  3. }

totalSupply查询当前代币的发行总量。

  1. function balanceOf(address account) public view virtual override returns (uint256) {
  2.     return _balances[account];
  3. }

balanceOf查询指令帐户的代币余额。

  1.     // 转帐功能
  2.     function transfer(address to, uint256 amount) public virtual override returns (bool) {
  3.         address owner = msg.sender;
  4.         _transfer(owner, to, amount);
  5.         return true;
  6.     }
  7.     function _transfer(
  8.         address from,
  9.         address to,
  10.         uint256 amount
  11.     ) internal virtual {
  12.         require(from != address(0), "ERC20: transfer from the zero address");
  13.         require(to != address(0), "ERC20: transfer to the zero address");
  14.  
  15.         _beforeTokenTransfer(from, to, amount);
  16.  
  17.         uint256 fromBalance = _balances[from];
  18.         require(fromBalance >= amount, "ERC20: transfer amount exceeds balance");
  19.         unchecked {
  20.             _balances[from] = fromBalance - amount;
  21.         }
  22.         _balances[to] += amount;
  23.  
  24.         emit Transfer(from, to, amount);
  25.  
  26.         _afterTokenTransfer(from, to, amount);
  27.     }

transfer转帐函数，一个比较重要的功能，调用者可以将自己的余额转给其它帐户。

_transfer为private的具体实现函数。主要是作了一些必要的检查，然后从发起帐户扣减余额，再将余额加到接收帐户。最后发送了一个转帐事件，方便开发者监听转帐功能。这里的_beforeTokenTransfer和_afterTokenTransfer并没有实现具体功能，开发中可根据实现需要做一些功能实现。

  1.     // 获取被授权者可使用授权帐号的可使用余额
  2.     function allowance(address owner, address spender) public view virtual override returns (uint256) {
  3.         return _allowances[owner][spender];
  4.     }
  5.  
  6.     // 授权指定帐事情可使用自己一定额度的帐户余额。
  7.     // 授权spender, 可将自己余额。使用可使用的余额的总量为amount
  8.     function approve(address spender, uint256 amount) public virtual override returns (bool) {
  9.         address owner = msg.sender;
  10.         _approve(owner, spender, amount);
  11.         return true;
  12.     }
  13.     function _approve(
  14.         address owner,
  15.         address spender,
  16.         uint256 amount
  17.     ) internal virtual {
  18.         require(owner != address(0), "ERC20: approve from the zero address");
  19.         require(spender != address(0), "ERC20: approve  to the zero address");
  20.  
  21.         _allowances[owner][spender] = amount;
  22.         emit Approval(owner, spender, amount);
  23.     }

allowance、approve主要是实现授权其它帐户可以使用自己的余额，并设定使用上限。相关的授权者存储在_allowances变量中。

  1.     function increaseAllowance(address spender, uint256 addedValue) public virtual returns (bool) {
  2.         address owner = msg.sender;
  3.         _approve(owner, spender, _allowances[owner][spender] + addedValue);
  4.         return true;
  5.     }
  6.  
  7.     function decreaseAllowance(address spender, uint256 substractedValue) public virtual returns (bool) {
  8.         address owner = msg.sender;
  9.         uint256 currentAllowance = _allowances[owner][spender];
  10.         require(currentAllowance >= substractedValue, "ERC20: decreased allowance below zero");
  11.         unchecked {
  12.             _approve(owner, spender, currentAllowance - substractedValue);
  13.         }
  14.         return true;
  15.     }

increaseAllowance、decreaseAllowance两个函数是对approve函数功能的加强，对授权额度进行增减，这两个函数关不是ERC20协议中的内容。只是作者在参考源码时觉得有用，就加入了这两个函数。

  1.     function transferFrom(
  2.         address from,
  3.         address to,
  4.         uint256 amount
  5.     ) public virtual override returns (bool) {
  6.         address spender = msg.sender;
  7.         _spendAllowance(from, spender, amount);
  8.         _transfer(from, to, amount);
  9.         return true;
  10.     }
  11.     
  12.    function _spendAllowance(
  13.         address owner,
  14.         address spender,
  15.         uint256 amount
  16.     ) internal virtual {
  17.         uint256 currentAllowance = allowance(owner, spender);
  18.         if (currentAllowance != type(uint256).max) {
  19.             require(currentAllowance >= amount, "ERC20: insufficient allowance");
  20.             unchecked {
  21.                 _approve(owner, spender, currentAllowance - amount);
  22.             }
  23.         }
  24.     }

transferFrom，_spendAllowance是在授权额度下，进行转帐的功能实现。

transferFrom函数的from参数是授权帐户，to是余额接受帐户，amount是转帐余额，该函数的功能是将from帐户的余额转移amount个数据至to用户帐户中，调用者必须是from帐户通过_approve对其进行过授权，并且还有剩余的授权额度。该函数与transfer的区别是，transfer只能转移出调用者自己的帐户余额。

_spendAllowance是在进行授权转帐时首先扣减授权额度，保证被授权都在授权额度范围内使用转帐功能。

  1. function _mint(address account, uint256 amount) internal virtual {
  2.         require(account != address(0), "ERC20: mint to the zero address");
  3.  
  4.         _beforeTokenTransfer(address(0), account, amount);
  5.  
  6.         _totalSupply += amount;
  7.         _balances[account] += amount;
  8.         emit Transfer(address(0), account, amount);
  9.  
  10.         _afterTokenTransfer(address(0), account, amount);
  11.     }
  12.  
  13.     function _burn(address account, uint256 amount) internal virtual {
  14.         require(account != address(0), "ERC20: burn from the zero address");
  15.  
  16.         _beforeTokenTransfer(account, address(0), amount);
  17.  
  18.         uint256 accountBalance = _balances[account];
  19.         require(accountBalance >= amount, "ERC20: burn amount exceeds balance");
  20.         unchecked {
  21.             _balances[account] = accountBalance - amount;
  22.         }
  23.         _totalSupply -= amount;
  24.         emit Transfer(account, address(0), amount);
  25.         _afterTokenTransfer(account, address(0), amount);
  26.     }

_mint和_burn是两个相反的功能，一个是新铸造代币，一个是燃烧（销毁）代币。两个方法都是private,关没有对外开放。

完成上述三个源文件的代码就可能编译部署，选中ERC20.sol文件，完成编译。部署时要特别注意在选中Contract中的实现合约ERC20，不要误选了接口合约。

否则会部署后报如下错误，很多刚开始接触合约的读者都遇到该问题了，所以作者提示一下。

部署成功后，就可以查看并调用合约了。

一个比较健全的ERC20代币合约就完成了。下一章节给大家分享在ERC721协议下实现NTF相关的功能。

声明：本文内容由网友自发贡献，不代表【wpsshop博客】立场，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：https://www.wpsshop.cn/w/我家自动化/article/detail/369259?site
推荐阅读
相关标签

Copyright © 2003-2013 www.wpsshop.cn 版权所有，并保留所有权利。

  

闽ICP备14008679号