devbox
我家自动化
这个屌丝很懒，什么也没留下！
关注作者
热门标签
热门文章
当前位置:   article > 正文

改造winform的listview实现双击修改数据editbox和下拉框选择数据combobox功能_c# listview 双击编辑

作者：我家自动化 | 2024-05-05 06:51:31

赞

踩

c# listview 双击编辑

一直以来winform的listview都只是作为数据输出显示来用, 想要实现数据的双向操作比较难

之前都需要用其他表格类控件实现这个双击编辑文本,双击实现下拉列表框选择文本功能, 而且其中有很大一部分是ocx组件, 

那么就需要在客户电脑上regsvr32 注册它, 这样就需要管理员权限, 这样操作并不是很好, 

于是考虑着手动改造listview使其满足我的需求.

还好, aardio范例里有个数据视图win.ui.grid的库可供参考, 我就是根据这个库内的实现方法来升级改造的.

下面我在原listview grid基础上增加了, 双击指定列 可直接编辑文本  / 弹出下拉框选择文本 功能.

 listviewEX.aardio 库代码如下:

  1. //listview 扩展
  2. import win.ui.ctrl.edit;
  3. import win.ui.ctrl.combobox;
  4. namespace win.ui;
  5. class listviewEx{
  6.     ctor( listview ){
  7.         this = listview; 
  8.         this.fullRow = 1;
  9.         this.gridLines = 1;
  10.         this.columnsEditbox = {};//记录编辑框列号
  11.         this.columnsCombobox = {};//记录下拉框列号和列表值
  12.         //添加下拉框模板
  13.         this.addCtrl(
  14.             combobox = { 
  15.                 cls="combobox";font = LOGFONT( h = -19 );left = 0;top = 0;
  16.                 right = 50;bottom = 50;autoResize = false ;hide = 1;edge = 1;mode="dropdownlist";
  17.                 wndproc = function( hwnd, message, wParam, lParam ){
  18.                     var update;
  19.                     var event = owner.event;
  20.  
  21.                     if( message == 308 ) {
  22.                         update = true;
  23.                     }
  24.                     if( update ){
  25.                         owner.show(false);
  26.                         var t = this.getItemText(event.iItem,event.iSubItem );
  27.                         if( t!= owner.text ){
  28.                             if( this.onEditChanged ) {
  29.                                     if( false === this.onEditChanged(owner.text, event.iItem, event.iSubItem)) 
  30.                                         return;
  31.                             }
  32.                                  
  33.                             this.setItemText( owner.text, event.iItem, event.iSubItem );
  34.                         }
  35.                          
  36.                         if(this.onEditEnd){
  37.                             this.onEditEnd(event.iItem, event.iSubItem);
  38.                         }
  39.                     }
  40.                 }  
  41.             }
  42.          );
  43.         //添加编辑框模板
  44.        this.addCtrl(
  45.             editBox = { 
  46.                 cls="edit";font = LOGFONT( h = -19 );left = 0;top = 0;
  47.                 right = 50;bottom = 50;autoResize = false ;hide = 1;edge = 1;
  48.                 wndproc = function( hwnd, message, wParam, lParam ){
  49.                     var update;
  50.                     var event = owner.event;
  51.  
  52.                     if( ( message = 0x8/*_WM_KILLFOCUS*/)  || (message == 0x101/*_WM_KEYUP*/ && wParam == 0xD/*_VK_RETURN*/ ) ) {
  53.                         update = true;
  54.                     }
  55.                     elseif(message == 0x201/*_WM_LBUTTONDOWN*/ ){
  56.                         var x,y = ..win.getMessagePos(lParam)
  57.                         var rc = this.editBox.getClientRect();
  58.                         
  59.                         if( ! ::PtInRect(rc,x,y) ) update = true;
  60.                         this.editBox.capture = !update;
  61.                     } 
  62.                     elseif(message == 0x101/*_WM_KEYUP*/){
  63.                         if( wParam == 0xD/*_VK_RETURN*/ ) update = true;
  64.                         elseif( wParam == 0x1B/*_VK_ESC*/){
  65.                             owner.text = this.getItemText(event.iItem,event.iSubItem );
  66.                             update = true;
  67.                         }
  68.                     }
  69.                     if( update ){
  70.                         owner.show(false);
  71.                         var t = this.getItemText(event.iItem,event.iSubItem );
  72.                         if( t!= owner.text ){
  73.                             if( this.onEditChanged ) {
  74.                                     if( false === this.onEditChanged(owner.text, event.iItem, event.iSubItem)) 
  75.                                         return;
  76.                             }
  77.                                  
  78.                             this.setItemText( owner.text, event.iItem, event.iSubItem );
  79.                         }
  80.                          
  81.                         if(this.onEditEnd){
  82.                             this.onEditEnd(event.iItem, event.iSubItem);
  83.                         }
  84.                     }
  85.                 }  
  86.             }
  87.         )
  88.     };
  89.     //绘制下拉框
  90.     beginCombobox = function(iItem,iSubItem){
  91.         var combobox = this.combobox;
  92.         if( ..win.isVisible(combobox.hwnd) ) return; 
  93.          
  94.         var event = this.combobox.event;
  95.         if(iItem===null && iSubItem===null) {
  96.             iItem = event.iItem;
  97.             iSubItem = event.iSubItem;
  98.         }
  99.         else {
  100.             event = {
  101.                 iItem = iItem;
  102.                 iSubItem = iSubItem;
  103.             };
  104.             combobox.event = event;
  105.         } 
  106.          
  107.          combobox.items = this.columnsCombobox[iSubItem];
  108.         combobox.selText=this.getItemText(iItem,iSubItem);
  109.         var rc=this.getItemRect(iItem,iSubItem,,2/*_LVIR_LABEL*/ );
  110.          
  111.         rc.inflate(2,2);
  112.         combobox.setRect(rc);
  113.         combobox.showDropDown();
  114.         return true;   
  115.     };
  116.     //绘制编辑框
  117.     beginEdit = function(iItem,iSubItem){
  118.         var edit = this.editBox;
  119.         if( ..win.isVisible(edit.hwnd) ) return; 
  120.          
  121.         var event = this.editBox.event;
  122.         if(iItem===null && iSubItem===null) {
  123.             iItem = event.iItem;
  124.             iSubItem = event.iSubItem;
  125.         }
  126.         else {
  127.             event = {
  128.                 iItem = iItem;
  129.                 iSubItem = iSubItem;
  130.             };
  131.             edit.event = event;
  132.         } 
  133.  
  134.         edit.text=this.getItemText(iItem,iSubItem);
  135.         var rc=this.getItemRect(iItem,iSubItem,,2/*_LVIR_LABEL*/ );
  136.          
  137.         rc.inflate(2,2);
  138.         edit.setRect(rc);
  139.         edit.show(); 
  140.         edit.setFocus();
  141.         edit.capture = true;
  142.         return true;   
  143.     };
  144.     //设置下拉框模式 列号/下拉值
  145.     setcolumnsCombobox = function(iSubItem,tab,...){
  146.         var c = type(tab) === "table" ? tab : {tab,...}
  147.         this.columnsCombobox[iSubItem] = c;
  148.     };
  149.     //设置编辑框模式 列号
  150.     setcolumnsEditbox = function(...){
  151.         var c = type(...) === "table" ? ... : {...}
  152.         for(i,idx in c) this.columnsEditbox[idx] = 1;
  153.     };
  154.     prenotify = { 
  155.         [0xFFFFFFFD/*_NM_DBLCLK*/] = function(id,code,ptr){
  156.             var event = this.getNotifyMessage(code,ptr);
  157.             if( ! event.iItem && event.iSubItem ) return ;
  158.             //启用 编辑框
  159.              if( this.columnsEditbox[event.iSubItem] ){
  160.                  this.editBox.event = event; 
  161.                 this.beginEdit();
  162.              };
  163.              //启用 下拉框
  164.              if( this.columnsCombobox[event.iSubItem] ){
  165.                  this.combobox.event = event; 
  166.                 this.beginCombobox();
  167.              };
  168.         };
  169.     } 
  170. }
  171.  
  172.  
  173. /**intellisense()
  174. win.ui.listviewEx(__) = 参数必须指定一个listview控件对象\n返回一个可编辑单元格的列表视图对象,\n\n鼠标左键单击单元格、或者按空格键开始编辑,\n回车完成编辑,ESC键撤消编辑,回车+上下方向键快速移动到其他项,\n用户完成编辑后会触发onEditChanged事件.\n!listview.
  175. win.ui.listviewEx() = !win_ui_listviewEx.
  176. !win_ui_listviewEx.edit = 实现编辑功能的edit控件\n此功能需要扩展listview并实现了编辑功能的的控件才能支持\n!edit.
  177. !win_ui_listviewEx.combobox = 实现编辑功能的edit控件\n此功能需要扩展listview并实现了编辑功能的的控件才能支持\n!combobox.
  178. !win_ui_listviewEx.onEditChanged(text,iItem,iSubItem) = @.onEditChanged = function(text,iItem,iSubItem){
  179.     __/*控件完成编辑,并且文本已变更,\ntext为改变后的文本,iItem为行号,iSubItem为列号\n此功能需要扩展listview并实现了编辑功能的的控件才能支持\n返回false可中止更新显示文本*/
  180. }
  181. !win_ui_listviewEx.onEditEnd(iItem,iSubItem) = @.onEditEnd = function(iItem,iSubItem){
  182.     __/*控件完成编辑*/
  183. }
  184. !win_ui_listviewEx.setTable(__) = 用listview控件显示数据表\n此函数会自动清空控件之前的所有项,\n如果没有创建任何列,则自动创建列\n\n数据表应当包含行组成的数组,\n每行的数据列必须是由列名和列值组成的键值对\n数据表应使用fields包含需要显示的列名称数组\n可以通过fields控制要显的列、以及要显示的顺序\n\n使用sqlite,access,sqlServer等数据库对象提供的getTable函数可获取符合此规格的数据表 
  185. !win_ui_listviewEx.setColumns(__) = 用一个字符串数组指定要显示的列\n如果参数为空则清空所有列
  186. !win_ui_listviewEx.setcolumnsCombobox(__) = 可以使用一个或多个参数指定要禁止编辑的列序号,\n也可以用一个数组参数指定多个列序号
  187. !win_ui_listviewEx.setcolumnsEditbox(__) = 可以使用一个或多个参数指定要编辑的列序号,\n也可以用一个数组参数指定多个列序号
  188. !win_ui_listviewEx.clear() = 清空所有行
  189. !win_ui_listviewEx.clear(true) = 清空所有行,并且清空所有列
  190. end intellisense**/

使用也很简单, 只需要指定哪一列是文本框模式, 哪一列是下拉框模式.

  1. import win.ui;
  2. /*DSG{{*/
  3. mainForm = win.form(text="testListviewEx";right=740;bottom=315;bgcolor=16777215)
  4. mainForm.add(
  5. listview={cls="listview";left=13;top=8;right=729;bottom=309;border=1;db=1;dl=1;dr=1;dt=1;font=LOGFONT(h=-13);fullRow=1;gridLines=1;msel=false;vscroll=1;z=1}
  6. )
  7. /*}}*/
  8.  
  9. import console
  10. console.open()
  11.  
  12. import win.ui.listviewEx;
  13. var grid = win.ui.listviewEx(mainForm.listview);
  14. grid.setcolumnsEditbox(2);
  15. grid.setcolumnsCombobox(3,"10","1000","2000","5000");
  16. grid.setcolumnsCombobox(4,{"Z+","Z-","ZNP+","ZNP-"});
  17. grid.setcolumnsCombobox(5,{"急停","减速停"});
  18. grid.onEditChanged = function(text,iItem,iSubItem){
  19.     console.log("onEditChanged",text,iItem,iSubItem)
  20. }
  21.  
  22.  
  23. import win.imageList;
  24. var iml = win.imageList(1,30);
  25. mainForm.listview.setImageList( iml,1/*_LVSIL_NORMAL*/ );
  26. mainForm.listview.setColumns(
  27.     {"轴号","加减速时间","单脉冲运动量","找零方式","停止方式"},
  28.     {60,120,120,100,100},
  29.     {2,2,2,2,2},
  30. );
  31. var axisData = {};
  32. for(i=1;20;1){
  33.     axisData[i]={};
  34.     axisData[i][1] = "轴"++i;
  35.     axisData[i][2] = "0.1";
  36.     axisData[i][3] = "1";
  37.     axisData[i][4] = "Z+";
  38.     axisData[i][5] = "急停";
  39. }
  40. mainForm.listview.items = axisData;
  41.  
  42.  
  43. mainForm.show();
  44. return win.loopMessage();

主要看上面部分, 上面声明完所有的列功能, 下面还是用listview自己的功能实现代码.

完整示例工程可以去我的博客下载:

 改造listview使其实现表格内编辑框editbox和下拉列表框combobox功能 - 上位机开发笔记一直以来winform的listview都只是作为数据输出显示来用, 想要实现数据的双向操作比较难之前都需要用其他表格类控件实现这个双击编辑文本,双击实现下拉列表框选择文本功能, 而且其中有很大一部分是ocx组件, 那么就需要在客户电脑上regsvr32 注册它, 这样就需要管理员权限, 这样操作并https://aardio.com.cn/t/21395

另外, 如果有更新会在我的博客第一时间更新, 有代码方面的问题也可以去那里跟帖提问.

声明：本文内容由网友自发贡献，不代表【wpsshop博客】立场，版权归原作者所有，本站不承担相应法律责任。如您发现有侵权的内容，请联系我们。转载请注明出处：https://www.wpsshop.cn/w/我家自动化/article/detail/537716
推荐阅读
相关标签

Copyright © 2003-2013 www.wpsshop.cn 版权所有，并保留所有权利。

  

闽ICP备14008679号