devbox
空白诗007
这个屌丝很懒，什么也没留下！
关注作者
热门标签
热门文章
当前位置:   article > 正文

【UnityShader入门精要】从简单的shader编写到基础光照_unity怎么写shader

作者：空白诗007 | 2024-07-16 06:46:13

赞

踩

unity怎么写shader

温(mian)馨(ze)提(sheng)示(ming):

  1. 此文内容质量差，仅作为个人学习过程记录
  2. 所有内容在UnityShader入门精要上都有

unity中的shader

最简单的VS/FS

创建一个材质和shader，并且赋给一个球，可以看到现在场景如图下：

打开此shader写个最简单的vs/fs：

可以看到现在只有白色，fs这里什么都没干，只是单纯设置了个颜色

稍微修改一下代码，增加输入输出的结构以及增加属性：

  1. Shader "Custom/simple_youyider"
  2. {
  3.     Properties
  4.     {
  5.         _Color ("Color Tint",Color)=(1.0,1.0,1.0,1.0)
  6.     }
  7.     SubShader
  8.     {
  9.         Pass
  10.         {
  11.             CGPROGRAM
  12.  
  13.             #pragma vertex vert
  14.             #pragma fragment frag
  15.  
  16.             fixed4 _Color;
  17.  
  18.             struct a2v
  19.             {
  20.                 float4 vertex:POSITION;
  21.                 float3 normal:NORMAL;
  22.                 float4 texcoord:TEXCOORD0;
  23.             };
  24.  
  25.             struct v2f
  26.             {
  27.                 float4 pos:SV_POSITION;
  28.                 fixed3 color:COLOR0;
  29.             };
  30.             
  31.             v2f vert(a2v v)
  32.             {
  33.                 v2f o;
  34.                 o.pos=UnityObjectToClipPos(v.vertex);
  35.                 o.color=v.normal*0.5+fixed3(0.5,0.5,0.5);
  36.                 return o;
  37.             }
  38.  
  39.             fixed4 frag(v2f i):SV_Target
  40.             {
  41.                 fixed3 c=i.color;
  42.                 c*=_Color.rgb;
  43.                 return fixed4(c,1.0);
  44.             }
  45.             
  46.             ENDCG
  47.         }
  48.     }
  49. }

这里在vs输出颜色时，通过法线进行了颜色的设置，因此不同的法线方向的shading point的颜色也不一样。虽然fs看似加了更改，但是_color都是1，fs依然是输入什么颜色就输出什么颜色

可以得到：

通过假色彩图像debug

这里vs的代码debug的话应该是只写一个color的赋值的，这边写在一起可以看到最后的输出很诡异哈哈哈

值得一提的是if中出现了两个内置函数：any() 函数是一个逻辑函数，用于判断括号内的条件表达式是否有任何一个元素为真；saturate() 函数用于将输入的值限制在 [0, 1] 的范围内

  1. Shader "Custom/falsecolor"
  2. {
  3.     SubShader
  4.     {
  5.         pass
  6.         {
  7.         CGPROGRAM
  8.  
  9.         #pragma vertex vert
  10.         #pragma fragment frag
  11.  
  12.         #include "UnityCG.cginc"
  13.  
  14.         struct v2f
  15.         {
  16.                 float4 pos:SV_POSITION;
  17.                 fixed4 color:COLOR0;
  18.         };
  19.         v2f vert(appdata_full v)
  20.         {
  21.             v2f o;
  22.             o.pos=UnityObjectToClipPos(v.vertex);
  23.  
  24.             o.color=fixed4(v.normal*0.5+fixed3(0.5,0.5,0.5),1.0);
  25.  
  26.             o.color=fixed4(v.tangent.xyz*0.5+fixed3(0.5,0.5,0.5),1.0);
  27.             
  28.             fixed3 binormal=cross(v.normal,v.tangent.xyz)*v.tangent.w;
  29.             o.color=fixed4(binormal*0.5+fixed3(0.5,0.5,0.5),1.0);
  30.  
  31.             o.color=fixed4(v.texcoord.xy,0.0,1.0);
  32.  
  33.             o.color=fixed4(v.texcoord1.xy,0.0,1.0);
  34.  
  35.             o.color=frac(v.texcoord);
  36.             if(any(saturate(v.texcoord)-v.texcoord))
  37.             {
  38.                 o.color.b=0.5;
  39.             }
  40.             o.color.a =1.0;
  41.  
  42.             o.color=frac(v.texcoord1);
  43.             if(any(saturate(v.texcoord1)-v.texcoord1))
  44.             {
  45.                 o.color.b=0.5;
  46.             }
  47.             o.color.a =1.0;
  48.  
  49.             return o;
  50.         }
  51.  
  52.         fixed4 frag(v2f i):SV_Target
  53.         {
  54.             return i.color;
  55.         }
  56.         ENDCG
  57.         }
  58.     }
  59. }

这里右边开启了帧调试器，可以在里面看到各个步骤的输出和数据

unity的基础光照

实现Gouraud shading的漫反射

值得一提的是 fixed3 worldNormal=normalize(mul(v.normal,(float3x3)unity_WorldToObject));我们知道法线在坐标变换的时候会变形，这就需要用到顶点变换矩阵的逆转置矩阵来获得法线该有的样子。由于这里是要把法线从局部坐标变为世界坐标，所以unity_WorldToObject是局部变世界坐标的逆矩阵，然后可以看到代码中mul函数是向量在左，矩阵在右，放在左边是为了实现同矩阵转置后右乘向量的一样效果。经过上面两步我们就获得了需要的逆转置矩阵。

  1. Shader "Custom/DiffuseVertexLevel_youyider"
  2. {
  3.     Properties
  4.     {
  5.         _Diffuse("Diffuse",Color)=(1,1,1,1)
  6.     }
  7.     SubShader
  8.     {
  9.         pass
  10.         {
  11.             Tags{"LightMode"="ForwardBase"}
  12.             CGPROGRAM
  13.  
  14.             #pragma vertex vert
  15.             #pragma fragment frag
  16.  
  17.             #include"Lighting.cginc"
  18.  
  19.             fixed4 _Diffuse;
  20.             
  21.             struct a2v
  22.             {
  23.                 float4 vertex:POSITION;
  24.                 float3 normal:NORMAL;
  25.             };
  26.  
  27.             struct v2f
  28.             {
  29.                 float4 pos:SV_POSITION;
  30.                 fixed3 color:COLOR;
  31.             };
  32.  
  33.             v2f vert(a2v v)
  34.             {
  35.                 v2f o;
  36.                 o.pos=UnityObjectToClipPos(v.vertex);
  37.  
  38.                 fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
  39.  
  40.                 fixed3 worldNormal=normalize(mul(v.normal,(float3x3)unity_WorldToObject));
  41.                 fixed3 worldLight=normalize(_WorldSpaceLightPos0.xyz);
  42.                 fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal,worldLight));
  43.  
  44.                 o.color=ambient+diffuse;
  45.  
  46.                 return o;
  47.             }
  48.  
  49.             fixed4 frag(v2f i):SV_Target
  50.             {
  51.                 return fixed4(i.color,1.0);
  52.             }
  53.             ENDCG
  54.         }
  55.  
  56.     }
  57.     Fallback"Diffuse"
  58. }

可以看到结果是这个样子

实现Phong shading的漫反射

这里的实现和上面的区别其实就是把上面在vs进行的颜色计算变道fs中

  1. Shader "Custom/DiffusePixelLevel_youyider"
  2. {
  3.     Properties
  4.     {
  5.         _Diffuse("Diffuse",Color)=(1,1,1,1)
  6.     }
  7.     SubShader
  8.     {
  9.         pass
  10.         {
  11.             Tags{"LightMode"="ForwardBase"}
  12.             CGPROGRAM
  13.  
  14.             #pragma vertex vert
  15.             #pragma fragment frag
  16.  
  17.             #include"Lighting.cginc"
  18.  
  19.             fixed4 _Diffuse;
  20.             
  21.             struct a2v
  22.             {
  23.                 float4 vertex:POSITION;
  24.                 float3 normal:NORMAL;
  25.             };
  26.  
  27.             struct v2f
  28.             {
  29.                 float4 pos:SV_POSITION;
  30.                 float3 worldNormal:TEXCOORD0;
  31.             };
  32.  
  33.             v2f vert(a2v v)
  34.             {
  35.                 v2f o;
  36.                 o.pos=UnityObjectToClipPos(v.vertex);
  37.  
  38.                 o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
  39.  
  40.                 return o;
  41.             }
  42.  
  43.             fixed4 frag(v2f i):SV_Target
  44.             {
  45.                 fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
  46.                 
  47.                 fixed3 worldNormal=normalize(i.worldNormal);
  48.  
  49.                 fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);
  50.  
  51.                 fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal,worldLightDir));
  52.  
  53.                 fixed3 color=ambient+diffuse;
  54.  
  55.                 return fixed4(color,1.0);
  56.             }
  57.             ENDCG
  58.         }
  59.  
  60.     }
  61.     FallBack "Diffuse"
  62. }

可以看到逐像素着色的阴影更细腻，逐顶点的有不平滑的地方（左下角亮面和暗面的交界处可以看到区别）

实现halfLambert光照

兰伯特光照模型是一种描述物体表面如何反射光线的模型，它假设物体表面是完全漫反射的，也就是说，光线会均匀地向所有方向反射。

然而，兰伯特模型有一个问题，那就是当光线与物体表面的夹角接近90度时，反射的光线会变得非常暗，这在某些情况下可能会导致不真实的效果。为了解决这个问题，人们提出了半兰伯特光照模型。

半兰伯特光照模型的主要思想是将兰伯特模型的反射强度曲线稍微调整一下，使得当光线与物体表面的夹角接近90度时，反射的光线不会变得太暗。这样可以使得物体表面在各种光照条件下都能保持一定的亮度，从而得到更真实的效果。

在实际应用中，半兰伯特光照模型常常用于游戏和动画的渲染，因为它可以在保持计算效率的同时，提供比兰伯特模型更好的视觉效果。

修改的地方非常少：

  1. Shader "Custom/HalfLambert_youyider"
  2. {
  3.     Properties
  4.     {
  5.         _Diffuse("Diffuse",Color)=(1,1,1,1)
  6.     }
  7.     SubShader
  8.     {
  9.         pass
  10.         {
  11.             Tags{"LightMode"="ForwardBase"}
  12.             CGPROGRAM
  13.  
  14.             #pragma vertex vert
  15.             #pragma fragment frag
  16.  
  17.             #include"Lighting.cginc"
  18.  
  19.             fixed4 _Diffuse;
  20.             
  21.             struct a2v
  22.             {
  23.                 float4 vertex:POSITION;
  24.                 float3 normal:NORMAL;
  25.             };
  26.  
  27.             struct v2f
  28.             {
  29.                 float4 pos:SV_POSITION;
  30.                 float3 worldNormal:TEXCOORD0;
  31.             };
  32.  
  33.             v2f vert(a2v v)
  34.             {
  35.                 v2f o;
  36.                 o.pos=UnityObjectToClipPos(v.vertex);
  37.  
  38.                 o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
  39.  
  40.                 return o;
  41.             }
  42.  
  43.             fixed4 frag(v2f i):SV_Target
  44.             {
  45.                 fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
  46.                 
  47.                 fixed3 worldNormal=normalize(i.worldNormal);
  48.  
  49.                 fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);
  50.  
  51.                 fixed halfLambert=dot(worldNormal,worldLightDir)*0.5+0.5;
  52.                 fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*halfLambert;
  53.  
  54.                 fixed3 color=ambient+diffuse;
  55.  
  56.                 return fixed4(color,1.0);
  57.             }
  58.             ENDCG
  59.         }
  60.  
  61.     }
  62.     FallBack "Diffuse"
  63. }

这个其实就只是在fs中的diffuse项上稍作修改，可以看到shader的改动或许不大，但是效果却可能因为一行或两行代码而发生很大的区别，即使他们每个步骤都几乎一样

实现Gouraud shading的镜面反射

这里的代码不只有逐顶点的镜面反射，还包含了逐顶点的漫反射

  1. Shader "Custom/SpecularVertexLevel_youyider"
  2. {
  3.     Properties
  4.     {
  5.         _Diffuse("Diffuse", Color) = (1,1,1,1)
  6.         _Specular("Specular",Color)=(1,1,1,1)
  7.         _Gloss("Gloss",Range(8.0,256))=20
  8.     }
  9.     SubShader
  10.     {
  11.         Pass
  12.         {
  13.         Tags { "LightMode"="ForwardBase" }
  14.  
  15.         CGPROGRAM
  16.  
  17.             #pragma vertex vert
  18.             #pragma fragment frag
  19.  
  20.             #include"Lighting.cginc"
  21.  
  22.             fixed4 _Diffuse;
  23.             float _Gloss;
  24.             fixed4 _Specular;
  25.         
  26.             struct a2v
  27.             {
  28.                 float4 vertex:POSITION;
  29.                 float3 normal:NORMAL;
  30.             };
  31.  
  32.             struct v2f
  33.             {
  34.                 float4 pos:SV_POSITION;
  35.                 fixed3 color:COLOR;
  36.             };
  37.  
  38.             v2f vert(a2v v)
  39.             {
  40.                 v2f o;
  41.                 o.pos=UnityObjectToClipPos(v.vertex);
  42.  
  43.                 fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
  44.  
  45.                 fixed3 worldNormal=normalize(mul(v.normal,(float3x3)unity_WorldToObject));
  46.                 fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);
  47.  
  48.                 fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal,worldLightDir));
  49.  
  50.                 fixed3 reflectDir=normalize(reflect(-worldLightDir,worldNormal));
  51.                 fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz-mul(unity_ObjectToWorld,v.vertex).xyz);
  52.  
  53.                 fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(saturate(dot(reflectDir,viewDir)),_Gloss);
  54.  
  55.                 o.color = ambient + diffuse +specular;
  56.                 return o;
  57.             }
  58.  
  59.             fixed4 frag(v2f i):SV_Target
  60.             {
  61.                 return fixed4(i.color,1.0);
  62.             }
  63.         ENDCG
  64.         }
  65.     }
  66.     FallBack "Specular"
  67. }

效果图如下：

实现Phong shading的镜面反射

直接放代码：

  1. Shader "Custom/SpecularPixelLevel_youyider"
  2. {
  3.     Properties
  4.     {
  5.         _Diffuse("Diffuse", Color) = (1,1,1,1)
  6.         _Specular("Specular",Color)=(1,1,1,1)
  7.         _Gloss("Gloss",Range(8.0,256))=20
  8.     }
  9.     SubShader
  10.     {
  11.         Pass
  12.         {
  13.         Tags { "LightMode"="ForwardBase" }
  14.  
  15.         CGPROGRAM
  16.  
  17.             #pragma vertex vert
  18.             #pragma fragment frag
  19.  
  20.             #include"Lighting.cginc"
  21.  
  22.             fixed4 _Diffuse;
  23.             float _Gloss;
  24.             fixed4 _Specular;
  25.         
  26.             struct a2v
  27.             {
  28.                 float4 vertex:POSITION;
  29.                 float3 normal:NORMAL;
  30.             };
  31.  
  32.             struct v2f
  33.             {
  34.                 float4 pos:SV_POSITION;
  35.                 float3 worldNormal:TEXCOORD0;
  36.                 float3 worldPos:TEXCOORD1;
  37.             };
  38.  
  39.             v2f vert(a2v v)
  40.             {
  41.                 v2f o;
  42.                 o.pos=UnityObjectToClipPos(v.vertex);
  43.  
  44.                 o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
  45.  
  46.                 o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
  47.  
  48.                 return o;
  49.             }
  50.  
  51.             fixed4 frag(v2f i):SV_Target
  52.             {                
  53.                 fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
  54.  
  55.                 fixed3 worldNormal=normalize(i.worldNormal);
  56.                 fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);
  57.  
  58.                 fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal,worldLightDir));
  59.  
  60.                 fixed3 reflectDir=normalize(reflect(-worldLightDir,worldNormal));
  61.                 fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz-i.worldPos.xyz);
  62.  
  63.                 fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(saturate(dot(reflectDir,viewDir)),_Gloss);
  64.  
  65.                 return fixed4(ambient + diffuse +specular,1.0);
  66.             }
  67.         ENDCG
  68.         }
  69.     }
  70.     FallBack "Specular"
  71. }

实现Blinn-Phong光照模型

前面的镜面反射已经是加上了漫反射，但是在高光反射的时候计算了反射方向，通过Blinn光照模型使用视角方向和光照方向相加并且归一化得到，这样的计算量没有之前的计算量那么费。

代码如下：

  1. Shader "Custom/BlinnPhong_youyider"
  2. {
  3.     Properties
  4.     {
  5.         _Diffuse("Diffuse", Color) = (1,1,1,1)
  6.         _Specular("Specular",Color)=(1,1,1,1)
  7.         _Gloss("Gloss",Range(8.0,256))=20
  8.     }
  9.     SubShader
  10.     {
  11.         Pass
  12.         {
  13.         Tags { "LightMode"="ForwardBase" }
  14.  
  15.         CGPROGRAM
  16.  
  17.             #pragma vertex vert
  18.             #pragma fragment frag
  19.  
  20.             #include"Lighting.cginc"
  21.  
  22.             fixed4 _Diffuse;
  23.             float _Gloss;
  24.             fixed4 _Specular;
  25.         
  26.             struct a2v
  27.             {
  28.                 float4 vertex:POSITION;
  29.                 float3 normal:NORMAL;
  30.             };
  31.  
  32.             struct v2f
  33.             {
  34.                 float4 pos:SV_POSITION;
  35.                 float3 worldNormal:TEXCOORD0;
  36.                 float3 worldPos:TEXCOORD1;
  37.             };
  38.  
  39.             v2f vert(a2v v)
  40.             {
  41.                 v2f o;
  42.                 o.pos=UnityObjectToClipPos(v.vertex);
  43.  
  44.                 o.worldNormal=mul(v.normal,(float3x3)unity_WorldToObject);
  45.  
  46.                 o.worldPos=mul(unity_ObjectToWorld,v.vertex).xyz;
  47.  
  48.                 return o;
  49.             }
  50.  
  51.             fixed4 frag(v2f i):SV_Target
  52.             {                
  53.                 fixed3 ambient=UNITY_LIGHTMODEL_AMBIENT.xyz;
  54.  
  55.                 fixed3 worldNormal=normalize(i.worldNormal);
  56.                 fixed3 worldLightDir=normalize(_WorldSpaceLightPos0.xyz);
  57.  
  58.                 fixed3 diffuse=_LightColor0.rgb*_Diffuse.rgb*saturate(dot(worldNormal,worldLightDir));
  59.  
  60.                 fixed3 viewDir=normalize(_WorldSpaceCameraPos.xyz-i.worldPos.xyz);
  61.                 fixed3 halfDir=normalize(worldLightDir+viewDir);
  62.  
  63.                 fixed3 specular=_LightColor0.rgb*_Specular.rgb*pow(max(dot(halfDir,worldNormal),0),_Gloss);
  64.  
  65.                 return fixed4(ambient + diffuse +specular,1.0);
  66.             }
  67.         ENDCG
  68.         }
  69.     }
  70.     FallBack "Specular"
  71. }

效果如下：

声明：本文内容由网友自发贡献，不代表【wpsshop博客】立场，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：https://www.wpsshop.cn/w/空白诗007/article/detail/832760
推荐阅读
相关标签

Copyright © 2003-2013 www.wpsshop.cn 版权所有，并保留所有权利。

  

闽ICP备14008679号