对于Cortex-A芯片来讲,大部分芯片在上电以后C语言环境还没准备好，,以第一行程序肯定是汇编的,至于要写多少汇编程序,那就看你能在哪一步把C语言环境准备好。所谓的C语言环境就是保证C语言能够正常运行。C语言中的函数调用涉及到出栈入栈,出栈入栈就要对堆栈进行操作,所谓的堆栈其实就是一段内存,这段内存比较特殊,由SP指针访问,SP指针指向栈顶。芯片一上电SP指针还没有初始化,所以C语言没法运行,对于有些芯片还需要初始化DDR,因为芯片本身没有RAM,或者内部RAM不开放给用户使用,用户代码需要在DDR 中运行,因此一开始要用汇编来初始化DDR控制器。

GNU汇编语法适用于所有的架构,并不是ARM独享的,GNU汇编由一系列的语句组成,每行一条语句,每条语句有三个可选部分,如下:

label: instruction @ comment

label即标号,表示地址位置,有些指令前面可能会有标号,这样就可以通过这个标号得到指令的地址,标号也可以用来表示数据地址。注意label后面的“:”,任何以“:”结尾的标识符都会被识别为一个标号。

instruction即指令,也就是汇编指令或伪指令。

@符号,表示后面的是注释,就跟C语言里面的“/*”和“*/”一样,其实在GNU汇编文件中我们也可以使用“/*”和“*/”来注释。

comment就是注释内容。


add:
 
MOVS R0,#0X12 @设置 R0=0X12

上面代码中“add:”就是标号, "MOVS R0,#0X12”就是指令,最后的“@设置R0=0X12”就是注释。

汇编由一条一条指令构成,指令就涉及到汇编指令。

处理器内部数据传输指令

MOV指令

MOV指令用于将数据从一个寄存器拷贝到另外一个寄存器,或者将一个立即数传递到寄存器里面,使用示例加下:


MOVRO, R1 @将寄存器R1中的数据传递给RO,即R0=R1
 
MOVRO, #0x12 @将立即数0X12传递给R0寄存器,即R0=0x12

MRS指令

MRS指令用于将特殊寄存器(如CPSR和SPSR)中的数据传递给通用寄存器,要读取特殊寄存器的数据只能使用MRS指令!使用示例如下:

MRS R0, CPSR @将特殊寄存器CPSR里面的数据传递给R0,即R0=CPSR

MSR指令

MSR指令和MRS刚好相反,MSR指令用来将普通寄存器的数据传递给特殊寄存器,也就是写特殊寄存器,写特殊寄存器只能使用MSR使用示例如下:

MSR CPSR, R0 @将R0中的数据复制到CPSR中,即CPSR=R0

存储器访问指令

LDR指令

LDR主要用于从存储加载数据到寄存器Rx中,LDR也可以将一个立即数加载到寄存器Rx中, LDR加载立即数的时候要使用“=”,而不是“#”。在嵌入式开发中, LDR最常用的就是读取CPU的寄存器值,比如I.MX6UL有个寄存器GPIO1_GDIR,其地址为0X0209C004,我们现在要读取这个寄存器中的数据,示例代码如下:


LDR R0, =0x0209C004 @将寄存器地址0x0209C004加载到R0中,即R0=0x0209C004
 
LDR R1, [R0] @读取地址0x0209C004中的数据到R1寄存器中

上述代码就是读取寄存器GPIO1_GDIR中的值,读取到的寄存器值保存在R1寄存器中,上面代码中offset是0,也就是没有用到offset。

STR指令

LDR是从存储器读取数据, STR就是将数据写入到存储器中,同样以I.MX6UL寄存器GPIO1_GDIR为例,现在我们要配置寄存器GPIO1_GDIR的值为0X20000002,示例代码如下:


LDR R0, =0X0209C004 @将寄存器地址0x0209C004加载到R0中,即R0=0X0209C004
 
LDR R1, =0X20000002 @R1保存要写入到寄存器的值,即R1=0X20000002
 
STR R1, [R0] @将R1中的值写入到R0中所保存的地址中

LDR和STR都是按照字进行读取和写入的,也就是操作的32位数据,如果要按照字节、半字进行操作的话可以在指令“LDR”后面加上B或H,比如按字节操作的指令就是LDRB和STRB,按半字操作的指令就是LDRH和STRH

压栈和出栈指令

假如我们现在要将R0-R3和R12这5个寄存器压栈,当前的SP指针指向0X80000000,处理器的堆栈是向下增长的,使用的汇编代码如下:

PUSH {RO-R3, R12}  @将R0-R3和R12压栈

完成压栈后示意图

如果我们要出栈的话就是使用如下代码:

POP {RO-R3,R12} @恢复R0-R3,R12

跳转指令

B指令

B指令会将PC寄存器的值设置为跳转目标地址,一旦执行B指令, ARM处理器就会立即跳转到指定的目标地址。如果要调用的函数不会再返回到原来的执行处,那就可以用B指令,如下示例:


start:
 
ldr sp, = 0X80200000 @设置栈指针
 
b main @跳转到main函数

上述代码就是典型的在汇编中初始化C运行环境,然后跳转到C文件的 main 函数中运行,

上述代码只是初始化了SP指针,有些处理器还需要做其他的初始化,比如初始化DDR等等。因为跳转到C文件以后再也不会回到汇编了,所以在第3行使用了B指令来完成跳转。

BL指令

BL指令相比B指令,在跳转之前会在寄存器LR(R14)中保存当前 PC 寄存器值,所以可以通过将LR寄存器中的值重新加载到PC中来继续从跳转之前的代码处运行,这是子程序调用一个基本但常用的手段。比如 Cortex-A 处理器的irq中断服务函数都是汇编写的,主要用汇编来实现现场的保护和恢复、获取中断号等。但是具体的中断处理过程都是C 函数,所以就会存在汇编中调用C函数的问题。而且当C语言版本的中断处理函数执行完成以后是需要返回到irq汇编中断服务函数,因为还要处理其他的工作,一般是恢复现场。这个时候就不能直接使用B指令了,因为B指令一旦跳转就再也不会回来了,这个时候要使用BL指令,示例代码如下:


push {r0, r1} @保存 r0,r1
 
cps #0x13 @进入svc模式,允许其他中断再次进去
 
bl system_irqhandler @加载c语言中断处理函数到r2寄存器中
 
cps #0x12 @进入IRQ模式
 
pop {r0, r1}
 
str r0, [r1, #0×10 ]@中断执行完成,写EOIR

上述代码中第3行就是执行C语言版的中断处理函数,当处理完成以后是需要返回来继续执行下面的程序,所以使用了BL指令。

算术运算指令

逻辑运算指令

汇编LED驱动实验源码


.global _start      @全局标号
 
_start:
 
    @使能所有外设时钟
    ldr r0, =0x020c4068 @加载CCGR0到r0寄存器
    ldr r1, =0xFFFFFFFF @要向CCGR0写入的数据
    str r1, [r0]        @将0xFFFFFFFF写入到CCGR0中
 
    ldr r0, =0x020c406c @加载CCGR1到r0寄存器   
    str r1, [r0]        @将0xFFFFFFFF写入到CCGR1中
 
    ldr r0, =0x020c4070 @加载CCGR2到r0寄存器   
    str r1, [r0]        @将0xFFFFFFFF写入到CCGR2中
 
    ldr r0, =0x020c4074 @加载CCGR3到r0寄存器   
    str r1, [r0]        @将0xFFFFFFFF写入到CCGR3中
 
    ldr r0, =0x020c4078 @加载CCGR4到r0寄存器   
    str r1, [r0]        @将0xFFFFFFFF写入到CCGR4中
 
    ldr r0, =0x020c407c @加载CCGR5到r0寄存器   
    str r1, [r0]        @将0xFFFFFFFF写入到CCGR5中
 
    ldr r0, =0x020c4080 @加载CCGR6到r0寄存器   
    str r1, [r0]        @将0xFFFFFFFF写入到CCGR6中
 
 
    @配置GPIO1_IO03 PIN的复用为GPIO,也就是设置
    @IOMUXC_SW_MUX_CTL_PAD_GPIO01_IO03=0x05 是设置为输出模式
    @寄存器地址为0x020E0068
    ldr r0, =0x020e0068 @加载IOMUXC_SW_MUX_CTL_PAD_GPIO01_IO03到r0寄存器
    ldr r1, =0x05       @要向IOMUXC_SW_MUX_CTL_PAD_GPIO01_IO03写入的数据
    str r1, [r0]        @将0x05写入到IOMUXC_SW_MUX_CTL_PAD_GPIO01_IO03中
 
    @配置GPIO1_IO03的电气属性
    @寄存器IOMUXC_SW_PAD_CTL_PAD_GPIO01_IO03 地址为0x020e02f4
    @bit0:      0压摆率为低速率(压摆率就是电平跳变时间)
    @bit5~3     111 R0/7驱动能力最强(看数据手册)
    @bit7~6     10  100MHz速度
    @bit11      0关闭开漏输出
    @bit12      1使能保持上拉/电路
    @bit13      0保持
    @bit15~14   00 默认100K下拉
    @bit16      0关闭Hyst
 
    ldr r0, =0x020e02f4   @加载IOMUXC_SW_PAD_CTL_PAD_GPIO01_IO03到r0寄存器
    ldr r1, =0x10b0       @要向IOMUXC_SW_PAD_CTL_PAD_GPIO01_IO03写入的数据
    str r1, [r0]          @将数据写入到IOMUXC_SW_PAD_CTL_PAD_GPIO01_IO03中
 
    @设置GPIO
    @设置GPIO01_GDIR寄存器,设置GPIO01_IO03为输出
    @寄存器地址是0x0209c004,设置GPIO01_GDIR寄存器bit3为1
    @就是设置GPIO01_IO03为输出
 
    ldr r0, =0x0209c004    @加载GPIO01_GDIR到r0寄存器
    ldr r1, =0x08          @要向GPIO01_GDIR写入的数据 
    str r1, [r0]           @将数据写入到GPIO01_GDIR中
 
    @打开LED,也就是设置GPIO1_IO03为0
    @GPIO1_DR寄存器地址为0x0209c000
    
    ldr r0, =0x0209c000     @加载GPIO01_DR到r0寄存器
    ldr r1, =0x00           @要向GPIO01_DR到r0寄存器
    str r1, [r0]            @将数据写入到GPIO01_DR中
 
 
 
 
 
    @死循环
loop:
    b loop

编译程序

1.使用arm-linux-gnueabihf-gcc,将.c.s文件变为.o

2.使用arm-linux-gnueabihf-ld将所有.o文件链接为elf格式的可执行文件。

3.使用arm-linux-gnueabihf-objcopy将elf文件转为bin文件

链接就是将所有.o文件链接在一起,并且链接到指定的地方。实验链接的时候要指定链接起始地址。链接起始地址就是代码运行的起始地址。对于6ULL来说,链接起始地址应该指向RAM地址。RAM分为内部RAM和外部RAM也就是DDR。6ULL内部RAM地址范围0x900000~0x91FFFF。也可以放到外部DDR中,本实验链接到0x87800000。要使用DDR,那么必须要初始化DDR,对于I.MX来说bin文件不能直接运行,需要添加一个头部,这个头部信息包含了DDR的初始化参数, I.MX系列SOC内部boot rom会从SD卡, EMMC等外置存储中读取头部信息,然后初始化DDR,并且将bin文件拷贝到指定的地方。Bin的运行地址一定要和链接起始地址一致,位置无关代码除外。

严格的来说,应该是bin文件不能直接烧写到SD卡、EMMC、NAND等外置存储中,然后从这些外置存储中启动运行。而不是bin文件不能直接运行,使用JLINK将bin文件直接下载到内部RAM中还是可以运行的。

链接的时候记得保存,出现找不到项目,把以前生成的文件删掉,重新生成.o在链接。(.global _start @全局标号).global中间有空格_start

注意命令大小写事不能乱变的

烧写Bin文件

6ULL支持SD卡、EMMC、NAND、nor、SPI flash等等启动。选择烧写到SD卡里面。

在Ubuntu下向SD卡烧写裸机Bin文件。烧写不是将Bin文件拷贝到SD卡中,而是将Bin文件烧写到SD卡绝对地址上。而且对于I.MX而言不能直接烧写Bin文件,比如先在Bin文件前面添加头部。

imxdownload使用方法,确定要烧写的SD卡文件

给予imxdownload可执行文件 chmod 777 imxdownload

烧写头部完成

imxdownlaod会向led.bin添加一个头部,生成新的load.imx文件,这个load.imx 文件就是最终烧写到SD卡里面去的。

Makefile文件编译代码


led.bin : led.s
	arm-linux-gnueabihf-gcc -g -c led.s -o led.o
	arm-linux-gnueabihf-ld -Ttext 0x87800000 led.o -o led.elf
	arm-linux-gnueabihf-objcopy -O binary -S -g led.elf led.bin
	arm-linux-gnueabihf-objdump -D led.elf > led.dis
 
clear:
	rm -rf *.o led.bin led.elf led.dis

给予imxdownload可执行文件 chmod 777 imxdownload

执行make后直接烧如

./imxdownlaod led.bin /dev/sdb

声明：本文内容由网友自发贡献，不代表【wpsshop博客】立场，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：https://www.wpsshop.cn/w/花生_TL007/article/detail/385614