【Unity Shader】实现带渐变效果的圆环_unity shader圆环扩散效果

最近用Unity Shader实现了个圆环效果

Shader "Sprites/GridCircle"
{
    Properties
    {
        _MainTex ("Texture", 2D) = "white" {}
		_InnerRadiuse("Inner Radius", Range(0,0.5)) = 0.1
		_InnerSideRadiuse("Inner Side Radius", Range(0.001,0.5)) = 0.05
		_OuterRadiuse("Outer Radius", Range(0,0.5)) = 0.2
		_OuterSideRadiuse("Outer Side Radius", Range(0.001,0.5)) = 0.05
		_InSideAlpha("In Side Alpha", Range(0,1)) = 0.2
		_Color("Circle Color", color) = (1,1,1,1)
    }

    SubShader
    {
		Tags
		{
			"Queue" = "Transparent"
			"IgnoreProjector" = "True"
			"RenderType" = "Transparent+2"
			"PreviewType" = "Plane"
			"CanUseSpriteAtlas" = "True"
		}

		Blend SrcAlpha OneMinusSrcAlpha  //半透混合模式

        Pass
        {
			ZWrite Off
			ZTest Less

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            // make fog work
            #pragma multi_compile_fog

            #include "UnityCG.cginc"

            struct appdata
            {
                float4 vertex : POSITION;
                float2 uv : TEXCOORD0;
            };

            struct v2f
            {
                float2 uv : TEXCOORD0;
                float4 vertex : SV_POSITION;
            };

            sampler2D _MainTex;
            float4 _MainTex_ST;
			fixed _InnerRadiuse;
			fixed _InnerSideRadiuse;
			fixed _OuterRadiuse;
			fixed _OuterSideRadiuse;
			fixed _InSideAlpha;
			fixed4 _Color;

            v2f vert (appdata v)
            {
                v2f o;
                o.vertex = UnityObjectToClipPos(v.vertex);
                o.uv = TRANSFORM_TEX(v.uv, _MainTex);
                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // sample the texture
                fixed4 col = tex2D(_MainTex, i.uv);
				col = col * _Color;

				fixed dis = distance(i.uv, fixed2(0.5, 0.5));

				// 外环
				fixed step0 = step(dis, _OuterRadiuse);
				col.a = lerp(1, step0 * _InSideAlpha, saturate(abs(dis - _OuterRadiuse) / _OuterSideRadiuse));

				clip(col.a - 0.0001);

				// 内环
				fixed step1 = step(_InnerRadiuse, dis);
				col.a = step1 * col.a + lerp(1, step1 * _InSideAlpha, saturate(abs(dis - _InnerRadiuse) / _InnerSideRadiuse));
				clip(col.a - 0.0001);

                return col;
            }
            ENDCG
        }
    }
}

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94