devbox
羊村懒王
这个屌丝很懒，什么也没留下！
关注作者
热门标签
热门文章
当前位置:   article > 正文

UnityShader17：光照属性与阴影_lighting_coords

作者：羊村懒王 | 2024-02-18 12:12:35

赞

踩

lighting_coords

前置：UnityShader16：点光源和聚光灯

一、一些重要的光照、阴影属性

一个一个来（绿色的部分暂时可以不用了解）：

  1. Type：光照类型，除了常用的3个，还有一个面光源
  2. Color：光照颜色
  3. Mode：光照模式：实时光照/混合/烘培光照
  4. Intensity：光照强度
  5. Indirect Multiplier：在计算该灯光所产生的间接光照时的强度倍乘
  6. Shadow Type：阴影类型：无阴影/硬阴影/软阴影
  7. Cookie：用于光照投影的纹理
  8. Cookie Size：Cookie 贴图大小倍数，只有平行光可以设置
  9. Draw Halo：灯光是否显示辉光，一般用于模拟光晕效果
  10. Flare：辉光贴图，一般为黑白图
  11. Render Mode：光照渲染模式，是否为重要光照，这个在这一章有详细介绍
  12. Culling Mask：选择哪些层受光源的影响，如果不勾选对应层，那么在这个层的物体将不会受到光照影响

其中对于点光源还有一个A半径属性，对于聚光灯还有一个B张角属性

关于阴影部分：

  • Baked Shadow Angle：只有为平行光软阴影时才可设置，一般用来在阴影的边缘增加人造软化，让阴影看起来更自然
  • Realtime Shadows Strength：实时阴影强度
  • Resolution：阴影贴图分辨率，较高的分辨率能增加阴影的保真度，但会消耗更多的GPU时间和存储空间
  • Bias：阴影偏移，也是阴影被推离光线的距离，范围为0到2，默认值为0.5，一般用于避免人工物体自阴影的错误
  • Normal Bias：法线偏移，也是投射阴影的表面相对于周围正常表面的下沉效果，范围为0到3，默认值为0.4，一般用于避免人工物体自阴影的错误
  • Near Plane：阴影最近剪切平面，与摄影机距离小于这个距离的场景物体将不产生阴影

关于物体是否接受阴影的设置：

其中将 Cast Shadows 设置为 Two Sided 后，对应物体的所有面都会计算阴影信息

二、阴影的实现原理

可以参考 OpenGL 的部分教程：

一个好消息是，关于阴影的计算 Unity 已经帮我们写好了，如不是需要特殊定制，不需要写太多的代码

在新版本的 Unity 里，其采用了屏幕空间阴影映射技术(Screenspace Shadow Map)来计算阴影，这也是原先延迟渲染中产生阴影的方法，不过对于部分显卡不支持 MRT 的平台可能就不支持这种特性

三、阴影的实现

只需要在之前的基础上更改3个地方就可以了：

1)：内置宏 SHADOW_COORDS() 或 LIGHTING_COORDS(,)：

  1. struct vert2frag 
  2. {
  3.     float4 pos: SV_POSITION;
  4.     float3 wPos: TEXCOORD0;
  5.     float3 wNormal: TEXCOORD1;
  6.     float2 uv: TEXCOORD2;
  7.     SHADOW_COORDS(3)
  8. };

内置宏的参数需要一个可用的插值寄存器索引值，它的作用就是声明一个用于阴影纹理采样坐标 _ShadowCoord

而对于 LIGHTING_COORDS 宏，它同时声明了用于阴影纹理采样坐标 _ShadowCoord 和用于衰减纹理采样坐标 _LightCoord

2)：内置宏 TRANSFER_SHADOW 或 TRANSFER_VERTEX_TO_FRAGMENT：

  1. vert2frag vert(_2vert v) 
  2. {
  3.     vert2frag o;
  4.     //……
  5.     TRANSFER_SHADOW(o);
  6.     return o;
  7. }

该宏的展开为一段计算阴影纹理坐标的代码，它会使用 v.vertex 或 v.pos 来计算坐标 _ShadowCoord，因此你需要保证这两个变量名要与宏内的代码相匹配，除此之外，顶点着色器的输入参数变量名也必须为 v

而对于 TRANSFER_VERTEX_TO_FRAGMENT 宏，它同时计算了 _ShadowCoord 和用于衰减纹理采样坐标 _LightCoord 坐标

如果当前平台可以使用屏幕空间阴影映射技术（通过判断是否定义了 UNITY_NO_SCREENSPACE_SHADOWS 来得到），那么 TRANSFER_SHADOW 就会调用内置的 ComputeScreenPos 来计算 _ShadowCoord

3)：内置宏 SHADOW_ATTENUATION() 或 LIGHT_ATTENUATION(i)：

  1. fixed4 frag(vert2frag i): SV_Target 
  2. {
  3.     //……
  4.     fixed shadow = SHADOW_ATTENUATION(i);
  5.     return fixed4((diffuse + specular) * atten * shadow, 1.0); 
  6. } 
  7. ENDCG

该宏的展开为计算阴影值，就和衰减值一样，其范围为 [0, 1]，使用 LIGHT_ATTENUATION 宏可以同时计算阴影值和衰减值，它当然要和 LIGHTING_COORDS(,)​​​​​​ 宏与 TRANSFER_VERTEX_TO_FRAGMENT 宏对应

最后得到的效果如下：

其它的点：

  • 上面的3个宏都可以在 AutoLight.cginc 中找到具体的实现
  • 如果关闭了阴影，SHADOW_ COORDS 和 TRANSFER_SHADOW 就不会有任何作用，SHADOW_ATTENUATION 的值等同于数值1
  • 对于 BasePass 和 AddPass 处理方式一样，不过 BasePass 中渲染的平行光默认是支持阴影的，而 AddPass 中渲染的光源在默认情况下是没有阴影效果的，即使在它的 Light 组件中设置了有阴影的 Shadow Type，但我们可以在 AddPass 中用 #pragma multi_compile_fwdadd_fullshadows 代替 #pragma multi_compile_fwdadd 编译指令，为点光源和聚光灯开启阴影效果，这需要 Unity 在内部使用更多的 Shader 变种

上面的内容都是为了实现让物体接收阴影，而让物体投射阴影不需要我们进行任何处理，只需要设置 Fallback 语义为 Specular 就可以了：

FallBack "Specular"

这是因为对于内置的 Specular，它的 Fallback 又调用了 VertexLit，对于这个内置的 Shader：VertexLit，它的里面实现了 LightMode 为 ShadowCaster 的 Pass，这个 Pass 的主要目的是把深度信息写入渲染目标中，这个渲染目标可以是阴影映射纹理，或是摄像机的深度纹理

如果开启了透明度测试，需要设置 Fallback 为 Transparent/Cutout/VertexLit（这个 ShadowCaster Pass 也同时计算了透明度测试），并且必须提供 _Cutoff 属性、设置物体的 CastShadow 属性为 Two Sided

四、完整的着色器代码

4)：内置宏 UNITY_LIGHT_ATTENUATION(atten, i, worldPos)：

其中第一个参数为衰减值（充当输出），第二个参数为片段着色器输入 v2f，第三个参数为顶点时间空间坐标，这个宏直接帮我们同时计算了光照衰减和阴影，有了它之后就不需要根据光源的类型来写判断自己算衰减了

当然了，这个宏现在已经基本不用了，既然要 Unity 帮我们同时计算阴影值和衰减值，上面的 LIGHT_ATTENUATION(i) 宏会是一个更好的选择

Unity 针对不同的光源类型、是否启用 cookie 等多种情况声明了多个版本的 UNITY_LIGHT_ATTENUATION

  1. // Upgrade NOTE: replaced '_LightMatrix0' with 'unity_WorldToLight'
  2.  
  3. Shader "Jaihk662/AllInOne1"
  4. {
  5.     Properties
  6.     {
  7.         _DiffuseColor ("DiffuseColor", Color) = (1.0, 1.0, 1.0, 1.0)
  8.         _SpecularColor ("SpecularColor", Color) = (1.0, 1.0, 1.0, 1.0)
  9.         _MainTex ("MainTex", 2D) = "white" {}
  10.         _NormalMap ("NormalMap", 2D) = "bump" {}
  11.         _NormalScale ("NormalScale", float) = 1.0       //控制法线贴图展现的凹凸效果，0~1
  12.         _SpecularMask ("SpecularMask", 2D) = "white" {}
  13.         _SpecularMaskScale ("SpecularMaskScale", float) = 1.0
  14.         _Gloss ("Gloss", Range(8.0, 256)) = 20
  15.     }
  16.     SubShader
  17.     {
  18.         LOD 200
  19.         Tags { "RenderType" = "Opaque" "Queue" = "Geometry" }
  20.         //如果场景中包含了多个平行光，Unity会选择最亮的那个传递给BasePass进行逐像素处理，其它平行光按照逐顶点或在AddPass中按逐像素处理（没有平行光默认全黑）
  21.         PASS 
  22.         {
  23.             Tags { "LightMode" = "ForwardBase" }
  24.  
  25.             CGPROGRAM
  26.             #pragma vertex vert
  27.             #pragma multi_compile_fwdbase
  28.             #pragma fragment frag
  29.             #include "UnityCG.cginc"
  30.             #include "Lighting.cginc"
  31.             #include "AutoLight.cginc"
  32.  
  33.             fixed4 _DiffuseColor;
  34.             fixed4 _SpecularColor;
  35.             sampler2D _MainTex;
  36.             sampler2D _NormalMap;
  37.             float _Gloss;
  38.             float _NormalScale;
  39.             sampler2D _SpecularMask;
  40.             float _SpecularMaskScale;
  41.  
  42.             float4 _MainTex_ST;
  43.             struct _2vert
  44.             {
  45.                 float4 vertex: POSITION;            //这个名字vertex不可修改，不然Unity内置宏就无法识别到
  46.                 float3 normal: NORMAL;
  47.                 float4 tangent: TANGENT;
  48.                 float4 texcoord: TEXCOORD0;
  49.             };
  50.             struct vert2frag 
  51.             {
  52.                 float4 pos: SV_POSITION;            //这个名字pos不可修改
  53.                 float2 uv: TEXCOORD0;
  54.                 float4 TtoW1 : TEXCOORD1;           //世界空间中的顶点坐标wPos放在了这3个float4的第四维里
  55.                 float4 TtoW2 : TEXCOORD2;  
  56.                 float4 TtoW3 : TEXCOORD3; 
  57.                 SHADOW_COORDS(4)
  58.             };
  59.  
  60.             vert2frag vert(_2vert v)                 //这个输入参数v不可修改
  61.             {
  62.                 vert2frag o;
  63.                 o.pos = UnityObjectToClipPos(v.vertex);
  64.                 o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
  65.  
  66.                 TANGENT_SPACE_ROTATION;
  67. 				float3 wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
  68.                 fixed3 wNormal = UnityObjectToWorldNormal(v.normal);
  69.                 fixed3 wTangent = UnityObjectToWorldDir(v.tangent.xyz);
  70.                 fixed3 wBinormal = cross(wNormal, wTangent) * v.tangent.w;
  71.                 o.TtoW1 = float4(wTangent.x, wBinormal.x, wNormal.x, wPos.x);
  72.                 o.TtoW2 = float4(wTangent.y, wBinormal.y, wNormal.y, wPos.y);
  73.                 o.TtoW3 = float4(wTangent.z, wBinormal.z, wNormal.z, wPos.z);
  74.  
  75.                 TRANSFER_SHADOW(o);
  76.                 return o;
  77.             }
  78.             fixed4 frag(vert2frag i): SV_Target 
  79.             {
  80.                 float3 wPos = float3(i.TtoW1.w, i.TtoW2.w, i.TtoW3.w);
  81.                 fixed3 normal = UnpackNormal(tex2D(_NormalMap, i.uv));       //内置函数UnpackNormal自动帮我们将法线向量由[0,1]映射到[-1,1]
  82.                 normal.xy *= _NormalScale;
  83.                 normal.z = sqrt(1.0 - saturate(dot(normal.xy, normal.xy)));     //反正是标准化过的单位向量，可以自己由xy算出z的值
  84.                 normal = normalize(half3(dot(i.TtoW1.xyz, normal), dot(i.TtoW2.xyz, normal), dot(i.TtoW3.xyz, normal)));
  85.  
  86.                 fixed3 wLightDir = normalize(UnityWorldSpaceLightDir(wPos));
  87.                 fixed3 wViewDir = normalize(UnityWorldSpaceViewDir(wPos));
  88.  
  89.                 fixed3 albedo = tex2D(_MainTex, i.uv) * _DiffuseColor.rgb;
  90.                 fixed3 ambient = UNITY_LIGHTMODEL_AMBIENT.xyz;
  91.                 fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(normal, wLightDir));
  92.                 
  93.                 fixed3 reflectDir = normalize(reflect(-wLightDir, normal));
  94.                 fixed specularMask = tex2D(_SpecularMask, i.uv).g * _SpecularMaskScale;
  95.                 fixed3 specular = specularMask * _LightColor0.rgb * _SpecularColor.rgb * pow(saturate(dot(reflectDir, wViewDir)), _Gloss);
  96.  
  97.                 UNITY_LIGHT_ATTENUATION(atten, i, wPos);
  98.                 return fixed4(ambient + (diffuse + specular) * atten, 1.0); 
  99.             } 
  100.             ENDCG
  101.         }
  102.         PASS
  103.         {
  104.             Tags { "LightMode" = "ForwardAdd" }
  105.             Blend One One
  106.             
  107.             CGPROGRAM
  108.             #pragma vertex vert
  109.             #pragma multi_compile_fwdadd_fullshadows        //使用此编译指令就能确保在 AddPass 中生成阴影
  110.             #pragma fragment frag
  111.             #include "UnityCG.cginc"
  112.             #include "Lighting.cginc"
  113.             #include "AutoLight.cginc"
  114.  
  115.             fixed4 _DiffuseColor;
  116.             fixed4 _SpecularColor;
  117.             sampler2D _MainTex;
  118.             sampler2D _NormalMap;
  119.             float _Gloss;
  120.             float _NormalScale;
  121.             sampler2D _SpecularMask;
  122.             float _SpecularMaskScale;
  123.  
  124.             float4 _MainTex_ST;
  125.             struct _2vert
  126.             {
  127.                 float4 vertex: POSITION;            //这个名字vertex不可修改，不然Unity内置宏就无法识别到
  128.                 float3 normal: NORMAL;
  129.                 float4 tangent: TANGENT;
  130.                 float4 texcoord: TEXCOORD0;
  131.             };
  132.             struct vert2frag 
  133.             {
  134.                 float4 pos: SV_POSITION;            //这个名字pos不可修改
  135.                 float2 uv: TEXCOORD0;
  136.                 float4 TtoW1 : TEXCOORD1;           //世界空间中的顶点坐标wPos放在了这3个float4的第四维里
  137.                 float4 TtoW2 : TEXCOORD2;  
  138.                 float4 TtoW3 : TEXCOORD3; 
  139.                 SHADOW_COORDS(4)
  140.             };
  141.  
  142.             vert2frag vert(_2vert v)                 //这个输入参数v不可修改
  143.             {
  144.                 vert2frag o;
  145.                 o.pos = UnityObjectToClipPos(v.vertex);
  146.                 o.uv = v.texcoord.xy * _MainTex_ST.xy + _MainTex_ST.zw;
  147.  
  148.                 TANGENT_SPACE_ROTATION;
  149. 				float3 wPos = mul(unity_ObjectToWorld, v.vertex).xyz;
  150.                 fixed3 wNormal = UnityObjectToWorldNormal(v.normal);
  151.                 fixed3 wTangent = UnityObjectToWorldDir(v.tangent.xyz);
  152.                 fixed3 wBinormal = cross(wNormal, wTangent) * v.tangent.w;
  153.                 o.TtoW1 = float4(wTangent.x, wBinormal.x, wNormal.x, wPos.x);
  154.                 o.TtoW2 = float4(wTangent.y, wBinormal.y, wNormal.y, wPos.y);
  155.                 o.TtoW3 = float4(wTangent.z, wBinormal.z, wNormal.z, wPos.z);
  156.  
  157.                 TRANSFER_SHADOW(o);
  158.                 return o;
  159.             }
  160.             fixed4 frag(vert2frag i): SV_Target 
  161.             {
  162.                 float3 wPos = float3(i.TtoW1.w, i.TtoW2.w, i.TtoW3.w);
  163.                 fixed3 normal = UnpackNormal(tex2D(_NormalMap, i.uv));       //内置函数UnpackNormal自动帮我们将法线向量由[0,1]映射到[-1,1]
  164.                 normal.xy *= _NormalScale;
  165.                 normal.z = sqrt(1.0 - saturate(dot(normal.xy, normal.xy)));     //反正是标准化过的单位向量，可以自己由xy算出z的值
  166.                 normal = normalize(half3(dot(i.TtoW1.xyz, normal), dot(i.TtoW2.xyz, normal), dot(i.TtoW3.xyz, normal)));
  167.  
  168.                 fixed3 wLightDir = normalize(UnityWorldSpaceLightDir(wPos));
  169.                 fixed3 wViewDir = normalize(UnityWorldSpaceViewDir(wPos));
  170.  
  171.                 fixed3 albedo = tex2D(_MainTex, i.uv) * _DiffuseColor.rgb;
  172.                 fixed3 diffuse = _LightColor0.rgb * albedo * saturate(dot(normal, wLightDir));
  173.                 
  174.                 fixed3 reflectDir = normalize(reflect(-wLightDir, normal));
  175.                 fixed specularMask = tex2D(_SpecularMask, i.uv).g * _SpecularMaskScale;
  176.                 fixed3 specular = specularMask * _LightColor0.rgb * _SpecularColor.rgb * pow(saturate(dot(reflectDir, wViewDir)), _Gloss);
  177.  
  178.                 UNITY_LIGHT_ATTENUATION(atten, i, wPos);
  179.                 return fixed4((diffuse + specular) * atten, 1.0); 
  180.             } 
  181.             ENDCG
  182.         }
  183.     }
  184.     FallBack "Specular"
  185. }

上面的代码同时也考虑了法线贴图

打开 FrameDebug 也可以看到阴影的渲染过程，总计的渲染步骤多出了不少，但是可以大致分为4个步骤：

  • UpdateDepthTexture：更新摄像机的深度纹理
  • RenderShadowMap：渲染得到平行光的阴影映射纹理
  • CollectShadows：即根据深度纹理和阴影映射纹理得到屏幕空间的阴影图
  • DrawCall：绘制渲染结果

五、关于半透明物体的阴影

对于透明度混合：如果想要半透明物体也得到正确的阴影，其实是一件非常困难的事，不但对于每个光源都要给出合理的渲染顺序，而且就算按照一般的方法渲染得到了正确的阴影，也不会是完全正确的，因为半透明物体的阴影并不只是简单的“衰减”，还需要额外考虑其材质的散射光学特性

想要实现一个非常不错的半透明阴影效果，可能需要去参考专攻的论文，并且就算能实现，其性能消耗也难以接受，所以一般对于半透明物体，直接不去计算阴影

声明：本文内容由网友自发贡献，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：【wpsshop博客】
推荐阅读
相关标签

Copyright © 2003-2013 www.wpsshop.cn 版权所有，并保留所有权利。

  

闽ICP备14008679号