Arduino实验——GP2Y1014检测空气颗粒物浓度_gp2y1014au

GP2Y1014AU0F 灰尘传感器模块

传感器介绍

GP2Y1014AU0F 是夏普公司生产的一款光学空气质量传感器。

在其中间有一个洞，空气可以自由流通，传感器内部邻角位置安装有红外发光二极管和光电晶体管，红外发光二极管定向发送红外光，当空气中有颗粒物阻碍红外线时，红外线发生漫反射，光电晶体管接收到红外光线，信号输出引脚电压会随之发生变化。该电压值在一定范围内与灰尘浓度成线性关系，因此在使用过程中，需要使用 ADC 采集该电压信号，并通过该电压值计算出空气中的灰尘浓度。

GP2Y1014AU0F 传感器通常应用于空气净化系统，可测量 0.8微米以上的微小粒子，可探测烟雾和花粉、室内外灰尘浓度等。由于体积较小、重量轻、接口简单、便于安装，广泛应用于空气净化器、换气空调、换气扇等产品。

传感器参数

• 测量对象：直径大于 0.8μm 灰尘颗粒
• 有效量程：500μg/m³
• 灵敏度：0.5V/(0.1mg/m³)，即灰尘浓度每变化 0.1mg/m3，输出电压变化 0.5V
• 工作电压：2.5V-5.5V
• 输出类型：电压模拟量
• 工作温度：-10-65℃
• 存储温度：-20~80℃
• 使用寿命：5年

工作原理

1. 通过设置模块 I_LED 引脚为高电平，从而打开传感器内部红外二极管。
2. 等待 0.28ms，外部控制器采样模块 A_OUT 引脚的电压值。（因为传感器内部红外二极管在开启之后经过 0.28ms，输出波形才达到稳定）
3. 采样持续 0.04ms 之后，再设置 I_LED 引脚为低电平，从而关闭内部红外二极管。
4. 根据电压与浓度的关系即可计算出当前空气中的灰尘浓度。

I_LED 端输入脉冲波形要求

I_LED 输入脉冲与 A_OUT 的采样时序

传感器输出特性

GP2Y1014AU0F 传感器输出电压与灰尘浓度关系在 0 到 0.5mg/m³ 范围内成线性关系，如下图所示：

在 0 ~ 0.5mg/m³ 范围内取部分电压与浓度的对应值，得到如下转换公式，其中 v 为电压（单位 V），d 为浓度（单位 mg/m³）。
$$\mathrm{v}=5.88\ast \mathrm{d}+0.6$$
转换为通过 v 计算 d，得到如下公式：
$$\mathrm{d}=(\mathrm{v}-0.6)\ast 0.17$$
在代码中我们将会定义对应的宏定义值：

#define    COV_RATIO                      0.17
#define    NO_DUST_VOLTAGE    600
1
2

需要特别指出，由于这里使用的模块中对输出的电压做了分压处理，因此测量到的电压需要放大 11 倍才是实际传感器输出的电压。

硬件连接

GP2Y1014AU0F 传感器有六个引脚，如下图所示。参照上面的电路原理图，可知在我们使用的模块中，VCC 和 GND 是共用的，因此我们只需要连接四个引脚。

传感器模块与 Arduino 接口的连接如下：

Arduino 代码

#define        COV_RATIO                           0.17           // (ug/m3) / mv
#define        NO_DUST_VOLTAGE         600            // mv
#define        SYS_VOLTAGE                     5000          // ADC参考电压    

/*
I/O define
*/
const int iled = 3;                                           //drive the led of sensor
const int vout = 0;                                           //analog input

/*
variable
*/
float density, voltage;
int   adcvalue;

/*
private function
*/
int Filter(int m)
{
  static int flag_first = 0, _buff[10], sum;
  const int _buff_max = 10;
  int i;
  
  if(flag_first == 0)
  {
    flag_first = 1;

    for(i = 0, sum = 0; i < _buff_max; i++)
    {
      _buff[i] = m;
      sum += _buff[i];
    }
    return m;
  }
  else
  {
    sum -= _buff[0];
    for(i = 0; i < (_buff_max - 1); i++)
    {
      _buff[i] = _buff[i + 1];
    }
    _buff[9] = m;
    sum += _buff[9];
    
    i = sum / 10.0;
    return i;
  }
}

void setup(void)
{
  pinMode(iled, OUTPUT);
  digitalWrite(iled, LOW);                                     //iled default closed
  Serial.begin(9600);                                          //send and receive at 9600 baud
}

void loop(void)
{
  /*
  get adcvalue
  */
  digitalWrite(iled, HIGH);
  delayMicroseconds(280);
  adcvalue = analogRead(vout);
  delayMicroseconds(40);
  digitalWrite(iled, LOW);
  
  adcvalue = Filter(adcvalue);
  
  /*
  covert voltage (mv)
  */
  voltage = (SYS_VOLTAGE / 1024.0) * adcvalue * 11;
  
  /*
  voltage to density
  */
  if(voltage >= NO_DUST_VOLTAGE)
  {
    voltage -= NO_DUST_VOLTAGE;
    density = voltage * COV_RATIO;
  }
  else
    density = 0;
    
  /*
  display the result
  */
  Serial.print("The current dust concentration is: ");
  Serial.print(density);
  Serial.print(" ug/m3\n");  
  
  delay(1000);
}
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96

经过前面一系列的铺垫，程序应该比较容易理解。但可能对 Filter() 滤波函数比较陌生，Filter() 函数的作用是记录最近采样的十个数据，计算出平均值。这样的好处是最终得到的数据不会与前面的数据相差太大，因为实际环境中的空气灰尘浓度是连续平滑变化的。

波形观察

因为使用万用表测量 A_OUT 输出电压时发现电压一直很低，在几mv到十几mv之间，于是决定用示波器观察一下 I_LED 和 A_OUT 信号的波形情况（黄色通道1为 I_LED 信号，绿色通道2为 A_OUT 信号）。

输入脉冲 280us，模拟高浓度

输入脉冲 320us，模拟低浓度

输入脉冲 320us，模拟高浓度

输入脉冲 1Hz，模拟高浓度

于是有了以下几点思考：

• 无论传感器模块 VCC 给 5V 还是 3.3V，A_OUT 的电压值并没有影响，可能是因为其内部有升压电路，所以 2.5V-5.5V 电源输入都可以工作。
• I_LED 的上升沿和下降沿都会影响 A_OUT，但 A_OUT 此后仍有明显波动，应该与传感器的工作机制有关。
• 输入脉冲周期可在合适范围内自行选择，I_LED 高电平大于 280us 即可正确读数，是否保持 320us 影响不大。
• A_OUT 的输出保持与 I_LED 脉冲宽度并无明显关系，不会一直保持输出采样值，因此万用表读数很低是正常的。

输出调试

空气污染指数分级标准