devbox
繁依Fanyi0
这个屌丝很懒，什么也没留下！
关注作者
热门标签
热门文章
当前位置:   article > 正文

小梅哥Xilinx FPGA学习笔记8——从计数器到可控线性序列机_小梅哥笔记

作者：繁依Fanyi0 | 2024-04-11 03:34:11

赞

踩

小梅哥笔记

目录

一、功能介绍

二、任务1的代码编写

1.设计文件

2.激励文件

3.仿真图

三、任务2的代码编写

实现思路一：

1.设计文件

2.激励文件

3.仿真图

实现思路二：

1.设计文件

2.激励文件

3.仿真图

四、任务3的代码编写

1.设计文件

2.激励文件

3.仿真图

五、任务4的代码编写

1.设计文件

2.激励文件

3.仿真图​编辑

六、总结

一、功能介绍

任务1：让LED灯按照亮0.25秒，灭0.75秒的状态循环亮灭

任务2：让LED灯按照亮0.25秒，灭0.5秒，亮0.75秒，灭1秒的状态循环亮灭

任务3：以0.25为基本的LED状态变化间隔（最小时间单元）以8小段·为一个循环周期（参考任务二10个小段）；LED在每一小段该点亮还是该熄灭由8个输入端口决定。

任务4：在任务三的基础上，实现每隔一定时间，比如1秒钟，执行一轮LED8个状态的切换控制。

二、任务1的代码编写

实现思路：计数器相当于一个刻度时间尺，在一秒的时间内，首先led应该是高电平，即计数器开始计数时LED电平就是高电平，然后当计数器计到0.25s后，LED就变成低电平了，什么时候又变成高电平呢？当然是1秒结束后，也就是计数器重新从0计数时LED变为高电平，此时第一个1秒循环结束，开始下一循环。

1.设计文件

  1. //功能实现led亮0.25s，灭0.75s
  2. module LED_ctrl0(
  3.     input Clk,
  4.     input Reset_n,
  5.     output reg Led
  6.     );
  7.     
  8.     reg [25:0]counter;//定义计数器位数，板上时钟资源是20ns为一个周期，所以要用计时数除以20ns来计算计时次数。最后将次数转化成二进制位，有几位就定义几位计时器
  9.     //计数器计数
  10.     always@(posedge Clk or negedge Reset_n)
  11.     if(!Reset_n)//可见Reset_n复位是低电平有效   
  12.         counter <= 0;
  13.     else if(counter == 50_000_000-1)  
  14.         counter <= 0;
  15.     else
  16.         counter <= counter + 1'd1;
  17.         
  18.     always@(posedge Clk or negedge Reset_n)
  19.     if(!Reset_n)//可见Reset_n复位是低电平有效     
  20.         Led <= 0; 
  21.     else if(counter == 0)  
  22.         Led <= 1;    
  23.     else if(counter == 12_500_000-1)    
  24.         Led <= !Led; 
  25.     else  
  26.         Led <= Led;     
  27. endmodule

2.激励文件

  1. `timescale 1ns / 1ns
  2.  
  3. module LED_ctrl0_tb();
  4.  
  5.     reg Clk;
  6.     reg Reset_n;
  7.     wire Led;
  8.  
  9. LED_ctrl0 LED_ctrl0(
  10.     .Clk(Clk),
  11.     .Reset_n(Reset_n),
  12.     .Led(Led)
  13.     );
  14.      
  15.     initial Clk = 1;//初始信号为高电平
  16.     always #10 Clk = ~Clk;//延时10ns以后初始信号取反，这句话是总是执行的。
  17.     
  18.     //产生激励复位信号
  19.     initial begin
  20.         Reset_n = 0;//开始复位信号为0，有效复位
  21.         #201  Reset_n = 1;//201ns以后复位信号变为高电平，无效电平。开始仿真
  22.         #2000000000;//两秒仿真
  23.         $stop;//停止仿真
  24.     end
  25. endmodule

3.仿真图

三、任务2的代码编写

实现思路一：

计数器相当于一个刻度时间尺，在2.5s的时间内，首先led应该是高电平，保持0.25s,然后是低电平并保持0.5s,然后是高电平保持0.75s，最后是低电平保持1s。即计数器开始计数时LED电平就是高电平，然后当计数器计到0.25s后，LED就变成低电平了，什么时候又变成高电平呢？当然是0.75s秒后，那什么时候又变成低电平呢？当然是1.5s后啦，最后就是2s也就是计数器变为0时led重新拉高，一个循环结束。

1.设计文件

  1. //功能实现led亮0.25s，灭0.5s，亮0.75s,灭1s
  2. module LED_ctrl1(
  3.     input Clk,
  4.     input Reset_n,
  5.     output reg Led
  6.     );
  7.     
  8.     parameter MCNT = 1000;
  9.  
  10.     reg [26:0]counter;//定义计数器位数，板上时钟资源是20ns为一个周期，所以要用计时数除以20ns来计算计时次数。最后将次数转化成二进制位，有几位就定义几位计时器
  11.     //计数器计数
  12.     always@(posedge Clk or negedge Reset_n)
  13.     if(!Reset_n)//可见Reset_n复位是低电平有效   
  14.         counter <= 0;
  15.     else if(counter == 125_000*MCNT -1)  
  16.         counter <= 0;
  17.     else
  18.         counter <= counter + 1'd1;
  19.         
  20.     always@(posedge Clk or negedge Reset_n)
  21.     if(!Reset_n)//可见Reset_n复位是低电平有效     
  22.         Led <= 0; 
  23.     else if(counter == 0)  
  24.         Led <= 1;    
  25.     else if(counter == 12_500*MCNT)    
  26.         Led <= !Led; 
  27.     else if(counter == 37_500*MCNT)    
  28.         Led <= !Led; 
  29.     else if(counter == 75_000*MCNT)    
  30.         Led <= !Led;
  31.     else  
  32.         Led <= Led;     
  33. endmodule

2.激励文件

  1. `timescale 1ns / 1ns
  2.  
  3. module LED_ctrl0_tb();
  4.  
  5.     reg Clk;
  6.     reg Reset_n;
  7.     wire Led;
  8.  
  9. LED_ctrl1 LED_ctrl3_inst0(
  10.     .Clk(Clk),
  11.     .Reset_n(Reset_n),
  12.     .Led(Led)
  13.     );
  14.  
  15.     defparam LED_ctrl3_inst0.MCNT = 1;
  16.    
  17.     initial Clk = 1;//初始信号为高电平
  18.     always #10 Clk = ~Clk;//延时10ns以后初始信号取反，这句话是总是执行的。
  19.     
  20.     //产生激励复位信号
  21.     initial begin
  22.         Reset_n = 0;//开始复位信号为0，有效复位
  23.         #201  Reset_n = 1;//201ns以后复位信号变为高电平，无效电平。开始仿真
  24.         #2000000;//两毫秒仿真
  25.         #2000000;//两毫秒仿真
  26.         $stop;//停止仿真
  27.     end
  28. endmodule

3.仿真图

实现思路二：

可以将2.5S等分为10份，每一份做不同的事情。此时使用两个计数器来实现，其中一个计数器用来计时0.25S另外一个计时器用来计算计数器1计满0.25S的次数。这样就可以在不同的时刻做不同的事情了。框图如下图所示，有助于理解。

1.设计文件

  1. //功能实现led亮0.25s，灭0.5s，亮0.75s,灭1s
  2. module LED_ctrl2(
  3.     input Clk,
  4.     input Reset_n,
  5.     output reg Led
  6.     );
  7.   
  8.     reg [23:0]counter0;//定义计数器位数，板上时钟资源是20ns为一个周期，所以要用计时数除以20ns来计算计时次数。最后将次数转化成二进制位，有几位就定义几位计时器
  9.     reg [3:0]counter1; 
  10.   
  11.     parameter MCNT = 1000;
  12.  
  13.     //计数器计数
  14.     always@(posedge Clk or negedge Reset_n)
  15.     if(!Reset_n)//可见Reset_n复位是低电平有效       
  16.         counter0 <= 0;   
  17.     else if(counter0 == 12_500*MCNT -1) 
  18.         counter0 <= 0;
  19.     else
  20.         counter0 <= counter0 + 1'd1;
  21.      
  22.     always@(posedge Clk or negedge Reset_n)
  23.     if(!Reset_n)//可见Reset_n复位是低电平有效    
  24.         counter1 <= 0;     
  25.     else if(counter0 == 12_500*MCNT-1)
  26.     begin  
  27.         if(counter1 == 9)
  28.             counter1 <= 0;
  29.         else 
  30.             counter1 <= counter1+1'd1; 
  31.     end
  32.     else
  33.         counter1 <= counter1;
  34. //使用if else语句实现     
  35. //    always@(posedge Clk or negedge Reset_n)
  36. //    if(!Reset_n)//可见Reset_n复位是低电平有效     
  37. //        Led <= 0; 
  38. //    else if(counter1 == 0)  
  39. //        Led <= 1;    
  40. //    else if(counter1 == 1||counter1 == 2)    
  41. //        Led <= 0; 
  42. //    else if(counter1 == 3||counter1 == 4||counter1 == 5)    
  43. //        Led <= 1; 
  44. //    else if(counter1 == 6||counter1 == 7||counter1 == 8||counter1 == 9)    
  45. //        Led <= 0; 
  46. //    else  
  47. //        Led <= Led;   
  48. //使用case语句实现
  49. always@(posedge Clk or negedge Reset_n)
  50.     if(!Reset_n)//可见Reset_n复位是低电平有效     
  51.         Led <= 0; 
  52.     else begin
  53.         case(counter1)
  54.             0:Led <= 1; 
  55.             1:Led <= 0; 
  56.             2:Led <= 0; 
  57.             3:Led <= 1; 
  58.             4:Led <= 1;
  59.             5:Led <= 1;
  60.             6:Led <= 0;
  61.             7:Led <= 0;
  62.             8:Led <= 0;
  63.             9:Led <= 0;
  64.             default:Led <= Led ;
  65.          endcase    
  66.     end  
  67. endmodule
  68.

2.激励文件

同实现思路一

3.仿真图

同实现思路一

四、任务3的代码编写

实现思路二：可以将2S等分为8份，每一份做不同的事情。此时使用两个计数器来实现，其中一个计数器用来计时0.25S另外一个计时器用来计算计数器1计满0.25S的次数。这样就可以在不同的时刻做不同的事情了。

1.设计文件

  1. //功能实现led亮0.25s，灭0.5s，亮0.75s,灭1s
  2. module LED_ctrl3(
  3.     input Clk,
  4.     input Reset_n,
  5.     input [7:0]SW,
  6.     output reg Led
  7.     );
  8.   
  9.     reg [23:0]counter0;//定义计数器位数，板上时钟资源是20ns为一个周期，所以要用计时数除以20ns来计算计时次数。最后将次数转化成二进制位，有几位就定义几位计时器
  10.     reg [2:0]counter1;
  11.     
  12.     parameter MCNT = 12500000-1;   
  13.     //计数器计数
  14.     always@(posedge Clk or negedge Reset_n)
  15.     if(!Reset_n)//可见Reset_n复位是低电平有效       
  16.         counter0 <= 0;   
  17.     else if(counter0 == MCNT) 
  18.         counter0 <= 0;
  19.     else
  20.         counter0 <= counter0 + 1'd1;
  21.     
  22.     //8个数计数计到7自动清零。 
  23.     always@(posedge Clk or negedge Reset_n)
  24.     if(!Reset_n)//可见Reset_n复位是低电平有效    
  25.         counter1 <= 0;     
  26.     else if(counter0 == MCNT)
  27.         counter1 <= counter1+1;
  28.     else
  29.         counter1 <= counter1;
  30.  
  31. //使用case语句实现
  32. always@(posedge Clk or negedge Reset_n)
  33.     if(!Reset_n)//可见Reset_n复位是低电平有效     
  34.         Led <= 0; 
  35.     else begin
  36.         case(counter1)
  37.             0:Led <= SW[0]; 
  38.             1:Led <= SW[1]; 
  39.             2:Led <= SW[2]; 
  40.             3:Led <= SW[3]; 
  41.             4:Led <= SW[4];
  42.             5:Led <= SW[5];
  43.             6:Led <= SW[6];
  44.             7:Led <= SW[7];
  45.             default:Led <= Led ;
  46.          endcase    
  47.     end  
  48. endmodule

2.激励文件

  1. `timescale 1ns / 1ns
  2.  
  3. module LED_ctrl0_tb();
  4.  
  5.     reg Clk;
  6.     reg Reset_n;
  7.     reg [7:0]SW;
  8.     wire Led;
  9.  
  10. LED_ctrl3 LED_ctrl3_inst0(
  11.     .Clk(Clk),
  12.     .Reset_n(Reset_n),
  13.     .Led(Led),
  14.     .SW(SW)
  15.     );
  16.     
  17.     defparam LED_ctrl3_inst0.MCNT = 12500-1;
  18.  
  19.     initial Clk = 1;//初始信号为高电平
  20.     always #10 Clk = ~Clk;//延时10ns以后初始信号取反，这句话是总是执行的。
  21.     
  22.     //产生激励复位信号
  23.     initial begin
  24.         Reset_n = 0;//开始复位信号为0，有效复位
  25.         SW = 8'b0010_1010;
  26.         #201  Reset_n = 1;//201ns以后复位信号变为高电平，无效电平。开始仿真
  27.         #2_000_000;//仿真2ms
  28.         SW = 8'b0000_0001;
  29.         #2_000_000;//仿真2ms
  30.         $stop;//停止仿真
  31.     end
  32. endmodule

3.仿真图

五、任务4的代码编写

实现思路一：可以将3S等分为12份，每一份做不同的事情。此时前4份为空闲状态，后8位为动态变化状态，其中一个计数器用来计时0.25S，另外一个计时器用来计算计数器1计满0.25S的次数。这样就可以在不同的时刻做不同的事情了。

实现思路二（百用）：计数器是一个刻度尺，写一个周期为3S的计数器，将这个计数器作为一个时间刻度尺，找到1S,1.25S,1.5S,1.75S,2S,2.25S,2.5S,2.75S,3S对应的计数器的值1。分别在计数器到达这些值的时候，控制LED输出SW的位，或者空闲态的0值。

实现思路三：使用3个计时器counter0,counter1,counter2;他们各自的作用是如下图：

counter1用于计时counter计满的次数，所以代码不用修改。

上面counter0和counter2中的en_counter0和en_counter2都是控制各个计时器是否开始计数的开关。en_counter2什么时候计数，什么时候不计数的框图如下图所示。

本文仅使用思路三进行实验。

1.设计文件

  1. //功能实现led亮0.25s，灭0.5s，亮0.75s,灭1s
  2. module LED_ctrl5(
  3.     input Clk,
  4.     input Reset_n,
  5.     input [7:0]SW,
  6.     output reg Led
  7.     );
  8.   
  9.     reg [23:0]counter0;//定义计数器位数，板上时钟资源是20ns为一个周期，所以要用计时数除以20ns来计算计时次数。最后将次数转化成二进制位，有几位就定义几位计时器
  10.     reg [2:0]counter1;//定时7个状态
  11.     reg [25:0]counter2;//定时1s用来表示空闲状态
  12.     reg encounter2;
  13.     reg encounter0;
  14.     
  15.     parameter MCNT0 = 12500000-1; 
  16.     parameter MCNT2 = 50000000-1;  
  17.     
  18.     always@(posedge Clk or negedge Reset_n)
  19.     if(!Reset_n)//可见Reset_n复位是低电平有效       
  20.         encounter2 <= 1'd1;//一开始就给一个有效值，等复位结束后就保持为有效值，然后题目要求就是一开始就是开始1S空闲，所以一开始counter2就开始计时。   
  21.     else if((counter1 == 7) && (counter0 == MCNT0))     
  22.         encounter2 <= 1'd1;
  23.     else if(counter2 == MCNT2)
  24.         encounter2 <= 1'd0;
  25.     else
  26.         encounter2 <= encounter2;   
  27.       
  28.     //assign encounter0 = !encounter2;   
  29.     always@(posedge Clk or negedge Reset_n)
  30.     if(!Reset_n)//可见Reset_n复位是低电平有效       
  31.         encounter0 <= 1'd0;//一开始就给一个有效值，等复位结束后就保持为有效值，然后题目要求就是一开始就是开始1S空闲，所以一开始counter2就开始计时。   
  32.     else if(counter2 == MCNT2)     
  33.         encounter0 <= 1'd1;
  34.     else if((counter1 == 7) && (counter0 == MCNT0))
  35.         encounter0 <= 1'd0;
  36.     else
  37.         encounter0 <= encounter0;      
  38.              
  39.     //计数器计数
  40.     always@(posedge Clk or negedge Reset_n)
  41.     if(!Reset_n)//可见Reset_n复位是低电平有效       
  42.         counter0 <= 0;   
  43.     else if(encounter0)
  44.     begin
  45.         if(counter0 == MCNT0) 
  46.             counter0 <= 0;
  47.         else
  48.             counter0 <= counter0 + 1'd1;
  49.     end
  50.     else
  51.         counter0 <= 0;//counter0未使能不计数
  52.          
  53.     always@(posedge Clk or negedge Reset_n)
  54.     if(!Reset_n)//可见Reset_n复位是低电平有效    
  55.         counter1 <= 0;     
  56.     else if(counter0 == MCNT0)
  57.         counter1 <= counter1+1;
  58.     else
  59.         counter1 <= counter1; 
  60.         
  61.     always@(posedge Clk or negedge Reset_n)
  62.     if(!Reset_n)//可见Reset_n复位是低电平有效       
  63.         counter2 <= 0;   
  64.     else if(encounter2)
  65.     begin
  66.         if(counter2 == MCNT2) 
  67.             counter2 <= 0;
  68.         else
  69.             counter2 <= counter2 + 1'd1;
  70.     end
  71.     else
  72.         counter2 <= 0;//counter0未使能不计数        
  73.                
  74. //使用case语句实现
  75. always@(posedge Clk or negedge Reset_n)
  76.     if(!Reset_n)//可见Reset_n复位是低电平有效     
  77.         Led <= 0; 
  78.     else if(encounter2 == 1)
  79.         Led <= 0;
  80.     else //if(encounter2 == 0)
  81.     begin
  82.         case(counter1)
  83.             0:Led <= SW[0]; 
  84.             1:Led <= SW[1]; 
  85.             2:Led <= SW[2]; 
  86.             3:Led <= SW[3]; 
  87.             4:Led <= SW[4]; 
  88.             5:Led <= SW[5]; 
  89.             6:Led <= SW[6];
  90.             7:Led <= SW[7];
  91.             default:Led <= Led ;
  92.          endcase    
  93.     end  
  94. endmodule

2.激励文件

  1. `timescale 1ns / 1ns
  2.  
  3. module LED_ctrl0_tb();
  4.  
  5.     reg Clk;
  6.     reg Reset_n;
  7.     reg [7:0]SW;
  8.     wire Led;
  9.  
  10. LED_ctrl5 LED_ctrl5(
  11.     .Clk(Clk),
  12.     .Reset_n(Reset_n),
  13.     .Led(Led),
  14.     .SW(SW)
  15.     );    
  16.  
  17.     defparam LED_ctrl5.MCNT0 = 12500-1;
  18.     defparam LED_ctrl5.MCNT2 = 50000-1;
  19.      
  20.     initial Clk = 1;//初始信号为高电平
  21.     always #10 Clk = ~Clk;//延时10ns以后初始信号取反，这句话是总是执行的。
  22.     
  23.     //产生激励复位信号
  24.     initial begin
  25.         Reset_n = 0;//开始复位信号为0，有效复位
  26.         SW = 8'b1010_1001;
  27.         #201  Reset_n = 1;//201ns以后复位信号变为高电平，无效电平。开始仿真
  28.         #40000000;//仿真40ms
  29.         
  30.         $stop;//停止仿真
  31.     end
  32. endmodule

3.仿真图

六、总结

1.case语句，没有列举完的情况，需要加一个默认项列举完

  1.     case(counter)
  2.         MCNT*1/8 -1:led <= ctrl[0];//语句1
  3.         MCNT*2/8 -1:led <= ctrl[1];
  4.         MCNT*3/8 -1:led <= ctrl[2];
  5.         MCNT*4/8 -1:led <= ctrl[3];
  6.         MCNT*5/8 -1:led <= ctrl[4];
  7.         MCNT*6/8 -1:led <= ctrl[5];
  8.         MCNT*7/8 -1:led <= ctrl[6];
  9.         MCNT*8/8 -1:led <= ctrl[7];
  10.         default:led <= led;          
  11.     endcase

2.计数器可以用作时间刻度尺，每个时间都可以进行断点，然后在不同的时间点去做不同的事情。

  1.     always@(posedge Clk or negedge Reset_n)
  2.     if(!Reset_n)//可见Reset_n复位是低电平有效     
  3.         Led <= 0; 
  4.     else if(counter == 0)  
  5.         Led <= 1;    
  6.     else if(counter == 12_500*MCNT)    
  7.         Led <= !Led; 
  8.     else if(counter == 37_500*MCNT)    
  9.         Led <= !Led; 
  10.     else if(counter == 75_000*MCNT)    
  11.         Led <= !Led;
  12.     else  
  13.         Led <= Led;     
  14. endmodule

声明：本文内容由网友自发贡献，不代表【wpsshop博客】立场，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：https://www.wpsshop.cn/w/繁依Fanyi0/article/detail/402680
推荐阅读
相关标签

Copyright © 2003-2013 www.wpsshop.cn 版权所有，并保留所有权利。

  

闽ICP备14008679号