Arduino学习笔记（12） -- MPU6050与卡尔曼滤波算法实践_arduino dmp

01 简介：Why MPU6050？

MPU 6050等IMU传感器用于自平衡机器人，无人机，智能手机等。IMU传感器帮助我们在三维空间中获得连接到传感器的物体的位置。这些值通常是角度，以帮助我们确定其位置。它们用于检测智能手机的方向，或者用于Fitbit等可穿戴设备，它使用IMU传感器跟踪运动。

MPU6050 它是全球首例整合性 6 轴运动处理组件，俗称的六轴陀螺仪（x y z 三轴的倾斜角度和三轴方向的加速度）。它集成了陀螺仪和加速度计于一体的芯片，它极大程度上免除了独立使用的陀螺仪和加速度计在时间上的误差，而且减少了占用 PCB 板的空间。（图1 为实物图）

MPU6050具体参数：

MPU-60X0 对陀螺仪和加速度计分别用了三个 16 位的 ADC，将其测量的模拟量转化为可输出的数字量。为了精确跟踪快速和慢速的运动，传感器的测量范围都是用户可控的，陀螺仪可测范围为±250，±500，±1000，±2000°/秒（dps），加速度计可测范围为±2，±4，±8，±16g。 一个片上 1024 字节的 FIFO，有助于降低系统功耗。和所有设备寄存器之间的通信采用400kHz的I2C接口或1MHz的SPI接口（SPI 仅 MPU-6000 可用）。对于需要高速传输的应用，对寄存器的读取和中断可用 20MHz 的 SPI。另外，片上还内嵌了一个温度传感器和在工作环境下仅有±1%变动的振荡器。 芯片尺寸 4×4×0.9mm，采用 QFN 封装（无引线方形封装），可承受最大 10000g 的冲击，并有可编程的低通滤波器。 关于电源，MPU-60X0 可支持 VDD范围 2.5V±5%，3.0V±5%，或 3.3V±5%。另外 MPU-6050 还有一个 VLOGIC 引脚，用来为 I2C 输出提供逻辑电平。VLOGIC 电压可取 1.8±5%或者 VDD。（图 2 为 MPU6050 三轴示意图。）
 

MPU6050作为价格低廉、功能强大、开源的硬件，其广泛应用于通用场景的移动嵌入书开发，诸如四轴无人机，平衡车，机器人等作品， 以智能平衡小车为例，其融合了 Z 轴和 Y 轴夹角实现小车平衡。 

电路原理图

MPU6050 模块内部自带稳压电路，可兼容 3.3V/5V 的供电电压，采用先进的数字滤波技术，提高精度同时抑制了测量噪声。通讯方面，MPU6050 保留了 IIC 接口，高级用户能够采样底层测量数据。值得一提的是，芯片集成了 DMP （Digital Motion Processor）数字动态处理器（以后会用到，实现平衡小车姿体平衡）从陀螺仪、加速度计以及外接的传感器接收并处理数据，处理结果可以从 DMP 寄存器读出，或通过 FIFO（First In First Out） 缓冲。图4为模块的原理图，图5为Arduino连接原理图。

IMU工作原理

IMU传感器通常由两个或多个部件组成。按优先级列出它们，它们是加速度计，陀螺仪，磁力计和高度计。MPU 6050是6 DOF（自由度）或六轴IMU传感器，这意味着它提供六个值作为输出：来自加速度计的三个值和来自陀螺仪的三个值。MPU 6050是基于MEMS（微机电系统）技术的传感器。加速度计和陀螺仪都嵌入在单个芯片内。该芯片使用I2C（内部集成电路）I2C (inter-integrated circuit) 协议进行通信。

一个加速度计适用于压电效应原理。想象一个立方体盒子，里面有一个小球，如上图所示。这个盒子的墙壁是用压电晶体制成的。每当您倾斜盒子时，球都会因重力而沿倾斜方向移动。球碰撞的壁产生微小的压电电流。长方体中有三对相对的墙。每对对应于3D空间中的轴：X，Y和Z轴。根据压电壁产生的电流，我们可以确定倾斜方向及其大小。

 

连接到Arduino

MPU 6050通过I2C协议与Arduino通信。MPU 6050连接到Arduino，如下图所示。如果MPU 6050模块具有5V引脚，则可以将其连接到Arduino的5V引脚。如果没有，则必须将其连接到3.3V引脚。接下来，Arduino的GND连接到MPU 6050的GND。

                                     Arduino MPU 6050连接图

我们将在这里运行的程序也利用了Arduino的中断引脚。将Arduino的数字引脚2（中断引脚0）连接到MPU 6050上标记为INT的引脚。

接下来，我们需要设置I2C线路。为此，将MPU 6050上标有SDA的引脚连接到Arduino的模拟引脚4（SDA），将MPU 6050上标记为SCL的引脚连接到Arduino的模拟引脚5（SCL）。至此，已完成了Arduino MPU 6050的接线。

• 要测试Arduino MPU 6050，首先要下载由Jeff Rowberg开发的MPU 6050的Arduino library- >>>>>here
• Arduino与6050之间的通信I2C (inter-integrated circuit) 协议进行通信，加载IIC通信协议库文件- >>>>>here.

---

02 卡尔曼滤波

 

滤波原理：见本人的另外一篇博客

读取MPU6050数据

代码:

#include "Wire.h"
#include "I2Cdev.h"
#include "MPU6050.h"
 
MPU6050 accelgyro;
 
unsigned long now, lastTime = 0;
float dt;                                   //微分时间
 
int16_t ax, ay, az, gx, gy, gz;             //加速度计陀螺仪原始数据
float aax=0, aay=0,aaz=0, agx=0, agy=0, agz=0;    //角度变量
long axo = 0, ayo = 0, azo = 0;             //加速度计偏移量
long gxo = 0, gyo = 0, gzo = 0;             //陀螺仪偏移量
 
float pi = 3.1415926;
float AcceRatio = 16384.0;                  //加速度计比例系数
float GyroRatio = 131.0;                    //陀螺仪比例系数
 
uint8_t n_sample = 8;                       //加速度计滤波算法采样个数
float aaxs[8] = {0}, aays[8] = {0}, aazs[8] = {0};         //x,y轴采样队列
long aax_sum, aay_sum,aaz_sum;                      //x,y轴采样和
 
float a_x[10]={0}, a_y[10]={0},a_z[10]={0} ,g_x[10]={0} ,g_y[10]={0},g_z[10]={0}; //加速度计协方差计算队列
float Px=1, Rx, Kx, Sx, Vx, Qx;             //x轴卡尔曼变量
float Py=1, Ry, Ky, Sy, Vy, Qy;             //y轴卡尔曼变量
float Pz=1, Rz, Kz, Sz, Vz, Qz;             //z轴卡尔曼变量
 
void setup()
{
    Wire.begin();
    Serial.begin(115200);
 
    accelgyro.initialize();                 //初始化
 
    unsigned short times = 200;             //采样次数
    for(int i=0;i<times;i++)
    {
        accelgyro.getMotion6(&ax, &ay, &az, &gx, &gy, &gz); //读取六轴原始数值
        axo += ax; ayo += ay; azo += az;      //采样和
        gxo += gx; gyo += gy; gzo += gz;
    
    }
    
    axo /= times; ayo /= times; azo /= times; //计算加速度计偏移
    gxo /= times; gyo /= times; gzo /= times; //计算陀螺仪偏移
}
 
void loop()
{
    unsigned long now = millis();             //当前时间(ms)
    dt = (now - lastTime) / 1000.0;           //微分时间(s)
    lastTime = now;                           //上一次采样时间(ms)
 
    accelgyro.getMotion6(&ax, &ay, &az, &gx, &gy, &gz); //读取六轴原始数值
 
    float accx = ax / AcceRatio;              //x轴加速度
    float accy = ay / AcceRatio;              //y轴加速度
    float accz = az / AcceRatio;              //z轴加速度
 
    aax = atan(accy / accz) * (-180) / pi;    //y轴对于z轴的夹角
    aay = atan(accx / accz) * 180 / pi;       //x轴对于z轴的夹角
    aaz = atan(accz / accy) * 180 / pi;       //z轴对于y轴的夹角
 
    aax_sum = 0;                              // 对于加速度计原始数据的滑动加权滤波算法
    aay_sum = 0;
    aaz_sum = 0;
  
    for(int i=1;i<n_sample;i++)
    {
        aaxs[i-1] = aaxs[i];
        aax_sum += aaxs[i] * i;
        aays[i-1] = aays[i];
        aay_sum += aays[i] * i;
        aazs[i-1] = aazs[i];
        aaz_sum += aazs[i] * i;
    
    }
    
    aaxs[n_sample-1] = aax;
    aax_sum += aax * n_sample;
    aax = (aax_sum / (11*n_sample/2.0)) * 9 / 7.0; //角度调幅至0-90°
    aays[n_sample-1] = aay;                        //此处应用实验法取得合适的系数
    aay_sum += aay * n_sample;                     //本例系数为9/7
    aay = (aay_sum / (11*n_sample/2.0)) * 9 / 7.0;
    aazs[n_sample-1] = aaz; 
    aaz_sum += aaz * n_sample;
    aaz = (aaz_sum / (11*n_sample/2.0)) * 9 / 7.0;
 
    float gyrox = - (gx-gxo) / GyroRatio * dt; //x轴角速度
    float gyroy = - (gy-gyo) / GyroRatio * dt; //y轴角速度
    float gyroz = - (gz-gzo) / GyroRatio * dt; //z轴角速度
    agx += gyrox;                             //x轴角速度积分
    agy += gyroy;                             //x轴角速度积分
    agz += gyroz;
    
    /* kalman start */
    Sx = 0; Rx = 0;
    Sy = 0; Ry = 0;
    Sz = 0; Rz = 0;
    
    for(int i=1;i<10;i++)
    {                 //测量值平均值运算
        a_x[i-1] = a_x[i];                      //即加速度平均值
        Sx += a_x[i];
        a_y[i-1] = a_y[i];
        Sy += a_y[i];
        a_z[i-1] = a_z[i];
        Sz += a_z[i];
    
    }
    
    a_x[9] = aax;
    Sx += aax;
    Sx /= 10;                                 //x轴加速度平均值
    a_y[9] = aay;
    Sy += aay;
    Sy /= 10;                                 //y轴加速度平均值
    a_z[9] = aaz;
    Sz += aaz;
    Sz /= 10;
 
    for(int i=0;i<10;i++)
    {
        Rx += sq(a_x[i] - Sx);
        Ry += sq(a_y[i] - Sy);
        Rz += sq(a_z[i] - Sz);
    
    }
    
    Rx = Rx / 9;                              //得到方差
    Ry = Ry / 9;                        
    Rz = Rz / 9;
  
    Px = Px + 0.0025;                         // 0.0025在下面有说明...
    Kx = Px / (Px + Rx);                      //计算卡尔曼增益
    agx = agx + Kx * (aax - agx);             //陀螺仪角度与加速度计速度叠加
    Px = (1 - Kx) * Px;                       //更新p值
 
    Py = Py + 0.0025;
    Ky = Py / (Py + Ry);
    agy = agy + Ky * (aay - agy); 
    Py = (1 - Ky) * Py;
  
    Pz = Pz + 0.0025;
    Kz = Pz / (Pz + Rz);
    agz = agz + Kz * (aaz - agz); 
    Pz = (1 - Kz) * Pz;
 
    /* kalman end */
 
    Serial.print(agx);Serial.print(",");
    Serial.print(agy);Serial.print(",");
    Serial.print(agz);Serial.println();
    
}