UnityShader入门精要-渲染纹理 镜子 玻璃 效果_unity urp shadergraph 制作简单的玻璃材质

        通常模式是一个摄像机的渲染结果输出到颜色缓冲内并显示到屏幕上，现代GPU允许我们把场景渲染到一个中间缓冲（渲染目标纹理RTT），与之相关的是多重渲染目标MRT允许我们把场景同时渲染到多个渲染目标中而不需要为每个渲染目标纹理单独渲染完成的场景。应用：延迟渲染。

        使用渲染纹理：

①project视图下create-render texture，将某个摄像机的渲染目标设置为该纹理，这样该相机的渲染结果就会实时更新到渲染纹理中。

②在屏幕后处理中使用GrabPass或OnRenderImage获取当前屏幕图像。

镜子效果：

创建一个平面，为其附着带有镜子shader的材质，并将创建好的渲染纹理为其添加，此外创建一个摄像机模拟镜子看到的东西，将其target texture 设置为创建好的渲染纹理。

Unity 快速实现镜子效果_辛羊华的博客-CSDN博客_unity镜子

shader：

// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
// Upgrade NOTE: replaced 'mul(UNITY_MATRIX_MVP,*)' with 'UnityObjectToClipPos(*)'
 
// Upgrade NOTE: replaced '_Object2World' with 'unity_ObjectToWorld'
 
Shader "Shaders/AdvTex/Mirror"
 {
	Properties {
		_MainTex("Main Tex",2D)="white"{}
	}
	SubShader {
		Tags { "RenderType"="Opaque" "Queue"="Geometry"}
		
		Pass { 
			Tags { "LightMode"="ForwardBase" }
		
			CGPROGRAM
			
			#pragma multi_compile_fwdbase	
			
			#pragma vertex vert
			#pragma fragment frag
			
			#include "Lighting.cginc"
			#include "AutoLight.cginc"
			
			sampler2D _MainTex;
			
			struct a2v {
				float4 vertex : POSITION;
				float3 texcoord : TEXCOORD0;
			};
			
			struct v2f {
				float4 pos : SV_POSITION;
				float2 uv:TEXCOORD0;
			};
			
			v2f vert(a2v v) {
				v2f o;
				o.pos = UnityObjectToClipPos(v.vertex);
				
				o.uv=v.texcoord;
				o.uv.x=1-o.uv.x;
				
				return o;
			}
			
			fixed4 frag(v2f i) : SV_Target {
				return tex2D(_MainTex, i.uv);
			}
			
			ENDCG
		}
	} 
	FallBack Off
}

 注意要对x分量纹理坐标进行反转，以模拟镜子的相反效果。

玻璃效果：

        前面说到一种特殊的pass---GrabPass,在shader中定义了一个grabpass后，unity会将当前屏幕的图像绘制在一个纹理中在后续的pass中访问，实现玻璃等透明材质的模拟，grabpass相比透明度混合优势为除了实现透明效果，还可以进行如模拟折射等效果。注意该物体要被设置为透明队列（Queue=Transparent），才可以保证渲染该物体是不透明物体已被绘制。 

        distortion用于控制模拟折射时图像的扭曲程度，refractamount表示折射程度，为0时仅有反射，注意渲染队列要设置为transparent，使用GrabPass获取屏幕图像，并定义获取到的纹理与纹素大小的变量，用于对图像采样计算坐标偏移时使用。

v2f vert (a2v v) {
				v2f o;
				o.pos = mul(UNITY_MATRIX_MVP, v.vertex);
				
				o.scrPos = ComputeGrabScreenPos(o.pos);
				
				o.uv.xy = TRANSFORM_TEX(v.texcoord, _MainTex);
				o.uv.zw = TRANSFORM_TEX(v.texcoord, _BumpMap);
				
				float3 worldPos = mul(_Object2World, v.vertex).xyz;  
				fixed3 worldNormal = UnityObjectToWorldNormal(v.normal);  
				fixed3 worldTangent = UnityObjectToWorldDir(v.tangent.xyz);  
				fixed3 worldBinormal = cross(worldNormal, worldTangent) * v.tangent.w; 
				
				o.TtoW0 = float4(worldTangent.x, worldBinormal.x, worldNormal.x, worldPos.x);  
				o.TtoW1 = float4(worldTangent.y, worldBinormal.y, worldNormal.y, worldPos.y);  
				o.TtoW2 = float4(worldTangent.z, worldBinormal.z, worldNormal.z, worldPos.z);  
				
				return o;
			}

        顶点着色器中完成了顶点坐标变换，ComputeGrabScreenPos得到被抓去到屏幕图存储的纹理的采样坐标，为了在frag中能够将法线方向从切线空间变换到世界空间，需要计算该矩阵，每行分别存在TtoW0,1,2中，w分量表示世界空间下的顶点坐标。

         在片元着色器中，先通过矩阵的w分量得到世界坐标与视角方向，对法线纹理采样得到切线空间下的法线方向，将得到的结果与扭曲程度以及得到的纹素大小得到偏移值，切线空间下的法线方向进行偏移可以反映顶点局部空间的法线方向，对scrPos透视除法后得到真正的屏幕坐标，用这个坐标再对grab到的纹理采样，得到模拟的折射颜色，此后再从切线空间换回世界空间，计算反射方向，折射方向，用反射方向对环境纹理采样得到颜色与主纹理本身的颜色相乘得到反射颜色，最终得到的颜色为反射与折射得到的颜色关于折射程度的插值。

fixed4 frag (v2f i) : SV_Target {		
				float3 worldPos = float3(i.TtoW0.w, i.TtoW1.w, i.TtoW2.w);
				fixed3 worldViewDir = normalize(UnityWorldSpaceViewDir(worldPos));
				
				// Get the normal in tangent space
				fixed3 bump = UnpackNormal(tex2D(_BumpMap, i.uv.zw));	
				
				// Compute the offset in tangent space
				float2 offset = bump.xy * _Distortion * _RefractionTex_TexelSize.xy;
				i.scrPos.xy = offset * i.scrPos.z + i.scrPos.xy;
				fixed3 refrCol = tex2D(_RefractionTex, i.scrPos.xy/i.scrPos.w).rgb;
				
				// Convert the normal to world space
				bump = normalize(half3(dot(i.TtoW0.xyz, bump), dot(i.TtoW1.xyz, bump), dot(i.TtoW2.xyz, bump)));
				fixed3 reflDir = reflect(-worldViewDir, bump);
				fixed4 texColor = tex2D(_MainTex, i.uv.xy);
				fixed3 reflCol = texCUBE(_Cubemap, reflDir).rgb * texColor.rgb;
				
				fixed3 finalColor = reflCol * (1 - _RefractAmount) + refrCol * _RefractAmount;
				
				return fixed4(finalColor, 1);
			}

对比：

grabpass：代码简单

渲染纹理：性能优越